gentoo resync : 17.02.2021

1 files changed, 60 insertions, 0 deletions

diff --git a/media-sound/bristol/bristol-0.60.11-r2.ebuild b/media-sound/bristol/bristol-0.60.11-r2.ebuild
new file mode 100644
index 000000000000..e5481dc9adb8
--- /dev/null
+++ b/media-sound/bristol/bristol-0.60.11-r2.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic
+
+DESCRIPTION="Synthesizer keyboard emulation package: Moog, Hammond and others"
+HOMEPAGE="https://sourceforge.net/projects/bristol"
+SRC_URI="mirror://sourceforge/bristol/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="alsa oss"
+# osc : configure option but no code it seems...
+# jack: fails to build if disabled
+# pulseaudio: not fully supported
+
+BDEPEND="
+	virtual/pkgconfig"
+RDEPEND="
+	virtual/jack
+	x11-libs/libX11
+	alsa? ( media-libs/alsa-lib )"
+# osc? ( >=media-libs/liblo-0.22 )
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-cflags.patch
+	"${FILESDIR}"/${P}-implicit-dec.patch
+	"${FILESDIR}"/${P}-dontcompress.patch
+	"${FILESDIR}"/${P}-rm_alsa-iatomic.h.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	append-cflags -fcommon
+	econf \
+		--disable-static \
+		--disable-version-check \
+		$(use_enable alsa) \
+		$(use_enable oss)
+}
+
+src_compile() {
+	emake LDFLAGS="${LDFLAGS}"
+}
+
+src_install() {
+	default
+	dodoc HOWTO
+
+	find "${ED}" -name '*.la' -delete || die
+}