gentoo auto-resync : 16:10:2022 - 07:52:23

4 files changed, 191 insertions, 4 deletions

diff --git a/media-sound/ardour/Manifest b/media-sound/ardour/Manifest
index 547aa4bd4324..e31efdbc0200 100644
--- a/media-sound/ardour/Manifest
+++ b/media-sound/ardour/Manifest
@@ -1,5 +1,7 @@
 AUX ardour-6.8-metadata.patch 653 BLAKE2B 3929d825fd8de5205d0f5aa8d0172e6374ca9ffd195789386b756ae540e1842a9902592b8b6d74019c52f134e8cb9886085e23277ef022883c4425dc580c5bc9 SHA512 963f3cfcd00a3fb15cb9875f7fc31a8294058898b6fab94feb32f786369643139b1e8787ecc47a4ea6a33dabe6bd90f564b6009e0d6e482d8e5129534c789972
 DIST Ardour-6.9.0.tar.bz2 12297369 BLAKE2B 62037130b9f2d15a7f527b549c552a281105298dc85e3019d0f7ac09cb791f2b5460c4a7bd2f2098ccade6b87c70a16e6414691d90ec4baafeb6065f26d10a66 SHA512 ace45f5bfe6d0c9e4bb1712ae53ebaee2f15f883045650cae3ddcae251d4fd2f645ba745effb739b47c73a0568ae9e8ae443b711dd610584e04575fd9046b234
-EBUILD ardour-6.9-r2.ebuild 4880 BLAKE2B f0bda35454e1bf344a4296e822a32bcebfabc1f5ddbf4b76f33f69c5ef9d8ccaa4b6ead7228324f0c828bd1dd4538698bcdfbc2f1d18d9b2c51a91e6280f7845 SHA512 a0b544100e88708818ff809f85251981c490033e7d7ea11d9558326e9138bed9ed66f0d79a3108bb91256485505f0b5cae3341de9b7f481b5cc559d806005a25
-EBUILD ardour-9999.ebuild 5045 BLAKE2B 59ce5767e5dbcadfd948af2de5c8284540ef73321de6b4725185fe285db315710f14304ef31b4899811428375535c02d3d8c285fb50f8513ef1a55a8d4e994a7 SHA512 be4ea4500bcaa8aae369429ea6da1474842f6528a398f63d80238189233845684d98d8334bd8242dc999dc71961d31d22d153856f01d802cd255656abdf49372
+DIST Ardour-7.0.0.tar.bz2 12681139 BLAKE2B 7549c627ca085f40b4224ecd8a8f6e2a7a8a9a662e8a97048e9af3a0c6a0463ce69cea8ea20b867ae98649c3ab1b5940efed39978579b6b319b29ba5beb75d4d SHA512 5eeb84973f9a08e3bd2fbf9b829e902e001137ce330bcb26404f7a9da4ab3e89fdecca867511df7ae7bd3c744f7f2a5f9235b3de56c0d0c90d0a95dd6c043a27
+EBUILD ardour-6.9-r2.ebuild 4827 BLAKE2B 5b801194b7b30aacb4e3420e4cb1dd417b24f226a5651a495207b73716f0934fe16c67ede13e9efbdefb4df8d40c8f29fcb0b9eceb4b5deae1ed6b5c281b9907 SHA512 295c8cfaa174ca3a20f021b9139706fb1a987524468e6c574d3ecd1248ff66ba0fd445a11fc65116650d2c89788b66324c28a09344fbaadbdb9f96fece716f69
+EBUILD ardour-7.0.ebuild 4992 BLAKE2B 01f4753ac88da4d77d70cc5e1f0f78d93b0ac0f2ce5bed40d5dcf76fd61ccc221cc4e1414cd14e3ef8d16670a19fe9517b0681e870d86ec303ff4973e7c72366 SHA512 38bc166884bf5ec47071a5216ba0c53f8a2963a97714c5be9c0d6f5154c519b7f737ca63408a614959ce1893f50c742a48372875cd6727b572290451e2d26e9d
+EBUILD ardour-9999.ebuild 4992 BLAKE2B 01f4753ac88da4d77d70cc5e1f0f78d93b0ac0f2ce5bed40d5dcf76fd61ccc221cc4e1414cd14e3ef8d16670a19fe9517b0681e870d86ec303ff4973e7c72366 SHA512 38bc166884bf5ec47071a5216ba0c53f8a2963a97714c5be9c0d6f5154c519b7f737ca63408a614959ce1893f50c742a48372875cd6727b572290451e2d26e9d
 MISC metadata.xml 451 BLAKE2B 0ed571ca79f0d4b92239239982f04abf725365df169290e4a02f6d8f580cf801f70d8bc93414b4549c8172ff43864d5c49fa987caeec58e1b2331ffe01a69ae6 SHA512 504bd817356c7ee57c64193584b3fc5b3bc70f5224d5a531ac5ecf8fb974728639e75b77bb9e7c5ad77cf6099123361b9ec6211b855edb4761acd95b8cb7abcb
diff --git a/media-sound/ardour/ardour-6.9-r2.ebuild b/media-sound/ardour/ardour-6.9-r2.ebuild
index 21e7af85210c..3f85c9a41e8f 100644
--- a/media-sound/ardour/ardour-6.9-r2.ebuild
+++ b/media-sound/ardour/ardour-6.9-r2.ebuild
@@ -58,7 +58,7 @@ RDEPEND="
 	media-libs/lilv
 	media-libs/sratom
 	dev-libs/sord
-	|| ( >=media-libs/suil-0.10.16-r1[gtk2] <media-libs/suil-0.10.16-r1[gtk] )
+	media-libs/suil[gtk2]
 	media-libs/lv2"
 #	!bundled-libs? ( media-sound/fluidsynth ) at least libltc is missing to be able to unbundle...
 
diff --git a/media-sound/ardour/ardour-7.0.ebuild b/media-sound/ardour/ardour-7.0.ebuild
new file mode 100644
index 000000000000..463082c09921
--- /dev/null
+++ b/media-sound/ardour/ardour-7.0.ebuild
@@ -0,0 +1,185 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE='threads(+)'
+PLOCALES="cs de el en_GB es eu fr it ja nn pl pt pt_PT ru sv zh"
+inherit toolchain-funcs flag-o-matic plocale python-any-r1 waf-utils desktop xdg
+
+DESCRIPTION="Digital Audio Workstation"
+HOMEPAGE="https://ardour.org/"
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://git.ardour.org/ardour/ardour.git"
+	inherit git-r3
+else
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://dev.gentoo.org/~fordfrog/distfiles/Ardour-${PV}.0.tar.bz2"
+	S="${WORKDIR}/Ardour-${PV}.0"
+fi
+
+LICENSE="GPL-2"
+SLOT="7"
+IUSE="doc jack nls phonehome pulseaudio cpu_flags_ppc_altivec cpu_flags_x86_sse cpu_flags_x86_mmx cpu_flags_x86_3dnow"
+
+RDEPEND="
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:2.4
+	dev-libs/boost:=
+	dev-libs/glib:2
+	dev-libs/libsigc++:2
+	dev-libs/libxml2:2
+	dev-libs/libxslt
+	>=gnome-base/libgnomecanvas-2
+	media-libs/alsa-lib
+	media-libs/aubio
+	media-libs/flac:=
+	media-libs/freetype:2
+	media-libs/libart_lgpl
+	media-libs/liblo
+	media-libs/liblrdf
+	media-libs/libsamplerate
+	media-libs/libsndfile
+	media-libs/libsoundtouch
+	media-libs/raptor:2
+	media-libs/rubberband
+	media-libs/taglib
+	media-libs/vamp-plugin-sdk
+	net-misc/curl
+	sys-libs/readline:0=
+	sci-libs/fftw:3.0[threads]
+	virtual/libusb:1
+	x11-libs/cairo
+	x11-libs/gtk+:2
+	x11-libs/pango
+	jack? ( virtual/jack )
+	pulseaudio? ( media-sound/pulseaudio )
+	media-libs/lilv
+	media-libs/sratom
+	dev-libs/sord
+	media-libs/suil[gtk2]
+	media-libs/lv2"
+#	!bundled-libs? ( media-sound/fluidsynth ) at least libltc is missing to be able to unbundle...
+
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	dev-util/itstool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )
+	jack? ( virtual/jack )"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-6.8-metadata.patch"
+)
+
+pkg_pretend() {
+	[[ $(tc-getLD) == *gold* ]] && (has_version sci-libs/fftw[openmp] || has_version sci-libs/fftw[threads]) && \
+		ewarn "Linking with gold linker might produce broken executable, see bug #733972"
+}
+
+pkg_setup() {
+	if has_version \>=dev-libs/libsigc++-2.6 ; then
+		append-cxxflags -std=c++11
+	fi
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+
+	sed 's/'full-optimization\'\ :\ \\[.*'/'full-optimization\'\ :\ \'\','/' -i "${S}"/wscript || die
+	MARCH=$(get-flag march)
+	OPTFLAGS=""
+	if use cpu_flags_x86_sse; then
+		if [[ ${MARCH} == "i686" ]] || [[ ${MARCH} == "i486" ]]; then
+			elog "You enabled sse but use an march that does not support sse!"
+			elog "We add -msse to the flags now, but please consider switching your march in make.conf!"
+		fi
+		OPTFLAGS="sse"
+	fi
+	if use cpu_flags_x86_mmx; then
+		if [[ ${MARCH} == "i486" ]]; then
+			elog "You enabled mmx with i486 set as march! You have been warned!"
+		fi
+		OPTFLAGS="${OPTFLAGS} mmx"
+	fi
+	if use cpu_flags_x86_3dnow; then
+		OPTFLAGS="${OPTFLAGS} 3dnow"
+	fi
+	sed 's/flag_line\ =\ o.*/flag_line\ =\ \": '"${OPTFLAGS}"' just some place holders\"/' \
+		-i "${S}"/wscript || die
+	sed 's/cpu\ ==\ .*/cpu\ ==\ "LeaveMarchAsIs":/' -i "${S}"/wscript || die
+	append-flags "-lboost_system"
+	python_fix_shebang "${S}"/wscript
+	python_fix_shebang "${S}"/waf
+	my_lcmsg() {
+		rm -f {gtk2_ardour,gtk2_ardour/appdata,libs/ardour,libs/gtkmm2ext}/po/${1}.po
+	}
+	plocale_for_each_disabled_locale my_lcmsg
+}
+
+src_configure() {
+	# avoid bug https://bugs.gentoo.org/800067
+	local -x AS="$(tc-getCC) -c"
+
+	local backends="alsa,dummy"
+	use jack && backends+=",jack"
+	use pulseaudio && backends+=",pulseaudio"
+
+	tc-export CC CXX
+	mkdir -p "${D}"
+	local myconf=(
+		--configdir=/etc
+		--freedesktop
+		--noconfirm
+		--optimize
+		--with-backends=${backends}
+		$({ use cpu_flags_ppc_altivec || use cpu_flags_x86_sse; } && echo "--fpu-optimization" || echo "--no-fpu-optimization")
+		$(usex doc "--docs" '')
+		$(usex nls "--nls" "--no-nls")
+		$(usex phonehome "--phone-home" "--no-phone-home")
+		# not possible right now  --use-external-libs
+	)
+
+	waf-utils_src_configure "${myconf[@]}"
+}
+
+src_compile() {
+	waf-utils_src_compile
+	use nls && waf-utils_src_compile i18n
+}
+
+src_install() {
+	local s
+
+	waf-utils_src_install
+
+	mv ${PN}.1 ${PN}${SLOT}.1 || die
+	doman ${PN}${SLOT}.1
+
+	for s in 16 22 32 48 256 512; do
+		newicon -s ${s} gtk2_ardour/resources/Ardour-icon_${s}px.png ardour${SLOT}.png
+	done
+
+	# the build system still installs ardour6.png files so we get rid of those to not conflict with ardour:6
+	find "${D}/usr/share/icons/" -name ardour6.png -delete
+
+	sed -i \
+		-e "s/\(^Name=\).*/\1Ardour ${SLOT}/" \
+		-e 's/;AudioEditing;/;X-AudioEditing;/' \
+		build/gtk2_ardour/ardour${SLOT}.desktop || die
+	domenu build/gtk2_ardour/ardour${SLOT}.desktop
+
+	insinto /usr/share/mime/packages
+	newins build/gtk2_ardour/ardour.xml ardour${SLOT}.xml
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	elog "Please do _not_ report problems with the package to ${PN} upstream."
+	elog "If you think you've found a bug, check the upstream binary package"
+	elog "before you report anything to upstream."
+}
diff --git a/media-sound/ardour/ardour-9999.ebuild b/media-sound/ardour/ardour-9999.ebuild
index 6b4cd2f9e9be..463082c09921 100644
--- a/media-sound/ardour/ardour-9999.ebuild
+++ b/media-sound/ardour/ardour-9999.ebuild
@@ -58,7 +58,7 @@ RDEPEND="
 	media-libs/lilv
 	media-libs/sratom
 	dev-libs/sord
-	|| ( >=media-libs/suil-0.10.16-r1[gtk2] <media-libs/suil-0.10.16-r1[gtk] )
+	media-libs/suil[gtk2]
 	media-libs/lv2"
 #	!bundled-libs? ( media-sound/fluidsynth ) at least libltc is missing to be able to unbundle...