gentoo resync : 27.10.2018

2 files changed, 272 insertions, 0 deletions

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index d57def02c9a2..9485fbff9109 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -5,6 +5,8 @@ AUX mpd-0.20.4.init 681 BLAKE2B 36f48fe4f2432f659c455e75c3e6a773e7d49b9194fea75c
 AUX mpd-0.20.4.logrotate 79 BLAKE2B fcff807fb7557d480378ae6712f598147c9dbc3381ca89b21529277bfc636448e474b610096eae5c02963bc5aa5cf1055f0a9bbde36f2cc8d178e373a755fa84 SHA512 b4616307eb4b06e42a53120bb37276ea19cb1b3096094214062835f71093a1d196bc515b6b6f1e23dbd83a49151565807071959408c4f1078d95925660d3b324
 DIST mpd-0.20.10.tar.xz 778828 BLAKE2B c16b955ace770cf3d5da2ccad81fd3089cf2e60bf47774745d75babcff38fa344646b26dd32617fa2fe86ee0c785b9c8272ea6c90f77266b1a0cba2d48145236 SHA512 bac6a71e5b85600c590eae6b785474574cf0d7b03d9add537161b968a2997a975a597639a9fece119a01a7e27b5207523e4ae30b2f4f35791eff8c3ff26d107c
 DIST mpd-0.20.21.tar.xz 800476 BLAKE2B 0c807ae8d79abd9400aa417b516c709073b23390aeed2b385c716e20f8c4f93376a235b54fe5f5cfcd451b04c76e105b41acbd180d294281432d4d1b6a427a15 SHA512 d44fb326ea6213ecf46721ca81efdfffaec4faa5a66e627185fd5ab7c4f0c5a380f4d04aed5c2909746a37b33987cb61f62dc2d747365da06629fbb78bf7c7d6
+DIST mpd-0.20.22.tar.xz 807084 BLAKE2B 156b5cac8ea571df37cd4460fb6c511c4101bed16dd9196d4287ed7dd83069d7cbe1c6ab64b2d955c36c22499653c929da2516a1ceafb498ba4b5645390ea568 SHA512 7fe2b7f31cdda874ec686fd3d2047a6630c9370d7475004c09fdb3c35e85ef1e1ee5d63e039ed1fed52929498a3d261b297e68ed802ae7487810d5779b02ad10
 EBUILD mpd-0.20.10.ebuild 7285 BLAKE2B 08b8d0afe72f0ad186438441aa1229e71c1c2564250c9e624eac2f7c6ec7596bd9f0ad4b353b4ca37af9acac2bda7b2a59f134265cb9a41be0bdfef64cf384b8 SHA512 82c6c20fbe05137a61ed07daa9bdcd0e7639267d8301e14257978d13e67a6ec9e0581f873c22df14a90a1dffb71dfd47fc456aee49889dc5d67a566ea6326ba4
 EBUILD mpd-0.20.21-r1.ebuild 7308 BLAKE2B a4579b515ea1904f2973f5b424f205cc08286aec7e516c33ba3aa035c2fca93117c8ede03818d3534a7cedba6b547fb1320039771f000a989ba218a60dcb7b87 SHA512 f7601f95f10158f112a65ac7625840f5a199bb349323c662dc6477e7a9b1498a593bff8cff289c1a37b78ebb80647136e843f8816bf77a5d7e1b8a0fc1624d66
+EBUILD mpd-0.20.22.ebuild 7311 BLAKE2B 25d0a67accc8cd81fd2a2d241f9a94b02d2a686af4fe7184f543fbd8f7a5f14793bf046a862222dea26b5e1533c0a132513a698b1199b46d33aa25b99a1f9392 SHA512 cd47cf1501ca33252c97e35c91708ca66c63e2030d1727d507b84575b5bc70e8867a4c8b3aca5ba4fdcba0847bb5bb36901d87989a002d0536016a53209f5b93
 MISC metadata.xml 2412 BLAKE2B b208c2d3481421794b7fd5328814e9dd340eb820df4972c0bd70626d9d63707dfceb8f7446239a3ca581f46004a1aa5e6438cbb6449700f472c1aa411d848649 SHA512 4cbaa880020239d2fcf6e2f057004569eb86288d3f25dce8e89eddc8d65cbbccf01dd0cfbfc376790297a1147d18aec3148515659fae5aec3bbe215bb94c2f8d
diff --git a/media-sound/mpd/mpd-0.20.22.ebuild b/media-sound/mpd/mpd-0.20.22.ebuild
new file mode 100644
index 000000000000..0e22d8297530
--- /dev/null
+++ b/media-sound/mpd/mpd-0.20.22.ebuild
@@ -0,0 +1,270 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools flag-o-matic linux-info systemd user
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~x64-macos"
+IUSE="adplug +alsa ao audiofile bzip2 cdio +curl debug +eventfd expat faad
+	+fifo +ffmpeg flac fluidsynth gme +icu +id3tag +inotify +ipv6 jack
+	lame mms libav libmpdclient libsamplerate libsoxr +mad mikmod modplug
+	mpg123 musepack +network nfs ogg openal opus oss pipe pulseaudio recorder
+	samba selinux sid +signalfd sndfile soundcloud sqlite systemd tcpd twolame
+	unicode upnp vorbis wavpack wildmidi zeroconf zip zlib webdav"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio recorder"
+DECODER_PLUGINS="adplug audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack ogg flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="
+	|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	network? ( || ( ${ENCODER_PLUGINS} ) )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	opus? ( ogg )
+	upnp? ( expat )
+	webdav? ( curl expat )
+"
+
+COMMON_DEPEND="
+	adplug? ( media-libs/adplug )
+	alsa? (
+		media-libs/alsa-lib
+		media-sound/alsa-utils
+	)
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile )
+	bzip2? ( app-arch/bzip2 )
+	cdio? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+	curl? ( net-misc/curl )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	flac? ( media-libs/flac[ogg?] )
+	fluidsynth? ( media-sound/fluidsynth )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? ( dev-libs/icu:= )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( virtual/jack )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	libsoxr? ( media-libs/soxr )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod:0 )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( >=media-sound/mpg123-1.12.2 )
+	musepack? ( media-sound/musepack-tools )
+	network? (
+		>=media-libs/libshout-2
+		!lame? ( !vorbis? ( media-libs/libvorbis ) )
+	)
+	nfs? ( net-fs/libnfs )
+	ogg? ( media-libs/libogg )
+	openal? ( media-libs/openal )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	samba? ( >=net-fs/samba-4.0.25 )
+	sid? ( || (
+		media-libs/libsidplay:2
+		media-libs/libsidplayfp
+	) )
+	sndfile? ( media-libs/libsndfile )
+	soundcloud? ( >=dev-libs/yajl-2:= )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd )
+	tcpd? ( sys-apps/tcp-wrappers )
+	twolame? ( media-sound/twolame )
+	upnp? ( net-libs/libupnp:0= )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	virtual/pkgconfig"
+RDEPEND="${COMMON_DEPEND}
+	!<sys-cluster/mpich2-1.4_rc2
+	selinux? ( sec-policy/selinux-mpd )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.18.conf.patch
+)
+
+pkg_setup() {
+	use network || ewarn "Icecast and Shoutcast streaming needs networking."
+	use fluidsynth && ewarn "Using fluidsynth is discouraged by upstream."
+
+	enewuser mpd "" "" "/var/lib/mpd" audio
+
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+	if use eventfd || use signalfd || use inotify; then
+		linux-info_pkg_setup
+	fi
+
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make
+		sure that MPD's pid_file is _set_."
+}
+
+src_prepare() {
+	cp -f doc/mpdconf.example doc/mpdconf.dist || die "cp failed"
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-database --disable-roar --disable-documentation
+		--enable-dsd --enable-largefile --disable-osx --disable-shine-encoder
+		--disable-solaris-output --enable-tcp --enable-un --disable-werror
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+	)
+
+	if use network; then
+		myeconfargs+=(
+			--enable-shout
+			$(use_enable vorbis vorbis-encoder)
+			--enable-httpd-output
+			$(use_enable lame lame-encoder)
+			$(use_enable twolame twolame-encoder)
+			$(use_enable audiofile wave-encoder)
+		)
+	else
+		myeconfargs+=(
+			--disable-shout
+			--disable-vorbis-encoder
+			--disable-httpd-output
+			--disable-lame-encoder
+			--disable-twolame-encoder
+			--disable-wave-encoder
+		)
+	fi
+
+	if use samba || use upnp; then
+		myeconfargs+=( --enable-neighbor-plugins )
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	myeconfargs+=(
+		$(use_enable eventfd)
+		$(use_enable signalfd)
+		$(use_enable libmpdclient)
+		$(use_enable expat)
+		$(use_enable upnp)
+		$(use_enable adplug)
+		$(use_enable alsa)
+		$(use_enable ao)
+		$(use_enable audiofile)
+		$(use_enable zlib)
+		$(use_enable bzip2)
+		$(use_enable cdio cdio-paranoia)
+		$(use_enable curl)
+		$(use_enable samba smbclient)
+		$(use_enable nfs)
+		$(use_enable debug)
+		$(use_enable ffmpeg)
+		$(use_enable fifo)
+		$(use_enable flac)
+		$(use_enable fluidsynth)
+		$(use_enable gme)
+		$(use_enable id3tag id3)
+		$(use_enable inotify)
+		$(use_enable ipv6)
+		$(use_enable cdio iso9660)
+		$(use_enable jack)
+		$(use_enable soundcloud)
+		$(use_enable tcpd libwrap)
+		$(use_enable libsamplerate lsr)
+		$(use_enable libsoxr soxr)
+		$(use_enable mad)
+		$(use_enable mikmod)
+		$(use_enable mms)
+		$(use_enable modplug)
+		$(use_enable musepack mpc)
+		$(use_enable mpg123)
+		$(use_enable openal)
+		$(use_enable opus)
+		$(use_enable oss)
+		$(use_enable pipe pipe-output)
+		$(use_enable pulseaudio pulse)
+		$(use_enable recorder recorder-output)
+		$(use_enable sid sidplay)
+		$(use_enable sndfile sndfile)
+		$(use_enable sqlite)
+		$(use_enable systemd systemd_daemon)
+		$(use_enable vorbis)
+		$(use_enable wavpack)
+		$(use_enable wildmidi)
+		$(use_enable zip zzip)
+		$(use_enable icu)
+		$(use_enable webdav)
+		$(use_enable faad aac)
+		$(use_with zeroconf zeroconf avahi)
+		--with-boost="${EPREFIX}"/usr
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+		--with-systemduserunitdir=$(systemd_get_userunitdir)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	insinto /etc
+	newins doc/mpdconf.dist mpd.conf
+
+	newinitd "${FILESDIR}"/${PN}-0.20.4.init ${PN}
+
+	if use unicode; then
+		sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+			"${ED}"/etc/mpd.conf || die "sed failed"
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}-0.20.21.logrotate ${PN}
+
+	use prefix || diropts -m0755 -o mpd -g audio
+	dodir /var/lib/mpd
+	keepdir /var/lib/mpd
+	dodir /var/lib/mpd/music
+	keepdir /var/lib/mpd/music
+	dodir /var/lib/mpd/playlists
+	keepdir /var/lib/mpd/playlists
+}
+
+pkg_postinst() {
+	# also change the homedir if the user has existed before
+	usermod -d "/var/lib/mpd" mpd
+}