gentoo auto-resync : 06:12:2022 - 03:08:16

1 files changed, 68 insertions, 0 deletions

diff --git a/net-fs/davfs2/davfs2-1.6.0-r1.ebuild b/net-fs/davfs2/davfs2-1.6.0-r1.ebuild
new file mode 100644
index 000000000000..fdd0b7931658
--- /dev/null
+++ b/net-fs/davfs2/davfs2-1.6.0-r1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Linux FUSE (or coda) driver that allows you to mount a WebDAV resource"
+HOMEPAGE="https://savannah.nongnu.org/projects/davfs2"
+SRC_URI="mirror://nongnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="amd64 ~arm ~arm64 ppc x86"
+IUSE="nls split-usr"
+RESTRICT="test"
+
+RDEPEND="dev-libs/libxml2
+	net-libs/neon
+	sys-libs/zlib
+	nls? ( virtual/libintl virtual/libiconv )
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+RDEPEND="${RDEPEND}
+	acct-group/davfs2
+	acct-user/davfs2
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.6.0-neon-0.32-support.patch
+)
+
+src_prepare() {
+	local f
+
+	# Let the package manager handle man page compression
+	while IFS="" read -d $'\0' -r f ; do
+		sed -e '/^manual[58]_DATA/ s/[.]gz//g' -i "${f}" || die
+	done < <(find "${S}"/man -type f -name 'Makefile.in' -print0)
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local ssbindir
+	if use split-usr; then
+		ssbindir=${EPREFIX}/sbin
+	else
+		ssbindir=${EPREFIX}/usr/sbin
+	fi
+
+	econf --enable-largefile $(use_enable nls) ssbindir="${ssbindir}"
+}
+
+pkg_postinst() {
+	elog
+	elog "Quick setup:"
+	elog "   (as root)"
+	elog "   # gpasswd -a \${your_user} davfs2"
+	elog "   # echo 'https://path/to/dav /home/\${your_user}/dav davfs rw,user,noauto  0  0' >> /etc/fstab"
+	elog "   (as user)"
+	elog "   \$ mkdir -p ~/dav"
+	elog "   \$ mount ~/dav"
+	elog
+}