gentoo auto-resync : 18:04:2024 - 12:04:39

2 files changed, 277 insertions, 0 deletions

diff --git a/media-video/mpv/Manifest b/media-video/mpv/Manifest
index 0e322c34c46c..b2efb3c80e17 100644
--- a/media-video/mpv/Manifest
+++ b/media-video/mpv/Manifest
@@ -1,7 +1,9 @@
 AUX mpv-0.37.0-drm-fix.patch 1444 BLAKE2B e0645e9b12ebbd0088b10aed34cabadbdb1b06d9cab14c40e9108c09d068c1ccba133dd91ba4c1d0735c67d0a8010003c77b85466343504cb220498fa24ac964 SHA512 8ce946f6043abb274b3051e787f5445ad40a3ea404cb2effcf9a4415a589483861381e54762e31f72d03c4975d01b67b662b6fb8a8a9194d7cd7d8acb4cab084
 AUX mpv-0.37.0-ffmpeg7.patch 1656 BLAKE2B 05826bd93c8c63d8114195a9ba595d93ce3fc9a03cc09c4dff364ca72f7ce934576c76b5841b0f45db4e9a85796ced590d2bf2cb34c22774ecbb87f75a383f43 SHA512 3a387c8b985a5aa02c1f7d4d1fba776731a820f057a9121d0ea6f2e95336755fdf3144c3f826ea452c6a5e135e006e3636f0b12c1c02ae6bd5f1eead36018d92
 DIST mpv-0.37.0.tar.gz 3384190 BLAKE2B 31d8d47ed7ae94540189fe05b7ea63f5b0d5c987a22191f931e4bd90664d05dca4c7e0bd0e05fcdf48b977e38e5f8eec0d2572265f2cf4a969a8a9a9dbf83d68 SHA512 a2f7fb3837312ec59c50427af7be3b2b1b6175a53ccc7463e81503284fc4047dff32cb105d665d80be77ee1ae775d4512b71584f324d6d202c9a7fc1fab53257
+DIST mpv-0.38.0.tar.gz 3419741 BLAKE2B 3ff59d30bc305394f58a1fff4f24540aa3be9412bc3cad27bec0c3478f4b7c13190e26847f38edc52996bb9f9a36dd6832c6fccebd6d873058acf78a320e42e4 SHA512 b5b2af59039ef4711814f94bbdfedb37f8ce914301670e42d4ed05fe1900025a3d3a2f3d5e69628a8aad115a647a27c386718959e2df1a18740468b3a84f8975
 EBUILD mpv-0.37.0-r1.ebuild 7034 BLAKE2B c951ca2938728125be40ae09e176e9cd1b489f15895ca4321b6221c93d3694f6e1fcf90e833ba4999bdf3eaa7930eb40c39d8625489a9ac28d28816e0a20cf36 SHA512 267e971f5717e7299b833adc0f974dcafa55695d3fb137cafbe4533f67bb1b6d59c318fe68d4506e81f1c4fac93e9be05dcb3d30724219bd5f80db1e4c1f0d56
 EBUILD mpv-0.37.0.ebuild 7087 BLAKE2B 322689b3988e47e41ae050e596518ca46d9f12048568d5d8920c98fe92f48adc28430a6fd92734cbf06ee9d01c74dea7f6aed133a9c8eb7aed50e2ffd2b5c0fb SHA512 b38640e3fae2cdaa8db042779516ce4143af50162af42548e49129c259d44bf76b217744d8541a7cc223f4385f1f9c55ba2fc8e7ea1c257a9034994a3b7f859d
+EBUILD mpv-0.38.0.ebuild 6881 BLAKE2B d440452a44439fb4f0a74ff6a3e221a98c80b8a910a5f0230fd8425c34580f4f4fdcf0a3a587f92d564e207d4db087952e7aa99815b60bc82ab52dc970395bda SHA512 c20624072cc97e353589793e1fee3da0edc49fc95d041c67cfa396fa54fe1bebd166425d5f51a17b81cc5045c9d8307e59673fe820f01e965c6b4a74def90087
 EBUILD mpv-9999.ebuild 6881 BLAKE2B d440452a44439fb4f0a74ff6a3e221a98c80b8a910a5f0230fd8425c34580f4f4fdcf0a3a587f92d564e207d4db087952e7aa99815b60bc82ab52dc970395bda SHA512 c20624072cc97e353589793e1fee3da0edc49fc95d041c67cfa396fa54fe1bebd166425d5f51a17b81cc5045c9d8307e59673fe820f01e965c6b4a74def90087
 MISC metadata.xml 2248 BLAKE2B 384962e209948418c928a4a8d903f57a226116929db253847e7977d0febbf3fc23b18f947e9896b5a16e816267eb06c0e64145fc15270f66dca4fe7321c36897 SHA512 c4f1191adacde565a5d6ff6fdf10a9dedc84fae3d04792baac456e37fabcd80f04858031f442dcf1dd07c3d59e2343319c955969b23d0aef456c2d927a76bcbf
diff --git a/media-video/mpv/mpv-0.38.0.ebuild b/media-video/mpv/mpv-0.38.0.ebuild
new file mode 100644
index 000000000000..a79aeac37bd3
--- /dev/null
+++ b/media-video/mpv/mpv-0.38.0.ebuild
@@ -0,0 +1,275 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LUA_COMPAT=( lua5-1 luajit )
+PYTHON_COMPAT=( python3_{10..12} )
+inherit flag-o-matic lua-single meson optfeature pax-utils python-single-r1 xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/mpv-player/mpv.git"
+else
+	SRC_URI="https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux"
+fi
+
+DESCRIPTION="Media player for the command line"
+HOMEPAGE="https://mpv.io/"
+
+LICENSE="LGPL-2.1+ GPL-2+ BSD ISC MIT" #506946
+SLOT="0/2" # soname
+IUSE="
+	+X +alsa aqua archive bluray cdda +cli coreaudio debug +drm dvb
+	dvd +egl gamepad +iconv jack javascript jpeg lcms libcaca +libmpv
+	+lua nvenc openal opengl pipewire pulseaudio rubberband sdl selinux
+	sixel sndio soc test tools +uchardet vaapi vdpau vulkan wayland xv
+	zimg zlib
+"
+REQUIRED_USE="
+	${PYTHON_REQUIRED_USE}
+	|| ( cli libmpv )
+	egl? ( || ( X drm wayland ) )
+	lua? ( ${LUA_REQUIRED_USE} )
+	nvenc? ( || ( egl opengl vulkan ) )
+	opengl? ( || ( X aqua ) )
+	test? ( cli )
+	tools? ( cli )
+	uchardet? ( iconv )
+	vaapi? ( || ( X drm wayland ) )
+	vdpau? ( X )
+	vulkan? ( || ( X wayland ) )
+	xv? ( X )
+"
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	media-libs/libass:=[fontconfig]
+	>=media-libs/libplacebo-6.338.2:=[opengl?,vulkan?]
+	>=media-video/ffmpeg-4.4:=[encode,soc(-)?,threads,vaapi?,vdpau?]
+	X? (
+		x11-libs/libX11
+		x11-libs/libXScrnSaver
+		x11-libs/libXext
+		x11-libs/libXpresent
+		x11-libs/libXrandr
+		xv? ( x11-libs/libXv )
+	)
+	alsa? ( media-libs/alsa-lib )
+	archive? ( app-arch/libarchive:= )
+	bluray? ( media-libs/libbluray:= )
+	cdda? (
+		dev-libs/libcdio-paranoia:=
+		dev-libs/libcdio:=
+	)
+	drm? (
+		x11-libs/libdrm
+		egl? ( media-libs/mesa[gbm(+)] )
+	)
+	dvd? (
+		media-libs/libdvdnav
+		media-libs/libdvdread:=
+	)
+	egl? (
+		media-libs/libglvnd
+		media-libs/libplacebo[opengl]
+	)
+	gamepad? ( media-libs/libsdl2[joystick] )
+	iconv? (
+		virtual/libiconv
+		uchardet? ( app-i18n/uchardet )
+	)
+	jack? ( virtual/jack )
+	javascript? ( dev-lang/mujs:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	lcms? ( media-libs/lcms:2 )
+	libcaca? ( media-libs/libcaca )
+	lua? ( ${LUA_DEPS} )
+	openal? ( media-libs/openal )
+	opengl? ( media-libs/libglvnd[X?] )
+	pipewire? ( media-video/pipewire:= )
+	pulseaudio? ( media-libs/libpulse )
+	rubberband? ( media-libs/rubberband )
+	sdl? ( media-libs/libsdl2[sound,threads,video] )
+	sixel? ( media-libs/libsixel )
+	sndio? ( media-sound/sndio:= )
+	vaapi? ( media-libs/libva:=[X?,drm(+)?,wayland?] )
+	vdpau? ( x11-libs/libvdpau )
+	vulkan? ( media-libs/vulkan-loader[X?,wayland?] )
+	wayland? (
+		dev-libs/wayland
+		dev-libs/wayland-protocols
+		x11-libs/libxkbcommon
+	)
+	zimg? ( media-libs/zimg )
+	zlib? ( sys-libs/zlib:= )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	selinux? ( sec-policy/selinux-mplayer )
+	tools? ( ${PYTHON_DEPS} )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	X? ( x11-base/xorg-proto )
+	dvb? ( sys-kernel/linux-headers )
+	nvenc? ( media-libs/nv-codec-headers )
+	wayland? ( dev-libs/wayland-protocols )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	cli? ( dev-python/docutils )
+	wayland? ( dev-util/wayland-scanner )
+"
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	if use !debug; then
+		if use test; then
+			einfo "Skipping -DNDEBUG due to USE=test"
+		else
+			append-cppflags -DNDEBUG # treated specially
+		fi
+	fi
+
+	mpv_feature_multi() {
+		local use set
+		for use in ${1} ${2}; do
+			use ${use} || set=disabled
+		done
+		echo -D${3-${2}}=${set-enabled}
+	}
+
+	local emesonargs=(
+		$(meson_use cli cplayer)
+		$(meson_use libmpv)
+		$(meson_use test tests)
+
+		$(meson_feature cli html-build)
+		$(meson_feature cli manpage-build)
+		-Dpdf-build=disabled
+
+		-Dbuild-date=false
+
+		# misc options
+		$(meson_feature archive libarchive)
+		$(meson_feature bluray libbluray)
+		$(meson_feature cdda)
+		-Dcplugins=enabled
+		$(meson_feature dvb dvbin)
+		$(meson_feature dvd dvdnav)
+		$(meson_feature gamepad sdl2-gamepad)
+		$(meson_feature iconv)
+		$(meson_feature javascript)
+		-Dlibavdevice=enabled
+		$(meson_feature lcms lcms2)
+		-Dlua=$(usex lua "${ELUA}" disabled)
+		$(meson_feature rubberband)
+		-Dsdl2=$(use gamepad || use sdl && echo enabled || echo disabled) #857156
+		$(meson_feature uchardet)
+		-Dvapoursynth=disabled # only available in overlays
+		$(meson_feature zimg)
+		$(meson_feature zlib)
+
+		# audio output
+		$(meson_feature alsa)
+		$(meson_feature coreaudio)
+		$(meson_feature jack)
+		$(meson_feature openal)
+		$(meson_feature pipewire)
+		$(meson_feature pulseaudio pulse)
+		$(meson_feature sdl sdl2-audio)
+		$(meson_feature sndio)
+
+		# video output
+		$(meson_feature X x11)
+		$(meson_feature aqua cocoa)
+		$(meson_feature drm)
+		$(meson_feature jpeg)
+		$(meson_feature libcaca caca)
+		$(meson_feature sdl sdl2-video)
+		$(meson_feature sixel)
+		$(meson_feature wayland)
+		$(meson_feature xv)
+
+		-Dgl=$(use egl || use libmpv || use opengl &&
+			echo enabled || echo disabled)
+		$(meson_feature egl)
+		$(mpv_feature_multi egl X egl-x11)
+		$(mpv_feature_multi egl drm gbm) # gbm is only used by egl-drm
+		$(mpv_feature_multi egl drm egl-drm)
+		$(mpv_feature_multi egl wayland egl-wayland)
+		$(meson_feature libmpv plain-gl)
+		$(mpv_feature_multi opengl X gl-x11)
+		$(mpv_feature_multi opengl aqua gl-cocoa)
+
+		$(meson_feature vulkan)
+
+		# hardware decoding
+		$(meson_feature nvenc cuda-hwaccel)
+		$(meson_feature nvenc cuda-interop)
+
+		$(meson_feature vaapi)
+		$(mpv_feature_multi vaapi X vaapi-x11)
+		$(mpv_feature_multi vaapi drm vaapi-drm)
+		$(mpv_feature_multi vaapi wayland vaapi-wayland)
+
+		$(meson_feature vdpau)
+		$(mpv_feature_multi vdpau opengl vdpau-gl-x11)
+
+		$(mpv_feature_multi aqua opengl videotoolbox-gl)
+
+		# notable options left to automagic
+		#dmabuf-wayland: USE="drm wayland" + plus memfd_create support
+		#vulkan-interop: USE="vulkan" + >=ffmpeg-6.1
+		# TODO?: perhaps few more similar compound options should be left auto
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	# ffmpeg tests are picky and easily break without necessarily
+	# meaning that there are runtime issues (bug #921091,#924276)
+	meson_src_test --no-suite ffmpeg
+}
+
+src_install() {
+	meson_src_install
+
+	if use lua; then
+		insinto /usr/share/${PN}
+		doins -r TOOLS/lua
+
+		if use cli && use lua_single_target_luajit; then
+			pax-mark -m "${ED}"/usr/bin/${PN}
+		fi
+	fi
+
+	if use tools; then
+		dobin TOOLS/{mpv_identify.sh,umpv}
+		newbin TOOLS/idet.sh mpv_idet.sh
+		python_fix_shebang "${ED}"/usr/bin/umpv
+	fi
+
+	if use cli; then
+		dodir /usr/share/doc/${PF}/html
+		mv "${ED}"/usr/share/doc/{mpv,${PF}/html}/mpv.html || die
+		mv "${ED}"/usr/share/doc/{mpv,${PF}/examples} || die
+	fi
+
+	local GLOBIGNORE=*/*build*:*/*policy*
+	dodoc RELEASE_NOTES DOCS/*.{md,rst}
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "URL support with USE=lua" net-misc/yt-dlp
+}