gentoo auto-resync : 13:12:2024 - 02:01:50

2 files changed, 108 insertions, 0 deletions

diff --git a/net-im/gajim/Manifest b/net-im/gajim/Manifest
index f9c619cf8450..babcc0eb2735 100644
--- a/net-im/gajim/Manifest
+++ b/net-im/gajim/Manifest
@@ -11,4 +11,5 @@ EBUILD gajim-1.8.1.ebuild 3010 BLAKE2B 0b38044c5065c4613c2fdc6a4bf4afbb82cc0084d
 EBUILD gajim-1.8.4-r1.ebuild 2957 BLAKE2B 81fb0ee481dc27f789d07222f9fbeb04c045ed8bb97cf2d1786f60a59c7891826a57bd961717cb4e2c46019e40b03f552f92f6412cb65ba810d101565a5608d6 SHA512 c4163b55d81b179c454775a94a48916996d216a467107be9fcfd68ab976a4cd87ecb9e80b1713947020b6c63d6f143a65c83cec6936747654347c889ea34aa4c
 EBUILD gajim-1.9.3.ebuild 3175 BLAKE2B 12baec5765436cec72e521bcfcf0dd0d56823f8133d22681ae827510ae764a968f51d7507651e7b330c955d78d4eb89e58e82a0e383bd91d864bf9b903e8ae07 SHA512 bcaf5c2649b7e3d151125b8db1aa16090953c433b9fb2bfbb70afae691c27478aadac3d5c8148b0d9e7488b87ec13967db4825b7899b95d662a28eb469cc5ced
 EBUILD gajim-1.9.5-r1.ebuild 3099 BLAKE2B e448fecd5f84505acdedd612dee92f559d2515846b60d1c9b9ec11464f6123eb4f2503736bfb80184fa95ebe7cce18c35f8463daafd0ba6b3ae14c05b5a299b7 SHA512 e393c0bc1adee93988cdb25ea5289ac5c868e712aaacc089664b989f5b6ad3ed6c478d63769e5db150543422bb4942e2201b216af185d58169922055e562b8b1
+EBUILD gajim-1.9.5-r2.ebuild 3129 BLAKE2B e8839baf082b3996d58806d3f0963a9ed3c717479781ace97dce4e59fc20302385c9fe65083a8aabbba5ecbc55dd0bff53bfae1025dda30d6c24ddee53dd6a17 SHA512 bc0d4552a598db2f8798a9e992ea33de5c7713b346fc4d86de2dcda732a651a9b96d9631b886db1b80da3c405cc982f0b512f851f316047e2a44418a53f17090
 MISC metadata.xml 815 BLAKE2B 37ae2afdfb03255bd4603856440ff96529aca09d85b1ad57e16e45784b93081738aac04c03f6f774a35f38e4be2789411e6d2e61f5283bbb01a74ca120f11b11 SHA512 a399b87e27fa06272cea267ded7b3792c8a0cd0abaeb477a27cbfa0a11a82043959a5d7d83256fd8e159858fe8c9a3571827f083b497641aa7636510a0b877d7
diff --git a/net-im/gajim/gajim-1.9.5-r2.ebuild b/net-im/gajim/gajim-1.9.5-r2.ebuild
new file mode 100644
index 000000000000..d7b1d3509aa8
--- /dev/null
+++ b/net-im/gajim/gajim-1.9.5-r2.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PYTHON_REQ_USE="sqlite,xml(+)"
+DISTUTILS_USE_PEP517=standalone
+DISTUTILS_SINGLE_IMPL=1
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="XMPP client written in PyGTK"
+HOMEPAGE="https://gajim.org/"
+SRC_URI="https://gajim.org/downloads/$(ver_cut 1-2)/${P/_p/-}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+# Rekeyword for ~long, ~x86 and ~riscv, when https://bugs.gentoo.org/937582 is fixed.
+# KEYWORDS="~amd64 ~arm64 ~loong ~riscv ~x86"
+KEYWORDS="~amd64 ~arm64"
+IUSE="+crypt geolocation jingle remote rst +spell +webp"
+
+COMMON_DEPEND="
+	dev-libs/gobject-introspection[cairo(+)]
+	>=x11-libs/gtk+-3.24.30:3[introspection]
+	x11-libs/gtksourceview:4[introspection]"
+DEPEND="${COMMON_DEPEND}
+	app-arch/unzip
+	virtual/pkgconfig
+	>=x11-libs/pango-1.50.0
+	>=sys-devel/gettext-0.17-r1"
+RDEPEND="${COMMON_DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/idna[${PYTHON_USEDEP}]
+		>=dev-python/nbxmpp-5.0.4[${PYTHON_USEDEP}]
+		dev-python/precis-i18n[${PYTHON_USEDEP}]
+		dev-python/pyasn1[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pycurl[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+		x11-libs/libXScrnSaver
+		sys-apps/xdg-desktop-portal
+		app-crypt/libsecret[crypt,introspection]
+		dev-python/keyring[${PYTHON_USEDEP}]
+		>=dev-python/secretstorage-3.1.1[${PYTHON_USEDEP}]
+		dev-python/css-parser[${PYTHON_USEDEP}]
+		dev-python/packaging[${PYTHON_USEDEP}]
+		net-libs/libsoup:3.0[introspection]
+		media-libs/gsound[introspection]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/jaraco-classes[${PYTHON_USEDEP}]
+		dev-python/python-axolotl[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/emoji[${PYTHON_USEDEP}]
+		dev-python/qrcode[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/omemo-dr[${PYTHON_USEDEP}]
+		crypt? (
+			dev-python/pycryptodome[${PYTHON_USEDEP}]
+			>=dev-python/python-gnupg-0.4.0[${PYTHON_USEDEP}] )
+		geolocation? ( app-misc/geoclue[introspection] )
+		jingle? (
+			net-libs/farstream:0.2[introspection]
+			media-libs/gstreamer:1.0[introspection]
+			media-libs/gst-plugins-base:1.0[introspection]
+			media-libs/gst-plugins-ugly:1.0
+			media-plugins/gst-plugins-gtk
+		)
+		remote? (
+			>=dev-python/dbus-python-1.2.0[${PYTHON_USEDEP}]
+			sys-apps/dbus[X]
+		)
+		rst? ( dev-python/docutils[${PYTHON_USEDEP}] )
+		spell? (
+			app-text/gspell[introspection]
+			app-text/hunspell
+		)
+	')"
+
+python_compile() {
+	./make.py build --dist unix || die
+	distutils-r1_python_compile
+}
+
+python_install() {
+	distutils-r1_python_install
+	./make.py install --dist unix --prefix="${ED}/usr" || die
+
+	gzip -d "${ED}"/usr/share/man/man1/*.gz || die
+}
+
+pkg_postinst() {
+	ewarn "The chat database format changes when upgrading from 1.8.x to 1.9.x."
+	ewarn "The first time the user starts Gajim, an automatic migration is performed."
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+# Tests are unfortunately regularly broken
+RESTRICT="test"