gentoo resync : 29.06.2021

2 files changed, 301 insertions, 0 deletions

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index fcfc4c49c445..d178cc068099 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -7,10 +7,12 @@ DIST mpd-0.22.4.tar.xz 729264 BLAKE2B d8060a205f94fa369ad8aee7a3e12f1389e7587aac
 DIST mpd-0.22.5.tar.xz 730308 BLAKE2B 2c7375af25c1b5d6dd8cf79f71e67842f75dcdb38b1ca90c8dda2661a5bd6d110ad0ebbefc53e0a38cfa6434ee4d2ad99688982588ee6d8d6895b24e15e3f927 SHA512 589516b7ee5820cbeee99042017b411a46857d39547302bce0bedb9c265da2c8465224a6817a1b7e65105f344398bee5fb2a3674064e42507157cdac01416295
 DIST mpd-0.22.6.tar.xz 730524 BLAKE2B 675b876415a343ba387e26ad800b2e562b40a5e3aaacdff31e0ec9d6ad09f0117406f82e519a08ba3187020b482dcd0434267f9e84dd13e9e1bf8565d1967c2c SHA512 5e417204e24d11fa609740ae92bc1d796aad2d63537655f655074d829cd79cadaf1ca025171dcf5486c1e557cc946152c21e299286b1cb74cc342da2b1f41343
 DIST mpd-0.22.8.tar.xz 737368 BLAKE2B 96866fdbcf124534d99db1bde89039d515c64afd7c65d341e6772be796feebf2fa20714f90856f82036dc322087ec2f85d8a4d85efad523a5f275f3d89d64920 SHA512 54b381e6d4e6113cd170ca7afbb671bef4ababb4de80a80504fe951f53aaf66269c123b7923112ab40291e069fa27457936227204cc84b42cf44aac1721c0d0d
+DIST mpd-0.22.9.tar.xz 738432 BLAKE2B c0c3a87ea83941e7ab85b4338db40daeff0c7fe665d4e0b27eebdf7cb06302d2b7a7573724d06d06d45a62583304f095ec4f67a21467748de665067e10a2514c SHA512 744e20e9a2b5df0f0c01b33809aa87cb159385b69868df5418302b091e6c5265dd70de13f383efcd71f76ae059c73969667212e55ee96e13d89ca0da5c2d4ae2
 EBUILD mpd-0.21.26.ebuild 8065 BLAKE2B bd01f82bd58a5026a179ed246a5b280b48c1f55fdbe80f41481f36a1e25827cbecd1a9904de791bd8a81e249b187aa0d94eff31c09e58f01032ea85196ef8338 SHA512 96879862ea3f10d67e420968703a476d02b4fc0c288fa1118170d225ce853303507de4a5265913f6afaa6690cde7b7995a7cf190ad8073df4c34914fd73af44c
 EBUILD mpd-0.22.3.ebuild 8122 BLAKE2B 79a904effc8fb09208f648dee611ba9795f2b25676399e9972aa0b4708c1084368a5c691dbbbe9336b8825439029a7f2b1b090bd0d58263569c104a2080b239a SHA512 23ef558178b9a67bbf39ade963e6cea591ee18157403ff0612c28640a8820d4d328b4dcddd465127658277222d8683a3f0ae8e02dfa8dd1ca32904abb5e83584
 EBUILD mpd-0.22.4-r1.ebuild 8514 BLAKE2B 6b3c92ba40b90459a9bab52a8ea7adf3878823a3e19dcaa32f925a68e4bb47473e1f5474c0299bf9e9065362061c99f6a63a48d4111d7e8efb02c0f6415e2ec8 SHA512 a618f86daae62d7e93eae96115a8593e9fd2a310c9a5167f1098d5f470136ca665dacd1aca18f98b068b21f4fca89d4b4f5d5dacd578d75bacb70fb52fd43c97
 EBUILD mpd-0.22.5.ebuild 8514 BLAKE2B 6b3c92ba40b90459a9bab52a8ea7adf3878823a3e19dcaa32f925a68e4bb47473e1f5474c0299bf9e9065362061c99f6a63a48d4111d7e8efb02c0f6415e2ec8 SHA512 a618f86daae62d7e93eae96115a8593e9fd2a310c9a5167f1098d5f470136ca665dacd1aca18f98b068b21f4fca89d4b4f5d5dacd578d75bacb70fb52fd43c97
 EBUILD mpd-0.22.6.ebuild 8514 BLAKE2B 6b3c92ba40b90459a9bab52a8ea7adf3878823a3e19dcaa32f925a68e4bb47473e1f5474c0299bf9e9065362061c99f6a63a48d4111d7e8efb02c0f6415e2ec8 SHA512 a618f86daae62d7e93eae96115a8593e9fd2a310c9a5167f1098d5f470136ca665dacd1aca18f98b068b21f4fca89d4b4f5d5dacd578d75bacb70fb52fd43c97
 EBUILD mpd-0.22.8.ebuild 8514 BLAKE2B 2724c46d1ee527aea93d3767cd89cb72ec416cf3e733e5a085cf023a265002f3bffe4e3faffd63151b8be0c259a8d065472f9e023b01327836f4a72fe3c3841c SHA512 52a61a59ec75fb83e6c04bbe59dd2e7d3f0a420d5f6a5f1b76016ecb2acaa40be2c4c2785621c3b2811c99e12e8392e8886395955a64ff8ab2b900e38bd1fec9
+EBUILD mpd-0.22.9.ebuild 8514 BLAKE2B 2724c46d1ee527aea93d3767cd89cb72ec416cf3e733e5a085cf023a265002f3bffe4e3faffd63151b8be0c259a8d065472f9e023b01327836f4a72fe3c3841c SHA512 52a61a59ec75fb83e6c04bbe59dd2e7d3f0a420d5f6a5f1b76016ecb2acaa40be2c4c2785621c3b2811c99e12e8392e8886395955a64ff8ab2b900e38bd1fec9
 MISC metadata.xml 2563 BLAKE2B a974514d9226d8ddb4ac85adaaccb4beb5104fc28d68248ac4afe87ab5358e2e7a4214444444419c20c22533ffeb1649308f805958273bce8f603f6f47551884 SHA512 642ecc4d91cfd82db6e4afa9e35f1dd01dd7c4be23576303cc29e266e629463b73491c61d0c0ff5b7dba753ea6c60ec89ccf1f5a895968e9127852b445151a39
diff --git a/media-sound/mpd/mpd-0.22.9.ebuild b/media-sound/mpd/mpd-0.22.9.ebuild
new file mode 100644
index 000000000000..cb6f9fbd098d
--- /dev/null
+++ b/media-sound/mpd/mpd-0.22.9.ebuild
@@ -0,0 +1,299 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic linux-info meson systemd xdg-utils
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="+alsa ao +audiofile bzip2 cdio chromaprint +cue +curl doc +dbus
+	+eventfd expat faad +ffmpeg +fifo flac fluidsynth gme +icu +id3tag +inotify
+	+ipv6 jack lame libmpdclient libsamplerate libsoxr +mad mikmod mms
+	modplug mpg123 musepack +network nfs openal opus oss pipe pulseaudio qobuz
+	recorder samba selinux sid signalfd sndfile sndio soundcloud sqlite systemd
+	test tidal twolame udisks vorbis wavpack webdav wildmidi upnp
+	zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pulseaudio sndio recorder"
+DECODER_PLUGINS="audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="
+	|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	network? ( || ( ${ENCODER_PLUGINS} ) )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	upnp? ( expat )
+	webdav? ( curl expat )
+	"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-user/mpd
+	sys-libs/liburing:=
+	alsa? (
+		media-libs/alsa-lib
+		media-sound/alsa-utils
+	)
+
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile:= )
+
+	cdio? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia
+	)
+
+	chromaprint? ( media-libs/chromaprint )
+	curl? ( net-misc/curl )
+	dbus? ( sys-apps/dbus )
+	doc? ( dev-python/sphinx )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	flac? ( media-libs/flac )
+	fluidsynth? ( media-sound/fluidsynth )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? (  dev-libs/icu:= )
+	id3tag? ( media-libs/libid3tag )
+	jack? ( virtual/jack )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	libsoxr? ( media-libs/soxr )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( media-sound/mpg123 )
+	musepack? ( media-sound/musepack-tools )
+	network? ( media-libs/libshout )
+	nfs? ( net-fs/libnfs )
+	openal? ( media-libs/openal )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-sound/pulseaudio )
+	qobuz? ( dev-libs/libgcrypt:0 )
+	samba? ( net-fs/samba )
+	selinux? ( sec-policy/selinux-mpd )
+	sid? ( || (
+		media-libs/libsidplay:2
+		media-libs/libsidplayfp
+	) )
+	sndfile? ( media-libs/libsndfile )
+	sndio? ( media-sound/sndio )
+	soundcloud? ( >=dev-libs/yajl-2:= )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd )
+	tidal? ( dev-libs/yajl
+		net-misc/curl )
+	twolame? ( media-sound/twolame )
+	udisks? ( sys-fs/udisks:2 )
+	upnp? ( net-libs/libupnp:0 )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib )
+	zlib? ( sys-libs/zlib:= )"
+
+DEPEND="${RDEPEND}
+	>=dev-libs/boost-1.58:=
+	test? ( dev-cpp/gtest )"
+
+BDEPEND=">=dev-util/meson-0.49.2
+	virtual/pkgconfig"
+
+pkg_setup() {
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+
+	if use eventfd || use signalfd || use inotify; then
+		linux-info_pkg_setup
+	fi
+
+	elog "If you will be starting mpd via /etc/init.d/mpd, please make
+	sure that MPD's pid_file is _set_."
+}
+
+src_prepare() {
+	sed -i \
+		-e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
+		-e 's:^#user.*$:user "mpd":' \
+		-e 's:^#bind_to_address.*any.*$:bind_to_address "localhost":' \
+		-e 's:^#bind_to_address.*$:bind_to_address "/var/lib/mpd/socket":' \
+		-e 's:^#music_directory.*$:music_directory "/var/lib/mpd/music":' \
+		-e 's:^#playlist_directory.*$:playlist_directory "/var/lib/mpd/playlists":' \
+		-e 's:^#db_file.*$:db_file "/var/lib/mpd/database":' \
+		-e 's:^#log_file.*$:log_file "/var/lib/mpd/log":' \
+		-e 's:^#pid_file.*$:pid_file "/var/lib/mpd/pid":' \
+		-e 's:^#state_file.*$:state_file "/var/lib/mpd/state":' \
+		doc/mpdconf.example || die
+	default
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dbzip2=$(usex bzip2 enabled disabled)
+		-Dcdio_paranoia=$(usex cdio enabled disabled)
+		-Dchromaprint=$(usex chromaprint enabled disabled)
+		-Dcue=$(usex cue true false)
+		-Dcurl=$(usex curl enabled disabled)
+		-Ddbus=$(usex dbus enabled disabled)
+		-Deventfd=$(usex eventfd true false)
+		-Dexpat=$(usex expat enabled disabled)
+		-Dicu=$(usex icu enabled disabled)
+		-Did3tag=$(usex id3tag enabled disabled)
+		-Dinotify=$(usex inotify true false)
+		-Dipv6=$(usex ipv6 enabled disabled)
+		-Diso9660=$(usex cdio enabled disabled)
+		-Dlibmpdclient=$(usex libmpdclient enabled disabled)
+		-Dlibsamplerate=$(usex libsamplerate enabled disabled)
+		-Dmms=$(usex mms enabled disabled)
+		-Dnfs=$(usex nfs enabled disabled)
+		-Dsignalfd=$(usex signalfd true false)
+		-Dsmbclient=$(usex samba enabled disabled)
+		-Dsoxr=$(usex libsoxr enabled disabled)
+		-Dsqlite=$(usex sqlite enabled disabled)
+		-Dsystemd=$(usex systemd enabled disabled)
+		-Dtest=$(usex test true false)
+		-Dudisks=$(usex udisks enabled disabled)
+		-Dupnp=$(usex upnp enabled disabled)
+		-Dwebdav=$(usex webdav enabled disabled)
+		-Dzeroconf=$(usex zeroconf avahi disabled)
+		-Dzlib=$(usex zlib enabled disabled)
+		-Dzzip=$(usex zip enabled disabled)
+		)
+
+	emesonargs+=(
+		-Dalsa=$(usex alsa enabled disabled)
+		-Dao=$(usex ao enabled disabled)
+		-Dfifo=$(usex fifo true false)
+		-Djack=$(usex jack enabled disabled)
+		-Dopenal=$(usex openal enabled disabled)
+		-Doss=$(usex oss enabled disabled)
+		-Dpipe=$(usex pipe true false)
+		-Dpulse=$(usex pulseaudio enabled disabled)
+		-Drecorder=$(usex recorder true false)
+		-Dsndio=$(usex sndio enabled disabled)
+	)
+
+	if use samba || use upnp; then
+		emesonargs+=( -Dneighbor=true )
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L/usr/$(get_libdir)/sidplay/builders"
+
+	if use network; then
+
+	emesonargs+=(
+		-Dshine=disabled
+		-Dshout=enabled
+		-Dvorbisenc=$(usex vorbis enabled disabled)
+		-Dhttpd=true
+		-Dlame=$(usex lame enabled disabled)
+		-Dtwolame=$(usex twolame enabled disabled)
+		-Dwave_encoder=$(usex audiofile true false)
+	)
+	fi
+
+	emesonargs+=(
+		# media-libs/adplug is not packaged anymore
+		-Dadplug=disabled
+		-Daudiofile=$(usex audiofile enabled disabled)
+		-Dfaad=$(usex faad enabled disabled)
+		-Dffmpeg=$(usex ffmpeg enabled disabled)
+		-Dflac=$(usex flac enabled disabled)
+		-Dfluidsynth=$(usex fluidsynth enabled disabled)
+		-Dgme=$(usex gme enabled disabled)
+		-Dmad=$(usex mad enabled disabled)
+		-Dmikmod=$(usex mikmod enabled disabled)
+		-Dmodplug=$(usex modplug enabled disabled)
+		-Dmpcdec=$(usex musepack enabled disabled)
+		-Dmpg123=$(usex mpg123 enabled disabled)
+		-Dopus=$(usex opus enabled disabled)
+		-Dsidplay=$(usex sid enabled disabled)
+		-Dsndfile=$(usex sndfile enabled disabled)
+		-Dvorbis=$(usex vorbis enabled disabled)
+		-Dwavpack=$(usex wavpack enabled disabled)
+		-Dwildmidi=$(usex wildmidi enabled disabled)
+
+	)
+
+	emesonargs+=(
+		-Dqobuz=$(usex qobuz enabled disabled)
+		-Dsoundcloud=$(usex soundcloud enabled disabled)
+		-Dtidal=$(usex tidal enabled disabled)
+	)
+
+	emesonargs+=(
+		--libdir="/usr/$(get_libdir)"
+		-Ddocumentation=$(usex doc enabled disabled)
+		-Dsolaris_output=disabled
+
+		-Ddatabase=true
+		-Ddsd=true
+		-Dio_uring=enabled
+		-Dtcp=true
+
+		-Dsystemd_system_unit_dir="$(systemd_get_systemunitdir)"
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+		)
+
+	if use icu; then
+		emesonargs+=( -Diconv=enabled )
+	else
+		emesonargs+=( -Diconv=disabled )
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /etc
+	newins doc/mpdconf.example mpd.conf
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/${PN}-0.21.1.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}-0.21.4.init ${PN}
+
+	keepdir /var/lib/mpd
+	keepdir /var/lib/mpd/music
+	keepdir /var/lib/mpd/playlists
+
+	fowners mpd:audio -R /var/lib/mpd
+
+	rm -r "${ED}"/usr/share/doc/mpd || die
+
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}