gentoo auto-resync : 18:06:2024 - 00:10:02

2 files changed, 140 insertions, 0 deletions

diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index ccfd1c228790..e73e0a29d159 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,6 +1,8 @@
 DIST QMPlay2-src-24.04.07.tar.xz 2042608 BLAKE2B 234d21478c090566210f48e62247a22c11f68d7491938d3c59aa201999eb5e0dd54cb9040cf75c655ca0b2337003b7edbe9574e45fb5ca1293e505d0e9824884 SHA512 998929c825db6c92f8a4fa22e998e51ba2aa6d6742d678aef0c380e9131f4de4a9e49c7008b73f8c19b1c8048f17288dd895fc3cade12becb729e5d981e90eac
 DIST QMPlay2-src-24.05.23.tar.xz 2040496 BLAKE2B 98842880382629c0a014d048fa55308809a980c097867d9240321ca21733278439cedebc7a381793d8605f2c29108de6fa4c4ef8daf6261db9ea4248cf0d501b SHA512 a09419fb7f59c30923e51a0673aa219bfb9e9b461775d17c3ac0d683ab145e71f8ecabecee6ace9deb1e0681ea94b8c71682a014bb49d4ee85452e7bce53b390
+DIST QMPlay2-src-24.06.16.tar.xz 2042180 BLAKE2B ba076fc7cb6c77f16529d082690c4d994e53c62cdf994c1e35afdb5255b203d0ccc72db1195730be60471d5fff48deca47e1348b0b41f22e898818206f8c53bb SHA512 3a8a7b99c7861318cfe0a6e096a27bb86f64cfafacf4ec52bdc4e955dd320d6e0f369dcb466dfd9bb73f8d173a2fc768848e7356f03590e429ae30270daf176b
 EBUILD qmplay2-24.04.07.ebuild 3462 BLAKE2B 62cc62f2b9bf8b1fff24b3e61ea5ae53cbc0ed5c896c4c9732576f0f36cc8249ea075885f65de716b2d7d173efcbb22667e439c51f81c43853f90908fc59e799 SHA512 7ad8c3585df15e46335946545bd18fb8c272ac230c5721061830498c939fa15dd535d9fda7a04b24d3da863f3b65d7075a5995c1728afb3e0ba0429f022b718c
 EBUILD qmplay2-24.05.23.ebuild 3378 BLAKE2B 6cc5773edb049423e62502ea823991428a07d737d46a90f1a470ab3214cf7d82212f3706eef61a9981c0c8fa9405b7fcf95101f44cd4019d9c285da38da855f6 SHA512 c6d941954a4887457264c06fec0721b4ae152731bc344923fc77443b35bc38b71c8dc0e5852e7031ad5894359b880762abec56c5c1ebeea4e0bc683827c95c5a
+EBUILD qmplay2-24.06.16.ebuild 3378 BLAKE2B 6cc5773edb049423e62502ea823991428a07d737d46a90f1a470ab3214cf7d82212f3706eef61a9981c0c8fa9405b7fcf95101f44cd4019d9c285da38da855f6 SHA512 c6d941954a4887457264c06fec0721b4ae152731bc344923fc77443b35bc38b71c8dc0e5852e7031ad5894359b880762abec56c5c1ebeea4e0bc683827c95c5a
 EBUILD qmplay2-9999.ebuild 3378 BLAKE2B 6cc5773edb049423e62502ea823991428a07d737d46a90f1a470ab3214cf7d82212f3706eef61a9981c0c8fa9405b7fcf95101f44cd4019d9c285da38da855f6 SHA512 c6d941954a4887457264c06fec0721b4ae152731bc344923fc77443b35bc38b71c8dc0e5852e7031ad5894359b880762abec56c5c1ebeea4e0bc683827c95c5a
 MISC metadata.xml 1225 BLAKE2B 9fc74ea3d0319bc8822e0ff56968efcbe4ab40b758bfeca900883ed4dbbe80608a6954ffe95a1f61d0dd988ae88afd29d2c4485f3d62b2b839b9fea289fe3b72 SHA512 94f8b05578de759be210af0eb26f15d48e15112b07e586b6336737bd9cb3dd768c7dbefc3b667753239c10bdb1fa6ebdd39d5abe234742ead51f189bf63f8173
diff --git a/media-video/qmplay2/qmplay2-24.06.16.ebuild b/media-video/qmplay2/qmplay2-24.06.16.ebuild
new file mode 100644
index 000000000000..1bb22871659a
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-24.06.16.ebuild
@@ -0,0 +1,138 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio qt6 sid
+	shaders +taglib vaapi videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )
+"
+
+RDEPEND="
+	media-video/ffmpeg:=[vaapi?]
+	!qt6? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5[X(-),vulkan?]
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+		extensions? ( dev-qt/qtdeclarative:5 )
+		videofilters? ( dev-qt/qtconcurrent:5 )
+	)
+	qt6? (
+		dev-qt/qtbase:6[concurrent,dbus,gui,network,opengl?,ssl,vulkan?,widgets]
+		dev-qt/qt5compat:6
+		dev-qt/qtsvg:6
+		extensions? ( dev-qt/qtdeclarative:6 )
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? ( media-libs/libva[X] )
+	vulkan? ( >=media-libs/vulkan-loader-1.2.133 )
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	!qt6? ( dev-qt/linguist-tools:5 )
+	qt6? ( dev-qt/qttools:6[linguist] )
+"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=$(usex qt6)
+		# core
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_PM=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}