gentoo resync : 10.09.2021

3 files changed, 158 insertions, 1 deletions

diff --git a/net-analyzer/netdata/Manifest b/net-analyzer/netdata/Manifest
index f691dd192d27..57497015ae40 100644
--- a/net-analyzer/netdata/Manifest
+++ b/net-analyzer/netdata/Manifest
@@ -10,6 +10,7 @@ EBUILD netdata-1.29.2.ebuild 3390 BLAKE2B d07855d29c4dd438dcb86c9aca06063ce4207f
 EBUILD netdata-1.29.3.ebuild 3390 BLAKE2B d07855d29c4dd438dcb86c9aca06063ce4207f9ff3c23eb9f8261833b0789935a2f0cd1f3d2e11240c32254325a5161dda00876826afcae5a85f3f2f0ffc6094 SHA512 0cda9b196543f54982f93fdee46f38caa3d9149d20b1443a0a7aee81201d8bb9d52c06a1d4a77b2b72c0b3333a6ca74bd269c9f91b4d2ac2e5082aeba426f1f7
 EBUILD netdata-1.30.1-r1.ebuild 3456 BLAKE2B a11fb3094aea689d1b3e637967c6ef8e31f0055dd324556b421b4fa26e573c51028c6a1f8c132030582ea87a949df8b46816f4e6e25e521af1b4bb41274d806a SHA512 ac0fc905b45771c2566ab0f1fa9b5d4a6f6f39ade1489483a92cf770516859d43784ed0b3e4a0eb007aa5029cf01f5ae521272efcee6003fb3d5c66f13efafb1
 EBUILD netdata-1.31.0-r1.ebuild 3560 BLAKE2B a9e13b381407f3dcfe7838edaeb5b9ae8395e7f901d44c5d53f7d8f3645e347d73acc9b9108f23b61eba7240fae3879be5b031a0cc1f270bac7a6057be0ec934 SHA512 5a329c86ab57e02f109483477244d4a114eb9625788c856f7efd70c63ceeeb430be009b7689c318601b58c57fdb1451436f1838056bee1cdcf6b8aa47b38ea95
+EBUILD netdata-1.31.0-r2.ebuild 3663 BLAKE2B 5ba967aea9b55f5078aa87ef87014a43f2e4f63840b8b3dbf10b79d23c2641b15964cea501df6cf1131ed5cdcf5915541da58bc04b4998b5d8dddd583ff73966 SHA512 ef1ef8ddef62a215c2014498ca595231c26e1bb06ac1848cdfb47587e9a3512e2af22cc88bca2a51ed2043861e03ddf665411407746d06801142e3bfa7efe11d
 EBUILD netdata-1.31.0.ebuild 3463 BLAKE2B 1d037e46b9e988c5c6db463f28b28f7ffef76628b85340fefb1f2f6307edaea3a7362e857fd92a54defdca5203a6bf57e59e596d2f33ffb12fea13cab60c45b2 SHA512 44eca85269f4d4335873640d9367ab56670ddb11fe2ba5a0ce2e013f620a275782cb2c9ccb6f0ec6bc7cafb061aeb39f8bd03a001f44d96b36c0fd3bb635e928
-EBUILD netdata-9999.ebuild 3560 BLAKE2B a9e13b381407f3dcfe7838edaeb5b9ae8395e7f901d44c5d53f7d8f3645e347d73acc9b9108f23b61eba7240fae3879be5b031a0cc1f270bac7a6057be0ec934 SHA512 5a329c86ab57e02f109483477244d4a114eb9625788c856f7efd70c63ceeeb430be009b7689c318601b58c57fdb1451436f1838056bee1cdcf6b8aa47b38ea95
+EBUILD netdata-9999.ebuild 3663 BLAKE2B 5ba967aea9b55f5078aa87ef87014a43f2e4f63840b8b3dbf10b79d23c2641b15964cea501df6cf1131ed5cdcf5915541da58bc04b4998b5d8dddd583ff73966 SHA512 ef1ef8ddef62a215c2014498ca595231c26e1bb06ac1848cdfb47587e9a3512e2af22cc88bca2a51ed2043861e03ddf665411407746d06801142e3bfa7efe11d
 MISC metadata.xml 1288 BLAKE2B 33251404c09ccdd7ba653dae7204cf262201fdfc058766eb6b12bd4eacd99be5482867110726ced371a89db6ff022f0c89cf62425ef14f5a2e13734ad1caf70d SHA512 27087ff277f6bec908d23a66183344dfed06761a9b344a3c0d8ec2048e56ac0cb542c3d30bc22fa71cd91aee5d396b4786b546556ce7d64ea394781e05644220
diff --git a/net-analyzer/netdata/netdata-1.31.0-r2.ebuild b/net-analyzer/netdata/netdata-1.31.0-r2.ebuild
new file mode 100644
index 000000000000..d1b0ffa89e2f
--- /dev/null
+++ b/net-analyzer/netdata/netdata-1.31.0-r2.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{3_8,3_9} )
+
+inherit autotools fcaps linux-info python-single-r1 systemd
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/netdata/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/netdata/${PN}/releases/download/v${PV}/${PN}-v${PV}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${PN}-v${PV}"
+	KEYWORDS="~amd64 ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Linux real time system monitoring, done right!"
+HOMEPAGE="https://github.com/netdata/netdata https://my-netdata.io/"
+
+LICENSE="GPL-3+ MIT BSD"
+SLOT="0"
+IUSE="caps cloud +compression cpu_flags_x86_sse2 cups +dbengine ipmi +jsonc kinesis +lto mongodb mysql nfacct nodejs postgres prometheus +python tor xen"
+REQUIRED_USE="
+	mysql? ( python )
+	python? ( ${PYTHON_REQUIRED_USE} )
+	tor? ( python )"
+
+# most unconditional dependencies are for plugins.d/charts.d.plugin:
+RDEPEND="
+	acct-group/netdata
+	acct-user/netdata
+	app-misc/jq
+	>=app-shells/bash-4:0
+	|| (
+		net-analyzer/openbsd-netcat
+		net-analyzer/netcat
+	)
+	net-libs/libwebsockets
+	net-misc/curl
+	net-misc/wget
+	sys-apps/util-linux
+	virtual/awk
+	caps? ( sys-libs/libcap )
+	cups? ( net-print/cups )
+	dbengine? (
+		app-arch/lz4
+		dev-libs/judy
+		dev-libs/openssl:=
+	)
+	dev-libs/libuv
+	compression? ( sys-libs/zlib )
+	ipmi? ( sys-libs/freeipmi )
+	jsonc? ( dev-libs/json-c:= )
+	kinesis? ( dev-libs/aws-sdk-cpp[kinesis] )
+	mongodb? ( dev-libs/mongo-c-driver )
+	nfacct? (
+		net-firewall/nfacct
+		net-libs/libmnl
+	)
+	nodejs? ( net-libs/nodejs )
+	prometheus? (
+		dev-libs/protobuf:=
+		app-arch/snappy
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
+		mysql? ( $(python_gen_cond_dep 'dev-python/mysqlclient[${PYTHON_USEDEP}]') )
+		postgres? ( $(python_gen_cond_dep 'dev-python/psycopg:2[${PYTHON_USEDEP}]') )
+		tor? ( $(python_gen_cond_dep 'net-libs/stem[${PYTHON_USEDEP}]') )
+	)
+	xen? (
+		app-emulation/xen-tools
+		dev-libs/yajl
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+FILECAPS=(
+	'cap_dac_read_search,cap_sys_ptrace+ep' 'usr/libexec/netdata/plugins.d/apps.plugin'
+)
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir="${EPREFIX}"/var \
+		--with-user=netdata \
+		$(use_enable cloud) \
+		$(use_with cloud aclk-ng) \
+		$(use_enable jsonc) \
+		$(use_enable cups plugin-cups) \
+		$(use_enable dbengine) \
+		$(use_enable nfacct plugin-nfacct) \
+		$(use_enable ipmi plugin-freeipmi) \
+		$(use_enable kinesis backend-kinesis) \
+		$(use_enable lto lto) \
+		$(use_enable mongodb backend-mongodb) \
+		$(use_enable prometheus backend-prometheus-remote-write) \
+		$(use_enable xen plugin-xenstat) \
+		$(use_enable cpu_flags_x86_sse2 x86-sse) \
+		$(use_with compression zlib)
+}
+
+src_compile() {
+	emake clean
+	default
+}
+
+src_install() {
+	default
+
+	rm -rf "${D}/var/cache" || die
+
+	keepdir /var/log/netdata
+	fowners -Rc netdata:netdata /var/log/netdata
+	keepdir /var/lib/netdata
+	keepdir /var/lib/netdata/registry
+	fowners -Rc netdata:netdata /var/lib/netdata
+
+	fowners -Rc root:netdata /usr/share/${PN}
+
+	newinitd system/netdata-openrc ${PN}
+	systemd_dounit system/netdata.service
+	insinto /etc/netdata
+	doins system/netdata.conf
+}
+
+pkg_postinst() {
+	fcaps_pkg_postinst
+
+	if use nfacct ; then
+		fcaps 'cap_net_admin' 'usr/libexec/netdata/plugins.d/nfacct.plugin'
+	fi
+
+	if use xen ; then
+		fcaps 'cap_dac_override' 'usr/libexec/netdata/plugins.d/xenstat.plugin'
+	fi
+
+	if use ipmi ; then
+	    fcaps 'cap_dac_override' 'usr/libexec/netdata/plugins.d/freeipmi.plugin'
+	fi
+}
diff --git a/net-analyzer/netdata/netdata-9999.ebuild b/net-analyzer/netdata/netdata-9999.ebuild
index 7d3cc3a14ed7..d1b0ffa89e2f 100644
--- a/net-analyzer/netdata/netdata-9999.ebuild
+++ b/net-analyzer/netdata/netdata-9999.ebuild
@@ -145,4 +145,8 @@ pkg_postinst() {
 	if use xen ; then
 		fcaps 'cap_dac_override' 'usr/libexec/netdata/plugins.d/xenstat.plugin'
 	fi
+
+	if use ipmi ; then
+	    fcaps 'cap_dac_override' 'usr/libexec/netdata/plugins.d/freeipmi.plugin'
+	fi
 }