gentoo resync : 11.02.2018

3 files changed, 299 insertions, 2 deletions

diff --git a/media-sound/xmms2/Manifest b/media-sound/xmms2/Manifest
index 25be52644a0b..3e1c60bd7385 100644
--- a/media-sound/xmms2/Manifest
+++ b/media-sound/xmms2/Manifest
@@ -23,5 +23,6 @@ DIST xmms2-0.8DrO_o-949-gca15e830.tar.bz2 1928653 BLAKE2B f34abf0c68f4574593eb70
 DIST xmms2-0.8DrO_o.tar.bz2 1670726 BLAKE2B e226f197b09ebc205fa274d6a0024190e222314bc0df2c6cf443061b3961ca622bd0a1834dfee5c128aa2b003d4e703b5c4976ddc038d84d7f05c3e052060b0b SHA512 478103d80264c0cb32912e828f74d0f5b2f10fe310f530a87ebecda7ca547a69e238cd572788f90bda29494494160d459fa6d1356b4fb87c7a8f0bf02e3b75f8
 EBUILD xmms2-0.8-r4.ebuild 7875 BLAKE2B eb19ec1826e269c446706a1c467f5201b292786672b249d18e7d04c37d1e0c7ebf43f2a25381df7ac170286db5328a83acbdc92d081672ed05d5d3423b8e82f3 SHA512 02272a12bec6a7c65522acf08a9174e34fa80af8ee01c551aa870c370e7c4802946fc56f3d7ef0ee441cf9c9f6ffc34147b4c6dbed8bd60af34b0cc65b68c0cc
 EBUILD xmms2-0.8_p20161122-r1.ebuild 7566 BLAKE2B deca0e3471553bf5d346a9338a3aa0fda6b4a2e23f5966575a5ae1184cb87c2b06fc52869b1d5c8aaddf9aa9211e39c08f2e45e30638cc3d1a0e0ea2abd4057b SHA512 e04abc582528c18a2dd45224280458ea1999be0659ec68b9d7d63938bba1bc513c88a378d72aaf2780d39bf8d98e4f8ddd75d64b135826fab813e750bfe3631e
+EBUILD xmms2-0.8_p20161122-r2.ebuild 7531 BLAKE2B 384cc2e5f938bbe842518c9a520eb357d2eeda24b185fe06cffd6f0e395309cfdea26f3daac2444945b7c740762a2ec569a76278d27c7d1f0907fe53b6d9f7be SHA512 a6163a73800122a6860ad9fd4c4e708ddcbde3555e47b232e88fed81e1f4dabc41e52a046504073b8128a0af5442440b8b00c59eb33cafa9cd823b05f8573b24
 EBUILD xmms2-0.8_p20161122.ebuild 7396 BLAKE2B 7b1eaa463c899ce5d0a2c6cb18e8529b77075cdc205bcc06234f39d74f5ebaf47f06a47f1a35d96031592ae62fb329e8e15aa3861ca522ca1e03e48c74b2fb7f SHA512 7a9c795d826171d5ce9cd24ebe2b385967803a7ca2ee8b7d082c71a5255ded6485f3e6e96c0d4b648d8efdd03f191202296e7990b068dba2b1bb25a0b7bb51c9
-MISC metadata.xml 2667 BLAKE2B 7c5324e6c9ba6f3df5f6a3fb6d7cedb7abf62d1a29684f82843bae821da161230ee4c0292e23e6004f99260485911d5d0365c58e95dd3d5d85357df83fa3876a SHA512 1f096499b2a77e2c07d64d4ad562d316c7687d6d2335b720bcc60bc710d61b3278db331f68c05c3ad400176ca27cf4c7ea0c89886ea0d0ad4a30ee032ab4c996
+MISC metadata.xml 2619 BLAKE2B db882bae1912243670ae3f8a075704ac0398f50a66f0ce990b4283b26b0c99846ea4d491375d9d920b320bb49da9ced1209bcfc86dd341f1e4cbc0a3649bd38d SHA512 f4477bdfc7575b104a7852dfcc789178631c0f0b470a968af7b763c8b7d70ab6cea8a4ff739b3b9adea280838cc5d8cb773337d899b20ecc0797a9d16ef38e97
diff --git a/media-sound/xmms2/metadata.xml b/media-sound/xmms2/metadata.xml
index 4072327e4cf2..551b4bd98e80 100644
--- a/media-sound/xmms2/metadata.xml
+++ b/media-sound/xmms2/metadata.xml
@@ -4,7 +4,6 @@
 	<maintainer type="person">
 		<email>slyfox@gentoo.org</email>
 		<name>Sergei Trofimovich</name>
-		<description>Primary Maintainer</description>
 	</maintainer>
 	<longdescription>
 		It features a client-server model, allowing multiple (even simultaneous!) user
diff --git a/media-sound/xmms2/xmms2-0.8_p20161122-r2.ebuild b/media-sound/xmms2/xmms2-0.8_p20161122-r2.ebuild
new file mode 100644
index 000000000000..4471878ba156
--- /dev/null
+++ b/media-sound/xmms2/xmms2-0.8_p20161122-r2.ebuild
@@ -0,0 +1,297 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+USE_RUBY="ruby20 ruby21 ruby22"
+
+inherit eutils multiprocessing python-single-r1 ruby-single toolchain-funcs
+
+# generated as 'python2 ./utils/gen-tarball.py' from clean git tree
+MY_P="${P%_p*}DrO_o-949-gca15e830"
+
+DESCRIPTION="X(cross)platform Music Multiplexing System. Next generation of the XMMS player"
+HOMEPAGE="https://xmms2.org/wiki/Main_Page"
+#SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.bz2"
+SRC_URI="https://dev.gentoo.org/~slyfox/distfiles/${MY_P}.tar.bz2"
+LICENSE="GPL-2 LGPL-2.1"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~x86"
+
+IUSE="aac airplay +alsa ao asf cdda curl cxx ffmpeg flac fluidsynth gvfs ices
+jack mac mlib-update mms +mad modplug mp3 mp4 musepack ofa opus oss
+perl phonehome pulseaudio python ruby samba +server sid sndfile speex
+test valgrind +vorbis vocoder wavpack xml zeroconf"
+
+RDEPEND="server? (
+		>=dev-db/sqlite-3.3.4
+
+		aac? ( >=media-libs/faad2-2.0 )
+		airplay? ( dev-libs/openssl:0= )
+		alsa? ( media-libs/alsa-lib )
+		ao? ( media-libs/libao )
+		cdda? ( dev-libs/libcdio-paranoia
+			>=media-libs/libdiscid-0.1.1
+			>=media-sound/cdparanoia-3.9.8 )
+		curl? ( >=net-misc/curl-7.15.1 )
+		ffmpeg? ( virtual/ffmpeg )
+		flac? ( media-libs/flac )
+		fluidsynth? ( media-sound/fluidsynth )
+		gvfs? ( gnome-base/gnome-vfs )
+		ices? ( media-libs/libogg
+			media-libs/libshout
+			media-libs/libvorbis )
+		jack? ( virtual/jack )
+		mac? ( media-sound/mac )
+		mms? ( virtual/ffmpeg
+			>=media-libs/libmms-0.3 )
+		modplug? ( media-libs/libmodplug )
+		mad? ( media-libs/libmad )
+		mp3? ( >=media-sound/mpg123-1.5.1 )
+		musepack? ( media-sound/musepack-tools )
+		ofa? ( media-libs/libofa )
+		opus? ( media-libs/opus
+			media-libs/opusfile )
+		pulseaudio? ( media-sound/pulseaudio )
+		samba? ( >=net-fs/samba-4.2 )
+		sid? ( media-sound/sidplay
+			media-libs/resid )
+		sndfile? ( media-libs/libsndfile )
+		speex? ( media-libs/speex
+			media-libs/libogg )
+		vorbis? ( media-libs/libvorbis )
+		vocoder? ( sci-libs/fftw:3.0= media-libs/libsamplerate )
+		wavpack? ( media-sound/wavpack )
+		xml? ( dev-libs/libxml2 )
+		zeroconf? ( net-dns/avahi[mdnsresponder-compat] )
+	)
+
+	>=dev-libs/glib-2.12.9
+	cxx? ( >=dev-libs/boost-1.32 )
+	perl? ( >=dev-lang/perl-5.8.8 )
+	python? ( ${PYTHON_DEPS} )
+	ruby? ( ${RUBY_DEPS} )
+"
+
+DEPEND="${RDEPEND}
+	dev-lang/python
+	virtual/pkgconfig
+	perl? ( dev-perl/Module-Build
+		virtual/perl-Module-Metadata )
+	python? ( >=dev-python/cython-0.15.1
+		dev-python/pyrex )
+	test? ( dev-util/cunit
+		valgrind? ( dev-util/valgrind ) )
+"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	# used both for building xmms2 and
+	# optionally linking client library
+	# against python
+	python-single-r1_pkg_setup
+}
+
+# use_enable() is taken as proto
+# $1 - useflag
+# $2 - xmms2 option/plugin name (equals to $1 if not set)
+
+xmms2_flag() {
+	[[ -z $1 ]] && eerror "!!! empty arg. usage: xmms2_flag <USEFLAG> [<xmms2_flagname>]."
+
+	local UWORD=${2:-$1}
+
+	case $1 in
+		ENABLED)
+			echo ",${UWORD}"
+			;;
+		DISABLED)
+			;;
+		*)
+			use $1 && echo ",${UWORD}"
+			;;
+	esac
+}
+
+src_prepare() {
+	./waf # inflate waf
+	cd .waf* || die
+	# needs port
+	#epatch "${FILESDIR}/${PN}"-0.8DrO_o-waflib-fix-perl.patch #578778
+	cd "${S}"
+
+	eapply "${FILESDIR}/${PN}"-0.8-ffmpeg2.patch #536232
+
+	eapply "${FILESDIR}/${PN}"-0.8-rtvg.patch #424377
+
+	# required to build tarball from git tree
+	eapply "${FILESDIR}/${P}"-tarball.patch
+
+	# fix hash to be the same on LE/BE platforms
+	eapply "${FILESDIR}/${P}"-be-hash.patch
+
+	# handle mac-3 -> -4 API change
+	eapply "${FILESDIR}/${P}"-mac-4.patch
+
+	eapply_user
+}
+
+src_configure() {
+	# ./configure alike options.
+	local waf_params="--prefix=/usr \
+			--libdir=/usr/$(get_libdir) \
+			--with-target-platform=${CHOST} \
+			--mandir=/usr/share/man \
+			--infodir=/usr/share/info \
+			--datadir=/usr/share \
+			--sysconfdir=/etc \
+			--localstatedir=/var/lib"
+
+	local optionals=""
+	local plugins=""
+	if ! use server ; then
+		waf_params+=" --without-xmms2d"
+	else
+		# some fun static mappings:
+		local option_map=(	# USE		# sorted xmms2 option flag (same, as USE if empty)
+					"phonehome	et"
+					"ENABLED	launcher"
+					"mlib-update	medialib-updater"
+					"ENABLED	nycli"
+					"		perl"
+					"ENABLED	pixmaps"
+					"		python"
+					"		ruby"
+					"DISABLED	tests"
+					"DISABLED	vistest"
+					"cxx		xmmsclient++"
+					"cxx		xmmsclient++-glib"
+					"DISABLED	xmmsclient-cf"
+					"DISABLED	xmmsclient-ecore" # not in tree
+
+					"test		tests"
+				)
+
+		local plugin_map=(	# USE		# sorted xmms2 plugin flag (same, as USE if empty)
+					"		alsa"
+					"		airplay"
+					"		ao"
+					"ffmpeg		apefile"
+					"ffmpeg		avcodec"
+					"		asf"
+					"ENABLED	asx"
+					"		cdda"
+					"DISABLED	coreaudio" # MacOS only?
+					"		curl"
+					"ENABLED	cue"
+					"zeroconf	daap"
+					"ENABLED	diskwrite"
+					"ENABLED	equalizer"
+					"aac		faad"
+					"ENABLED	file"
+					"		flac"
+					"		fluidsynth"
+					"ffmpeg		flv"
+					"ffmpeg		tta"
+					"DISABLED	gme" # not in tree
+					"		gvfs"
+					"ENABLED	html"
+					"		ices"
+					"ENABLED	icymetaint"
+					"ENABLED	id3v2"
+					"		jack"
+					"ENABLED	karaoke"
+					"ENABLED	m3u"
+					"		mac"
+					"		mms"
+					"		mad"
+					"ENABLED	midsquash"
+					"		mp4" # bug #387961 (aac, mp3, ape can sit there)
+					"mp3		mpg123"
+					"		modplug"
+					"		musepack"
+					"DISABLED	nms" # not in tree
+					"ENABLED	normalize"
+					"ENABLED	null"
+					"ENABLED	nulstripper"
+					"		ofa"
+					"		opus"
+					"		oss"
+					"ENABLED	pls"
+					"pulseaudio	pulse"
+					"ENABLED	replaygain"
+					"xml		rss"
+					"		samba"
+					"DISABLED	sc68" #not in tree
+					"		sid"
+					"		sndfile"
+					"		speex"
+					"DISABLED	sun" # {Open,Net}BSD only
+					"DISABLED	tremor" # not in tree
+					"		vorbis"
+					"		vocoder"
+					"ffmpeg		tta"
+					"ENABLED	wave"
+					"DISABLED	waveout" # windows only
+					"		wavpack"
+					"xml		xspf"
+					"ENABLED	xml"
+				)
+
+		local option
+		for option in "${option_map[@]}"; do
+			optionals+=$(xmms2_flag $option)
+		done
+
+		local plugin
+		for plugin in "${plugin_map[@]}"; do
+			plugins+=$(xmms2_flag $plugin)
+		done
+	fi # ! server
+
+	# pass them explicitely even if empty as we try to avoid magic deps
+	waf_params+=" --with-optionals=${optionals:1}" # skip first ',' if yet
+	waf_params+=" --with-plugins=${plugins:1}"
+	waf_params+=" $(use_with valgrind)"
+
+	CC="$(tc-getCC)"         \
+	CPP="$(tc-getCPP)"       \
+	AR="$(tc-getAR)"         \
+	RANLIB="$(tc-getRANLIB)" \
+	CXX="$(tc-getCXX)"       \
+	    ./waf configure ${waf_params} || die "'waf configure' failed"
+}
+
+src_compile() {
+	# waf is very keen to run tests in build phase (bug #424377) but
+	# it does not bother running tests twice, so the hack below works:
+	./waf --verbose build || ./waf --verbose build || die "waf build failed"
+}
+
+src_test() {
+	# rerun tests
+	./waf --alltests || die "waf --alltests failed"
+}
+
+src_install() {
+	./waf --without-ldconfig --destdir="${D}" install || die "'waf install' failed"
+	dodoc AUTHORS TODO
+}
+
+pkg_postinst() {
+	elog "This version is built on experimental development code"
+	elog "If you encounter any errors report them at https://bugs.xmms2.org"
+	elog "and visit #xmms2 at irc://irc.freenode.net"
+	if use phonehome ; then
+		einfo ""
+		einfo "The phone-home client xmms2-et was activated"
+		einfo "This client sends anonymous usage-statistics to the xmms2"
+		einfo "developers which may help finding bugs"
+		einfo "Disable the phonehome useflag if you don't like that"
+	fi
+}