gentoo auto-resync : 19:01:2025 - 06:42:08

2 files changed, 304 insertions, 0 deletions

diff --git a/media-sound/mpd/Manifest b/media-sound/mpd/Manifest
index f8237f3f0ac3..b49f81607d17 100644
--- a/media-sound/mpd/Manifest
+++ b/media-sound/mpd/Manifest
@@ -1,6 +1,9 @@
 AUX mpd-0.23.15.init 1400 BLAKE2B 6b9defd7f8a8cbfeaf6196d1ad4e928a9c0edf9b6d109a375a711aa81ab06128be8eace7bd278af8077cc841bb6ece5240a315902f55d42bb874ddddb0f73f09 SHA512 a19df8d17bc2b53200318bb2b1b4fb2a8e2f3a2968bf0769694b55e0cc5dc2db52bd261f933de2180c19f9c6125f01e62f67d4e09d5e3796abf0bdb71034fcce
 AUX mpd-0.23.15.init-r1 1433 BLAKE2B 30de4d260374d01bca9c24419207320d2253f974134da10ca946af88b8c3804555459e9f4e86575f2421810d1c894d6215ba1404b3c70467c23586208ff6859d SHA512 266b7a53e76cfb987794eb1741b46bcb10a33708cf6704fd92899a4315c78d3ea03d3ab2880197bad23d79c8c60c67c19c122d634f1d5caf78da27abe1285295
 AUX mpd-0.23.15.logrotate 124 BLAKE2B 4c2200d4a2fba4735037757f74a27cfbc71dcd9ec1d18e3f3d94efbeccbe99164adc7582fc1c153e50b019280b9d51bb92d08c5498d048cd7e6c2313e762b29a SHA512 2990b6facd1f8f99e85c67e16c248cb36444d933ff47a479612b0305296bb15d8eb570bea2e43a6752a687186d53728ba272869e84942b4d36f108b35fe475ac
+DIST mpd-0.23.15.16-fix-libfmt-11.1.0.patch.xz 7260 BLAKE2B 4321f48f8bf21011a1919517969ce7de6eaa5d6c051654ec96e57d01fe48f38341d7ecb206aec314bd33288b2a6a299d594328fa136b04547d6d0cb48de85f25 SHA512 a52443039a9f60c10d19e85ef1b4c8a762d6c6f135257d9a2c8f01c936f4007dd096e4bec354ffb756519794960f57d5b2a7882c8e9296d6e2f07f99e4267d20
 DIST mpd-0.23.15.tar.xz 778384 BLAKE2B 78036078b850afab900b5d50e44ce83cbbf900369f5028d4177fdbfc4128dd3c35c59a773528a1fcfcc0179d0e579566b827fe87ef780a88082dc3b7f70cd5e7 SHA512 12329dbd0c1994c1bd95b88ce2a62a4c1d691b655e9e4fac7e9ef7066d0be3422b26fad3ea6ca144ba9b21add0a7c492c4f74fd2b68a1539bff2e0d2714db709
+DIST mpd-0.23.16.tar.xz 778572 BLAKE2B 7e4e7dafdc60cac59b7b47898cdaf8332970dae9209f8dd408aee7f4ecf90909404ab12a263d06aae44124d795d0d1092425294034fc0728fc9b4ac973a75dd0 SHA512 1b7042cbe8543270b26c1a9e4f35d80d68e03682e4d1e039af8f52527753830972de2a763e5dfb7bde28f4c9d0308a397becd4a206d17e7a5b2fa97f48b69d20
 EBUILD mpd-0.23.15-r3.ebuild 7728 BLAKE2B 7ad0855d094a35c935f7d39a9477c9c2fa5169771363e6605ae1120c504f9ef06d075a02bbf61133b38a1179d63b3508c9a249889264505470cc9ebdcff786f5 SHA512 ffc34b9832ca38df5bf27aa8900b24007d6f218091896dd8c6eb70cfbd9892894d5398e47020391eb8d821bb0d6b8b79bc117b8ac35470b1727ab5866f740fa6
+EBUILD mpd-0.23.16.ebuild 7913 BLAKE2B f7d70dd8e8b29c91740803ea09bda59d137cc326b8a107eb67b98ded9cef5e2c67f89a2c6a9be1deb30df78bf1c7492df1ccdff260ce8346aa3d18326e4cc261 SHA512 4d8a72c1971003750de8848323f21f67a7e1a91697b834da0c872e01b1f60d2f07143b8dacec6258bd4041188833d1a47db6472da5a94af9614b4075d6abef27
 MISC metadata.xml 2980 BLAKE2B 26a685df9b51366dcd49c25068222a5e87837fba5ff9d1854fca8452bc4b9a9d47163b10a985f56621b66c24d51259f1a690eaeba7c9926bbcda1f87c597c6e4 SHA512 2554bb4b643c222fa647fbf717687d58d55c0f8473265da0f0790c5200e93a98c69a58fcef6e8840e88a704ea2bd7d899af2324c50c8591ebbc7604fa14e97dd
diff --git a/media-sound/mpd/mpd-0.23.16.ebuild b/media-sound/mpd/mpd-0.23.16.ebuild
new file mode 100644
index 000000000000..4946911eee31
--- /dev/null
+++ b/media-sound/mpd/mpd-0.23.16.ebuild
@@ -0,0 +1,301 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic linux-info meson systemd xdg
+
+DESCRIPTION="The Music Player Daemon (mpd)"
+HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
+SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/mpd-0.23.15.16-fix-libfmt-11.1.0.patch.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+alsa ao +audiofile bzip2 cdio chromaprint +cue +curl doc +dbus
+	+eventfd expat faad +ffmpeg +fifo flac fluidsynth gme +icu +id3tag +inotify +io-uring
+	jack lame libmpdclient libsamplerate libsoxr +mad mikmod mms
+	modplug mpg123 musepack +network nfs openal openmpt opus oss pipe pipewire pulseaudio qobuz
+	recorder samba selinux sid signalfd snapcast sndfile sndio soundcloud sqlite systemd
+	test twolame udisks vorbis wavpack webdav wildmidi upnp
+	yajl zeroconf zip zlib"
+
+OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pipewire pulseaudio snapcast sndio recorder"
+DECODER_PLUGINS="audiofile faad ffmpeg flac fluidsynth mad mikmod
+	modplug mpg123 musepack opus openmpt flac sid vorbis wavpack wildmidi"
+ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
+
+REQUIRED_USE="
+	|| ( ${OUTPUT_PLUGINS} )
+	|| ( ${DECODER_PLUGINS} )
+	network? ( || ( ${ENCODER_PLUGINS} ) )
+	recorder? ( || ( ${ENCODER_PLUGINS} ) )
+	qobuz? ( curl soundcloud )
+	snapcast? ( yajl )
+	soundcloud? ( curl qobuz yajl )
+	udisks? ( dbus )
+	upnp? ( curl expat )
+	webdav? ( curl expat )
+"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	acct-user/mpd
+	dev-libs/libfmt:=
+	dev-libs/libpcre2:=
+	media-libs/libogg
+	alsa? (
+		media-libs/alsa-lib
+		media-sound/alsa-utils
+	)
+	ao? ( media-libs/libao[alsa?,pulseaudio?] )
+	audiofile? ( media-libs/audiofile:= )
+	bzip2? ( app-arch/bzip2 )
+	cdio? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia:=
+	)
+	chromaprint? ( media-libs/chromaprint:= )
+	curl? ( net-misc/curl )
+	dbus? ( sys-apps/dbus )
+	doc? ( dev-python/sphinx )
+	expat? ( dev-libs/expat )
+	faad? ( media-libs/faad2 )
+	ffmpeg? ( media-video/ffmpeg:= )
+	flac? ( media-libs/flac:= )
+	fluidsynth? ( media-sound/fluidsynth:= )
+	gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
+	icu? (
+		>=dev-libs/icu-50:=
+		virtual/libiconv
+	)
+	id3tag? ( media-libs/libid3tag:= )
+	io-uring? ( sys-libs/liburing:= )
+	jack? ( virtual/jack )
+	lame? ( network? ( media-sound/lame ) )
+	libmpdclient? ( media-libs/libmpdclient )
+	libsamplerate? ( media-libs/libsamplerate )
+	libsoxr? ( media-libs/soxr )
+	mad? ( media-libs/libmad )
+	mikmod? ( media-libs/libmikmod )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mpg123? ( media-sound/mpg123-base )
+	musepack? ( media-sound/musepack-tools )
+	network? ( >=media-libs/libshout-2.4.0 )
+	nfs? ( net-fs/libnfs:= )
+	openal? ( media-libs/openal )
+	openmpt? ( media-libs/libopenmpt )
+	opus? ( media-libs/opus )
+	pulseaudio? ( media-libs/libpulse )
+	pipewire? ( media-video/pipewire:= )
+	qobuz? (
+		|| (
+			dev-libs/libgcrypt
+			media-video/ffmpeg
+		)
+	)
+	samba? ( net-fs/samba:= )
+	selinux? ( sec-policy/selinux-mpd )
+	sid? ( || (
+		media-libs/libsidplay:2
+		media-libs/libsidplayfp
+	) )
+	snapcast? ( media-sound/snapcast )
+	sndfile? ( media-libs/libsndfile )
+	sndio? ( media-sound/sndio:= )
+	sqlite? ( dev-db/sqlite:3 )
+	systemd? ( sys-apps/systemd:= )
+	twolame? ( media-sound/twolame )
+	udisks? ( sys-fs/udisks:2 )
+	upnp? ( net-libs/libupnp:= )
+	vorbis? ( media-libs/libvorbis )
+	wavpack? ( media-sound/wavpack )
+	wildmidi? ( media-sound/wildmidi )
+	yajl? ( >=dev-libs/yajl-2:= )
+	zeroconf? ( net-dns/avahi[dbus] )
+	zip? ( dev-libs/zziplib:= )
+	zlib? ( sys-libs/zlib:= )
+"
+
+DEPEND="
+	${RDEPEND}
+	dev-libs/boost:=
+	test? ( dev-cpp/gtest )
+"
+
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${WORKDIR}"/mpd-0.23.15.16-fix-libfmt-11.1.0.patch
+)
+
+pkg_setup() {
+	if use eventfd; then
+		CONFIG_CHECK+=" ~EVENTFD"
+		ERROR_EVENTFD="${P} requires eventfd in-kernel support."
+	fi
+
+	if use signalfd; then
+		CONFIG_CHECK+=" ~SIGNALFD"
+		ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
+	fi
+
+	if use inotify; then
+		CONFIG_CHECK+=" ~INOTIFY_USER"
+		ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
+	fi
+
+	if use io-uring; then
+		CONFIG_CHECK+=" ~IO_URING"
+		ERROR_IO_URING="${P} requires io-uring in-kernel support."
+	fi
+
+	if use eventfd || use signalfd || use inotify || use io-uring; then
+		linux-info_pkg_setup
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		# media-libs/adplug is not packaged anymore
+		-Dadplug=disabled
+		$(meson_feature alsa)
+		$(meson_feature ao)
+		$(meson_feature audiofile)
+		$(meson_feature bzip2)
+		$(meson_feature cdio cdio_paranoia)
+		$(meson_feature chromaprint)
+		$(meson_use cue)
+		$(meson_feature curl)
+		$(meson_feature dbus)
+		$(meson_use eventfd)
+		$(meson_feature expat)
+		$(meson_feature faad)
+		$(meson_feature ffmpeg)
+		$(meson_use fifo)
+		$(meson_feature flac)
+		$(meson_feature fluidsynth)
+		$(meson_feature gme)
+		$(meson_feature icu)
+		$(meson_feature id3tag)
+		$(meson_use inotify)
+		-Dipv6=enabled
+		$(meson_feature cdio iso9660)
+		$(meson_feature io-uring io_uring)
+		$(meson_feature jack)
+		$(meson_feature libmpdclient)
+		$(meson_feature libsamplerate)
+		$(meson_feature mad)
+		$(meson_feature mikmod)
+		$(meson_feature mms)
+		$(meson_feature modplug)
+		$(meson_feature musepack mpcdec)
+		$(meson_feature mpg123)
+		$(meson_feature nfs)
+		$(meson_feature openal)
+		$(meson_feature openmpt)
+		$(meson_feature opus)
+		$(meson_feature oss)
+		$(meson_use pipe)
+		$(meson_feature pipewire)
+		$(meson_feature pulseaudio pulse)
+		$(meson_feature qobuz)
+		$(meson_use recorder)
+		$(meson_use signalfd)
+		$(meson_feature samba smbclient)
+		$(meson_use snapcast)
+		$(meson_feature sid sidplay)
+		$(meson_feature sndfile)
+		$(meson_feature sndio)
+		$(meson_feature soundcloud)
+		$(meson_feature libsoxr soxr)
+		$(meson_feature sqlite)
+		$(meson_feature systemd)
+		$(meson_use test)
+		$(meson_feature udisks)
+		-Dupnp=$(usex upnp pupnp disabled)
+		$(meson_feature vorbis)
+		$(meson_feature wavpack)
+		$(meson_feature wildmidi)
+		$(meson_feature webdav)
+		$(meson_feature yajl)
+		-Dzeroconf=$(usex zeroconf avahi disabled)
+		$(meson_feature zlib)
+		$(meson_feature zip zzip)
+
+		--libdir="/usr/$(get_libdir)"
+		$(meson_feature doc documentation)
+		-Dsolaris_output=disabled
+
+		-Ddatabase=true
+		-Ddaemon=true
+		-Ddsd=true
+		-Dtcp=true
+
+		-Dsystemd_system_unit_dir="$(systemd_get_systemunitdir)"
+		-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
+
+		$(meson_feature icu iconv)
+	)
+
+	if use samba || use upnp; then
+		emesonargs+=( -Dneighbor=true )
+	fi
+
+	append-lfs-flags
+	append-ldflags "-L${ESYSROOT}/usr/$(get_libdir)/sidplay/builders"
+
+	if use network; then
+		emesonargs+=(
+			-Dshine=disabled
+			-Dshout=enabled
+			$(meson_feature vorbis vorbisenc)
+			-Dhttpd=true
+			$(meson_feature lame)
+			$(meson_feature twolame)
+			$(meson_use audiofile wave_encoder)
+		)
+	fi
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	insinto /etc
+	newins doc/mpdconf.example mpd.conf
+
+	# When running MPD as system service, better switch to the user we provide
+	sed -i \
+		-e 's:^#user.*$:user "mpd":' \
+		-e 's:^#group.*$:group "audio":' \
+		"${ED}/etc/mpd.conf" || die
+
+	if ! use systemd; then
+		# Extra options for running MPD under OpenRC
+		# (options that should not be set when using systemd)
+		sed -i \
+			-e 's:^#log_file.*$:log_file "/var/log/mpd/mpd.log":' \
+			-e 's:^#pid_file.*$:pid_file "/run/mpd/mpd.pid":' \
+			"${ED}/etc/mpd.conf" || die
+	fi
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}-0.23.15.logrotate" "${PN}"
+
+	newinitd "${FILESDIR}/${PN}-0.23.15.init-r1" "${PN}"
+
+	keepdir /var/lib/mpd
+	keepdir /var/lib/mpd/music
+	keepdir /var/lib/mpd/playlists
+	keepdir /var/log/mpd
+
+	rm -r "${ED}"/usr/share/doc/mpd || die
+
+	fowners mpd:audio -R /var/lib/mpd
+	fowners mpd:audio -R /var/log/mpd
+}