gentoo resync : 15.06.2021

1 files changed, 46 insertions, 0 deletions

diff --git a/media-sound/whipper/whipper-0.10.0.ebuild b/media-sound/whipper/whipper-0.10.0.ebuild
new file mode 100644
index 000000000000..964e6c65cd23
--- /dev/null
+++ b/media-sound/whipper/whipper-0.10.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="A Python CD-DA ripper preferring accuracy over speed (forked from morituri)"
+HOMEPAGE="https://github.com/whipper-team/whipper"
+SRC_URI="https://github.com/whipper-team/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+DEPEND="media-libs/libsndfile:="
+RDEPEND="
+	${DEPEND}
+	app-cdr/cdrdao
+	>=dev-libs/libcdio-paranoia-0.94_p2
+	>=dev-python/pycdio-2.1.0[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/python-discid[${PYTHON_USEDEP}]
+	dev-python/python-musicbrainz-ngs[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	media-libs/mutagen[${PYTHON_USEDEP}]
+	media-sound/sox[flac]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	test? ( dev-python/twisted[${PYTHON_USEDEP}] )"
+
+distutils_enable_tests unittest
+
+PATCHES=( "${FILESDIR}/${PN}-0.7.0-cdparanoia-name-fix.patch" )
+
+python_prepare_all() {
+	# accurip test totally depends on network access
+	rm "${PN}"/test/test_common_accurip.py || die
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+
+	distutils-r1_python_prepare_all
+}