gentoo resync : 09.03.2018

4 files changed, 141 insertions, 6 deletions

diff --git a/net-firewall/iptables/Manifest b/net-firewall/iptables/Manifest
index f9e55f89504d..3a547ae7ee11 100644
--- a/net-firewall/iptables/Manifest
+++ b/net-firewall/iptables/Manifest
@@ -15,6 +15,7 @@ DIST iptables-1.6.1.tar.bz2 620890 BLAKE2B b45ac26e1fb7e8b17a6df0afab3b6c0e2f0a5
 DIST iptables-1.6.2.tar.bz2 639785 BLAKE2B 3d129756fd33c8c73d56d57e3c5595896db86ded14834a45db21b964d82840b62216ce3cea4ae4960e8c5f0671df3cc6bfb222f68d29cf3a8c99e0eee14bf017 SHA512 04f22e969c794246b9aa28055b202638081cfb0bb4a5625c049a30c48ac84cdd41db12a53c5831398cfe47c8f5691aa02b30b0ae3b5afe0f20ec48cf86a799c0
 EBUILD iptables-1.4.21-r1.ebuild 2440 BLAKE2B 2461853963f0ea8a513b3a5a461cf6e442c43d89bfec47e65589e6dd37dbf8120789840cc97ca27cb285d16857acd400fa3f9b04cf30502d56b194d8f4ce22df SHA512 b8cc233407d3cdec4ac916c61f7dcacd0ab23ca344205d48be9ab1a6be52275e595c1a64ba48b0e2e122d6ad762b8ae73883cb3c98c646e0d2ec233a8ccc8155
 EBUILD iptables-1.4.21-r5.ebuild 2973 BLAKE2B 2e700eebb6d87385f9eae1290751abc24435b4077873a233dfed6be3d1c54c7b558183fed04dda950e0915f55e41ad66d72474b009d1b8bfd531a087c90a4d45 SHA512 97ed570fa03b3766127390becbb60bb2585f23e95b6e4969c810bbaad32eec266d913a26fb4d98e689a9bb7433e92bd1399e13126f75c13ec9f0ea4212e4b117
-EBUILD iptables-1.6.1-r3.ebuild 3106 BLAKE2B d274cdef11246ea65582f7e6d3a8ee93528f95e268b621e3210bc48ebefb58dbbfe8d3b408c92a78fb9bcfbc58de915f69494951ccd5b3326168af273cee5028 SHA512 bc2a83e6c80c4a200a1fcba808fec62f9985a67a08a3293dd70554fbd0652aca6c63b624b89eac7f75735ae81d8152c3b5dad621a7e39588c5a3ef6ee66e9bfb
-EBUILD iptables-1.6.2-r1.ebuild 3136 BLAKE2B dbe3dcb2b92c8130e3b51e97b9ed59058db61efa7530206a2cc83c40ab2d10abcc1132a06f9a1e1b3cece9cf9c323d92462132673f90bdb9b188c3c5e4622c65 SHA512 cc88a0e1e271049f21422fc65410be25a39ef6d0dc986f97d71dbf2de33703ba225f8a3fafa3199144278f4475d47086c0062228d9ab68ba2aa4b6ce789e141c
+EBUILD iptables-1.6.1-r3.ebuild 3223 BLAKE2B 1723b1193c4354531450af0f19e60bd9abc45c9cd902663f29e27679068590f3214d708ef210ea7fb7e77d18b05b6c733dda5d8b46852d4e649d322fa2f74926 SHA512 ba565cbca59d0e7ef19f9d473d94228a2346eccd39c8e60a97981604b0376ba959eee099a3978f17f6078325abb6652b5e823b977a8b5d2da3f707195a6de9b6
+EBUILD iptables-1.6.2-r1.ebuild 3253 BLAKE2B 9aaeef9bedd8f3c792425fe111545c3487fb4056bc544be6be013ff1a56641c621ac72a395e8aabe686a5bc96c8bb54e544c7453e859932e72d346343f396f7f SHA512 cf579239ef7a4ca5a17e3a4e902d2d6af58688643642c90c6d09bd7969ad554516d0d00384b156a43f06b00452a7be288353c03feda2f4540ee5f3999c66339b
+EBUILD iptables-1.6.2-r2.ebuild 3291 BLAKE2B 6c3d5dab5004c2a3117d5c4f39f0f4603bf8da099099b04d1ccee5d433c1669b489d4118a80a10141c3b8c9b54da4439c82192ea2bf30753b867838200b39630 SHA512 05cccda2013cddc561cf603c0148525793057a2be226c3450951cdcd6656d9e7250bed6e5365996f917bbc32be8be5c1107e34be519ed6d0ee4eba921a6f9593
 MISC metadata.xml 1465 BLAKE2B c60f98672fb6153499b700a436b26b63c0f271c8f8519a3391e486b761ba673c362a7dc5e23b86e3af887270596a1682ea993e643a08215f670f7e3804f095bd SHA512 26bf7e3008dfd705995b15eccaaaa8c79fd488be191570a874b76571a2f9d4648a7c19eb576399ca7bbe849336d7d193f5b6b58a3ff83f87f3c157c53333e987
diff --git a/net-firewall/iptables/iptables-1.6.1-r3.ebuild b/net-firewall/iptables/iptables-1.6.1-r3.ebuild
index 67f06ce7ac09..f76df06504ed 100644
--- a/net-firewall/iptables/iptables-1.6.1-r3.ebuild
+++ b/net-firewall/iptables/iptables-1.6.1-r3.ebuild
@@ -19,7 +19,7 @@ SLOT="0/12"
 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh sparc x86"
 IUSE="conntrack ipv6 netlink nftables pcap static-libs"
 
-RDEPEND="
+COMMON_DEPEND="
 	conntrack? ( >=net-libs/libnetfilter_conntrack-1.0.6 )
 	netlink? ( net-libs/libnfnetlink )
 	nftables? (
@@ -28,7 +28,7 @@ RDEPEND="
 	)
 	pcap? ( net-libs/libpcap )
 "
-DEPEND="${RDEPEND}
+DEPEND="${COMMON_DEPEND}
 	virtual/os-headers
 	virtual/pkgconfig
 	nftables? (
@@ -36,6 +36,12 @@ DEPEND="${RDEPEND}
 		virtual/yacc
 	)
 "
+RDEPEND="${COMMON_DEPEND}
+	nftables? (
+		!<net-firewall/ebtables-2.0.10.4-r2
+		!net-misc/ethertypes
+	)
+"
 
 src_prepare() {
 	# use the saner headers from the kernel
diff --git a/net-firewall/iptables/iptables-1.6.2-r1.ebuild b/net-firewall/iptables/iptables-1.6.2-r1.ebuild
index b6c9ab99f6ba..3ed3f6a11a02 100644
--- a/net-firewall/iptables/iptables-1.6.2-r1.ebuild
+++ b/net-firewall/iptables/iptables-1.6.2-r1.ebuild
@@ -19,7 +19,7 @@ SLOT="0/12"
 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
 IUSE="conntrack ipv6 netlink nftables pcap static-libs"
 
-RDEPEND="
+COMMON_DEPEND="
 	conntrack? ( >=net-libs/libnetfilter_conntrack-1.0.6 )
 	netlink? ( net-libs/libnfnetlink )
 	nftables? (
@@ -28,7 +28,7 @@ RDEPEND="
 	)
 	pcap? ( net-libs/libpcap )
 "
-DEPEND="${RDEPEND}
+DEPEND="${COMMON_DEPEND}
 	virtual/os-headers
 	virtual/pkgconfig
 	nftables? (
@@ -36,6 +36,12 @@ DEPEND="${RDEPEND}
 		virtual/yacc
 	)
 "
+RDEPEND="${COMMON_DEPEND}
+	nftables? (
+		!<net-firewall/ebtables-2.0.10.4-r2
+		!net-misc/ethertypes
+	)
+"
 
 src_prepare() {
 	# use the saner headers from the kernel
diff --git a/net-firewall/iptables/iptables-1.6.2-r2.ebuild b/net-firewall/iptables/iptables-1.6.2-r2.ebuild
new file mode 100644
index 000000000000..91954bd4d276
--- /dev/null
+++ b/net-firewall/iptables/iptables-1.6.2-r2.ebuild
@@ -0,0 +1,122 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# Force users doing their own patches to install their own tools
+AUTOTOOLS_AUTO_DEPEND=no
+
+inherit ltprune multilib systemd toolchain-funcs autotools flag-o-matic
+
+DESCRIPTION="Linux kernel (2.4+) firewall, NAT and packet mangling tools"
+HOMEPAGE="http://www.netfilter.org/projects/iptables/"
+SRC_URI="http://www.netfilter.org/projects/iptables/files/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+# Subslot tracks libxtables as that's the one other packages generally link
+# against and iptables changes.  Will have to revisit if other sonames change.
+SLOT="0/12"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="conntrack ipv6 netlink nftables pcap static-libs"
+
+COMMON_DEPEND="
+	conntrack? ( >=net-libs/libnetfilter_conntrack-1.0.6 )
+	netlink? ( net-libs/libnfnetlink )
+	nftables? (
+		>=net-libs/libmnl-1.0:0=
+		>=net-libs/libnftnl-1.0.5:0=
+	)
+	pcap? ( net-libs/libpcap )
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/os-headers
+	virtual/pkgconfig
+	nftables? (
+		sys-devel/flex
+		virtual/yacc
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	nftables? ( net-misc/ethertypes )
+"
+
+src_prepare() {
+	# use the saner headers from the kernel
+	rm -f include/linux/{kernel,types}.h
+
+	# Only run autotools if user patched something
+	eapply_user && eautoreconf || elibtoolize
+}
+
+src_configure() {
+	# Some libs use $(AR) rather than libtool to build #444282
+	tc-export AR
+
+	# Hack around struct mismatches between userland & kernel for some ABIs. #472388
+	use amd64 && [[ ${ABI} == "x32" ]] && append-flags -fpack-struct
+
+	sed -i \
+		-e "/nfnetlink=[01]/s:=[01]:=$(usex netlink 1 0):" \
+		-e "/nfconntrack=[01]/s:=[01]:=$(usex conntrack 1 0):" \
+		configure || die
+
+	local myeconfargs=(
+		--sbindir="${EPREFIX}/sbin"
+		--libexecdir="${EPREFIX}/$(get_libdir)"
+		--enable-devel
+		--enable-shared
+		$(use_enable nftables)
+		$(use_enable pcap bpf-compiler)
+		$(use_enable pcap nfsynproxy)
+		$(use_enable static-libs static)
+		$(use_enable ipv6)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	# Deal with parallel build errors.
+	use nftables && emake -C iptables xtables-config-parser.h
+	emake V=1
+}
+
+src_install() {
+	default
+	dodoc INCOMPATIBILITIES iptables/iptables.xslt
+
+	# all the iptables binaries are in /sbin, so might as well
+	# put these small files in with them
+	into /
+	dosbin iptables/iptables-apply
+	dosym iptables-apply /sbin/ip6tables-apply
+	doman iptables/iptables-apply.8
+
+	insinto /usr/include
+	doins include/iptables.h $(use ipv6 && echo include/ip6tables.h)
+	insinto /usr/include/iptables
+	doins include/iptables/internal.h
+
+	keepdir /var/lib/iptables
+	newinitd "${FILESDIR}"/${PN}.init iptables
+	newconfd "${FILESDIR}"/${PN}-1.4.13.confd iptables
+	if use ipv6 ; then
+		keepdir /var/lib/ip6tables
+		newinitd "${FILESDIR}"/iptables.init ip6tables
+		newconfd "${FILESDIR}"/ip6tables-1.4.13.confd ip6tables
+	fi
+
+	if use nftables; then
+		# Bug 647458
+		rm "${ED%/}"/etc/ethertypes || die
+	fi
+
+	systemd_dounit "${FILESDIR}"/systemd/iptables-{re,}store.service
+	if use ipv6 ; then
+		systemd_dounit "${FILESDIR}"/systemd/ip6tables-{re,}store.service
+	fi
+
+	# Move important libs to /lib #332175
+	gen_usr_ldscript -a ip{4,6}tc iptc xtables
+
+	prune_libtool_files
+}