gentoo resync : 12.03.2021

3 files changed, 195 insertions, 3 deletions

diff --git a/media-sound/deadbeef/Manifest b/media-sound/deadbeef/Manifest
index 1fe466b1d16b..071c2778b091 100644
--- a/media-sound/deadbeef/Manifest
+++ b/media-sound/deadbeef/Manifest
@@ -1,4 +1,6 @@
 AUX deadbeef-use-ffmpeg-plugin-for-ape-by-default.patch 492 BLAKE2B d6ed36829d7ed139c43b6aa65c940f07e3f023d0554c258a2557c528d75e85c7dd2ca57eecef56088383a3b7b0b4f12109eb899f2847b86953421e826777c954 SHA512 0cec1ae38cf48b3f2ea53f74a6348d0217b1b3f017b836489d5b520f09ad76b6526cd3add48ed23871bc86feb7f7ed697cf6a62164a202be1ecabfd947e895f6
 DIST deadbeef-1.8.4.tar.gz 13049446 BLAKE2B a6c052b3b0aa1f74b49cf29be94e235d3dfd3d3f07ed9e1d05a4fc32036e591633eaff4ab59329cf6895828c9a674eec86b62e4818784db5f8e47eed089c80eb SHA512 18c54ae2c7931419ea06f3eb581cc8e704fa6eb87d330fc09f7295f4a8ef6e88b6f8c314223c34c321cd2a54f14cb6911add41602250c39c1b1c1edbf64d63b7
-EBUILD deadbeef-1.8.4.ebuild 3643 BLAKE2B a0f2a811f2174b5c9e3c12487eec364e71f7ba02353474f2bd7c6a3197f8e9080dcfdc2dc8bddafeaf79d982436f253aa7f928c36ac70b07a4e7ca09f1d1572d SHA512 f866c587b7cc067d59b675feba821e425e4de180ea850164eff7b10ae7c235632b6007b6684dc3a4dab72448253ce21686da4e62b823d226d43c4d5c531a28b8
+DIST deadbeef-1.8.7.tar.bz2 5029039 BLAKE2B f6ae0d664553435fca566593d715f8f9fab13711bb0e0488c80b9c7ff88a28425d1e3de2ee4c57b87722705c5ede53e0390b81cdbe6ce804d781dfe934dc21e9 SHA512 49a9610f8aa8d9853cd4f9a38d103f9a902993a5ae1990937a3ac5a14a4f8533f4233002893875aedf45f737d1a95c7cea189c61d6387bd8be7f3535d60c96eb
+EBUILD deadbeef-1.8.4.ebuild 3646 BLAKE2B c2c4363e5e6f3e319bb6c69a7d94abdedf4a18edad70a7a0c537184715193f81670ad9e82df87429a7b7a90061f7b639f90447a182da1a231cd6029de57e6c46 SHA512 2abd44b486596e15ca79fcd7b6f7c9fbe1b6f037d5fdfa49afe0e6af771c7d26e36d3d2190b6bf63d6101fc38e21d787a76e9832c3df7d704a051a47cef31662
+EBUILD deadbeef-1.8.7-r1.ebuild 3986 BLAKE2B a11b7425de25d40fd4245d16fb1ad2c98586736c62dad67141b242619724582b63c94b3da03a22acab7f228255abd47b686879007747cb4a9467343d23cb2f73 SHA512 df1b8647ad68e47ece5176ba0238190e0cab779b07709664068244f504a1aab68d49a8267e6d296e217bc1418a9aebed7b6b084b07a18734294c2f922eaec6ad
 MISC metadata.xml 832 BLAKE2B e062743afe851439a7ac29e3547e0296a7a00b6ed93d875f8725de185e5ce6b677432fd039257887b47b294d692de2f0ccb6cf9112a2c843d443ecb528b82cd6 SHA512 96aaed52c8959177be8a6d7ad30266cb8a73475119c27ec734dbab0126d19a139a3d513323d0020c42dae822cb12344959f4b9440c01f8ddd578b8dbd1241aca
diff --git a/media-sound/deadbeef/deadbeef-1.8.4.ebuild b/media-sound/deadbeef/deadbeef-1.8.4.ebuild
index 2df08a6243f2..e9f95c2dcca5 100644
--- a/media-sound/deadbeef/deadbeef-1.8.4.ebuild
+++ b/media-sound/deadbeef/deadbeef-1.8.4.ebuild
@@ -1,4 +1,4 @@
-# Copyright 2020 Gentoo Authors
+# Copyright 2020-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -15,7 +15,7 @@ LICENSE="
 	wavpack? ( BSD )
 "
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
+KEYWORDS="amd64 x86"
 IUSE="aac alsa cdda converter cover dts ffmpeg flac +hotkeys lastfm mp3 musepack nls notify nullout opus oss pulseaudio shellexec +supereq threads vorbis wavpack"
 
 REQUIRED_USE="
diff --git a/media-sound/deadbeef/deadbeef-1.8.7-r1.ebuild b/media-sound/deadbeef/deadbeef-1.8.7-r1.ebuild
new file mode 100644
index 000000000000..57149d1c35bf
--- /dev/null
+++ b/media-sound/deadbeef/deadbeef-1.8.7-r1.ebuild
@@ -0,0 +1,190 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools xdg l10n flag-o-matic
+
+DESCRIPTION="DeaDBeeF is a modular audio player similar to foobar2000"
+HOMEPAGE="https://deadbeef.sourceforge.io/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="
+	GPL-2
+	LGPL-2.1
+	wavpack? ( BSD )
+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="aac alsa cdda converter cover dts ffmpeg flac +hotkeys lastfm mp3 musepack nls notify nullout opus oss pulseaudio shellexec +supereq threads vorbis wavpack"
+
+REQUIRED_USE="
+	|| ( alsa oss pulseaudio nullout )
+"
+
+DEPEND="
+	x11-libs/gtk+:3
+	net-misc/curl:0=
+	dev-libs/jansson
+	aac? ( media-libs/faad2 )
+	alsa? ( media-libs/alsa-lib )
+	cdda? (
+		dev-libs/libcdio:0=
+		media-libs/libcddb
+		dev-libs/libcdio-paranoia:0=
+	)
+	cover? ( media-libs/imlib2[jpeg,png] )
+	dts? ( media-libs/libdca )
+	ffmpeg? ( media-video/ffmpeg )
+	flac? (
+		media-libs/flac
+		media-libs/libogg
+	)
+	mp3? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	nls? ( virtual/libintl )
+	notify? (
+		sys-apps/dbus
+		dev-libs/libdispatch
+	)
+	opus? ( media-libs/opusfile	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	lastfm? ( dev-libs/libdispatch )
+"
+
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	sys-devel/clang
+	sys-devel/llvm
+"
+
+PATCHES=(
+	"${FILESDIR}/deadbeef-use-ffmpeg-plugin-for-ape-by-default.patch"
+)
+
+src_prepare() {
+	default
+
+	drop_from_linguas() {
+		sed "/${1}/d" -i "${S}/po/LINGUAS" || die
+	}
+
+	drop_and_stub() {
+		rm -rf "${1}"
+		mkdir "${1}"
+		cat > "${1}/Makefile.in" <<-EOF
+			all: nothing
+			install: nothing
+			nothing:
+		EOF
+	}
+
+	l10n_for_each_disabled_locale_do drop_from_linguas || die
+
+	eautopoint --force
+	eautoreconf
+
+	# Get rid of bundled gettext.
+	drop_and_stub "${S}/intl"
+
+	# Plugins that are undesired for whatever reason, candidates for unbundling and such.
+	for i in adplug alac dumb ffap mms gme mono2stereo psf sc60 shn sid soundtouch wma; do
+		drop_and_stub "${S}/plugins/${i}"
+	done
+
+	rm -rf "${S}/plugins/rg_scanner/ebur128"
+}
+
+src_configure () {
+	if ! tc-is-clang; then
+		AR=llvm-ar
+		CC=${CHOST}-clang
+		CXX=${CHOST}-clang++
+		NM=llvm-nm
+		RANLIB=llvm-ranlib
+
+		strip-unsupported-flags
+	fi
+
+	export HOST_CC="$(tc-getBUILD_CC)"
+	export HOST_CXX="$(tc-getBUILD_CXX)"
+	tc-export CC CXX LD AR NM OBJDUMP RANLIB PKG_CONFIG
+
+	local myconf=(
+		"--disable-static"
+		"--disable-staticlink"
+		"--disable-portable"
+		"--disable-rpath"
+
+		"--disable-libmad"
+		"--disable-gtk2"
+		"--disable-adplug"
+		"--disable-coreaudio"
+		"--disable-dumb"
+		"--disable-alac"
+		"--disable-ffap"
+		"--disable-gme"
+		"--disable-mms"
+		"--disable-mono2stereo"
+		"--disable-psf"
+		"--disable-rgscanner"
+		"--disable-sc68"
+		"--disable-shn"
+		"--disable-sid"
+		"--disable-sndfile"
+		"--disable-soundtouch"
+		"--disable-src"
+		"--disable-tta"
+		"--disable-vfs-zip"
+		"--disable-vtx"
+		"--disable-wildmidi"
+		"--disable-wma"
+
+		"$(use_enable alsa)"
+		"$(use_enable oss)"
+		"$(use_enable pulseaudio pulse)"
+		"$(use_enable mp3)"
+		"$(use_enable mp3 libmpg123)"
+		"$(use_enable nls)"
+		"$(use_enable vorbis)"
+		"$(use_enable threads)"
+		"$(use_enable flac)"
+		"$(use_enable supereq)"
+		"$(use_enable cdda)"
+		"$(use_enable cdda cdda-paranoia)"
+		"$(use_enable aac)"
+		"$(use_enable cover artwork)"
+		"$(use_enable cover artwork-imlib2)"
+		"$(use_enable cover artwork-network)"
+		"$(use_enable dts dca)"
+		"$(use_enable ffmpeg)"
+		"$(use_enable converter)"
+		"$(use_enable musepack)"
+		"$(use_enable notify)"
+		"$(use_enable nullout)"
+		"$(use_enable opus)"
+		"$(use_enable pulseaudio pulse)"
+		"$(use_enable shellexec)"
+		"$(use_enable shellexec shellexecui)"
+		"$(use_enable lastfm lfm)"
+		"$(use_enable wavpack)"
+
+		"--enable-gtk3"
+		"--enable-vfs-curl"
+		"--enable-shared"
+		"--enable-m3u"
+		"--enable-pltbrowser"
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}