gentoo auto-resync : 23:10:2023 - 14:39:50

3 files changed, 142 insertions, 0 deletions

diff --git a/media-video/Manifest.gz b/media-video/Manifest.gz
index 77a43fb702bf..57510fa3dc48 100644
--- a/media-video/Manifest.gz
+++ b/media-video/Manifest.gz
diff --git a/media-video/qmplay2/Manifest b/media-video/qmplay2/Manifest
index 50d78758df67..0d37c04d6454 100644
--- a/media-video/qmplay2/Manifest
+++ b/media-video/qmplay2/Manifest
@@ -1,6 +1,8 @@
 DIST QMPlay2-src-23.08.22.tar.xz 1440292 BLAKE2B 9f563f1deaa65f8d452d7536a0c2b10f2ca74f8ac39318922bfe2e04feaad88f02234ba8efe0b110f7885383c212f857b20e6275a417d663af5c8911fd90412c SHA512 19648080f9bf7c7c982b637e2c1a5eeec7390604eee0e98dca96cf710f0df8e7ab71ac95bae64d01a5407357880467e05b0f91561f1f4b8f72773c85a5dba1ea
 DIST QMPlay2-src-23.09.05.tar.xz 1441076 BLAKE2B b3c0140bdb17b8dab079f3706e35f635d481e8e639c60145088a592c4e70ba760e6574d0febc96cdb7e38fc40585ff34d762319769c99043a295bb72e42bb8bc SHA512 9e214b58b14f1954f11ca85c4a06661da339df3724f9bede57e3c543a07df0c73dba4e9547a5d57c8c1fc2315d3ee51502ba9a22afca30e893a51424bc2a815e
+DIST QMPlay2-src-23.10.22.tar.xz 1442072 BLAKE2B 605c446c976d523df82f1cce70b4efff5ef630149acc61d453521dbe82af407612f9950d14e62295f325fcd8aa7c0fe3e46e0aa2193fa81123118d8fe14f081e SHA512 a32ee5e2c952777c21a28927d96fdaca9026c6b3f0586bb6d5d9c45b73604e5f7f505c0d076f611504e4ff20b339fde4997cfdb8c217940f1a7b414e1530381f
 EBUILD qmplay2-23.08.22.ebuild 3487 BLAKE2B ad6d134d559ec5572a51df99e05cd24698e556e75fde6e8829acbdca711e9e1f3f3f09c1e2671209bd2328614b7075f84dc62d889095a2be46df9676c91d1d10 SHA512 8e0b0a948c43ff02aea0e5aeacfaf4c2d30f7c5c095bf7fd05f79ce61b9ff52a89610f9cc9b563d167410d6c3e004efd57dd53c130347494ea4d130ca15542b2
 EBUILD qmplay2-23.09.05.ebuild 3468 BLAKE2B e6e6aead979834a9624aa9985be5397ba9a5a03119d60a738bde5886456b2e447ccb89617da5f32aa35c7393514001c2e4c550de4f5ac857a4ffda28e685e861 SHA512 6f21c58fe58731da0e923c8cd300efe0cbeb99707ebbca73c8e90ec00435ed66369fc669e683872ba5dd88841ca53b0f090f01ddf72b2558af92acb51fb22a33
+EBUILD qmplay2-23.10.22.ebuild 3468 BLAKE2B e6e6aead979834a9624aa9985be5397ba9a5a03119d60a738bde5886456b2e447ccb89617da5f32aa35c7393514001c2e4c550de4f5ac857a4ffda28e685e861 SHA512 6f21c58fe58731da0e923c8cd300efe0cbeb99707ebbca73c8e90ec00435ed66369fc669e683872ba5dd88841ca53b0f090f01ddf72b2558af92acb51fb22a33
 EBUILD qmplay2-9999.ebuild 3468 BLAKE2B e6e6aead979834a9624aa9985be5397ba9a5a03119d60a738bde5886456b2e447ccb89617da5f32aa35c7393514001c2e4c550de4f5ac857a4ffda28e685e861 SHA512 6f21c58fe58731da0e923c8cd300efe0cbeb99707ebbca73c8e90ec00435ed66369fc669e683872ba5dd88841ca53b0f090f01ddf72b2558af92acb51fb22a33
 MISC metadata.xml 1287 BLAKE2B f04c4032dd3f32f10e33c551d364a9914d7663448b293ab9161da4741f53e65438749c1cd14b2ab0f5dd6a231109763642e53932d2705170a7e063e594acae36 SHA512 3f480f4d3cff62300e8eed043f16fe2a0f5cb8572be5fa00710b86036b93650b852168b7e01c2611c95755205d1a33883d67dfb8fd187d87c459d923e77c9fbd
diff --git a/media-video/qmplay2/qmplay2-23.10.22.ebuild b/media-video/qmplay2/qmplay2-23.10.22.ebuild
new file mode 100644
index 000000000000..961b70b140c8
--- /dev/null
+++ b/media-video/qmplay2/qmplay2-23.10.22.ebuild
@@ -0,0 +1,140 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+DESCRIPTION="A Qt-based video player, which can play most formats and codecs"
+HOMEPAGE="https://github.com/zaps166/QMPlay2"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zaps166/QMPlay2"
+else
+	SRC_URI="https://github.com/zaps166/QMPlay2/releases/download/${PV}/QMPlay2-src-${PV}.tar.xz"
+	S="${WORKDIR}/QMPlay2-src-${PV}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="LGPL-3"
+SLOT="0"
+
+IUSE="avdevice +audiofilters +alsa cdio cuvid extensions gme inputs libass
+	modplug notifications opengl pipewire portaudio pulseaudio qt6 sid
+	shaders +taglib vaapi vdpau videofilters visualizations vulkan xv"
+
+REQUIRED_USE="
+	audiofilters? ( || ( alsa pipewire portaudio pulseaudio ) )
+	shaders? ( vulkan )
+"
+
+RDEPEND="
+	media-video/ffmpeg:=[vaapi?,vdpau?]
+	!qt6? (
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5[X(-),vulkan?]
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtx11extras:5
+		extensions? ( dev-qt/qtdeclarative:5 )
+		videofilters? ( dev-qt/qtconcurrent:5 )
+	)
+	qt6? (
+		dev-qt/qtbase:6[concurrent,dbus,gui,network,opengl?,ssl,vulkan?,widgets]
+		dev-qt/qt5compat:6
+		dev-qt/qtsvg:6
+		extensions? ( dev-qt/qtdeclarative:6 )
+	)
+	alsa? ( media-libs/alsa-lib )
+	cdio? ( dev-libs/libcdio[cddb] )
+	gme? ( media-libs/game-music-emu )
+	libass? ( media-libs/libass )
+	opengl? ( virtual/opengl )
+	pipewire? ( media-video/pipewire )
+	portaudio? ( media-libs/portaudio )
+	pulseaudio? ( media-libs/libpulse )
+	sid? ( media-libs/libsidplayfp )
+	shaders? ( >=media-libs/shaderc-2020.1 )
+	taglib? ( media-libs/taglib	)
+	vaapi? ( media-libs/libva[X] )
+	vulkan? ( >=media-libs/vulkan-loader-1.2.133 )
+	xv? ( x11-libs/libXv )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	!qt6? ( dev-qt/linguist-tools:5 )
+	qt6? ( dev-qt/qttools:6[linguist] )
+"
+
+src_prepare() {
+	# disable compress man pages
+	sed -r \
+		-e 's/if\(GZIP\)/if\(TRUE\)/' \
+		-e 's/(install.+QMPlay2\.1)\.gz/\1/' \
+		-i src/gui/CMakeLists.txt || die
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_WITH_QT6=$(usex qt6)
+		# core
+		-DUSE_LINK_TIME_OPTIMIZATION=false
+		-DUSE_UPDATES=OFF
+		-DUSE_ALSA=$(usex alsa)
+		-DUSE_AUDIOCD=$(usex cdio)
+		-DUSE_DBUS_SUSPEND=ON
+		-DUSE_FREEDESKTOP_NOTIFICATIONS=ON
+		-DUSE_LIBASS=$(usex libass)
+		-DUSE_NOTIFY=$(usex notifications)
+		-DUSE_OPENGL=$(usex opengl)
+		-DUSE_VULKAN=$(usex vulkan)
+		-DUSE_GLSLC=$(usex shaders)
+		-DUSE_XVIDEO=$(usex xv)
+
+		# ffmpeg
+		-DUSE_FFMPEG_AVDEVICE=$(usex avdevice)
+		-DUSE_FFMPEG_VAAPI=$(usex vaapi)
+		-DUSE_FFMPEG_VDPAU=$(usex vdpau)
+
+		# chiptune
+		-DUSE_CHIPTUNE_GME=$(usex gme)
+		-DUSE_CHIPTUNE_SID=$(usex sid)
+
+		# modules
+		-DUSE_AUDIOFILTERS=$(usex audiofilters)
+		-DUSE_CUVID=$(usex cuvid)
+		-DUSE_INPUTS=$(usex inputs)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_PIPEWIRE=$(usex pipewire)
+		-DUSE_PORTAUDIO=$(usex portaudio)
+		-DUSE_PULSEAUDIO=$(usex pulseaudio)
+		-DUSE_TAGLIB=$(usex taglib)
+		-DUSE_VIDEOFILTERS=$(usex videofilters)
+		-DUSE_VISUALIZATIONS=$(usex visualizations)
+
+		# extensions
+		-DUSE_EXTENSIONS=$(usex extensions)
+	)
+
+	if use extensions; then
+		# Move inside an if, to remove unused option warning
+		mycmakeargs+=(
+			-DUSE_LASTFM=ON
+			-DUSE_LYRICS=ON
+			-DUSE_MEDIABROWSER=ON
+			-DUSE_MPRIS2=ON
+		)
+	fi
+
+	if [[ ${PV} == *9999 ]]; then
+		mycmakeargs+=( -DUSE_GIT_VERSION=true )
+	else
+		mycmakeargs+=( -DUSE_GIT_VERSION=false )
+	fi
+
+	cmake_src_configure
+}