gentoo resync : 25.08.2018

3 files changed, 152 insertions, 2 deletions

diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index cf395534b86e..8bab47d92547 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1,6 +1,8 @@
 DIST kvirc-5.0_pre20180401054732.tar.gz 6040980 BLAKE2B fa023ef84f5c84e92b11ed043be0a2e52316fc92f206c41bcb7216760e0473e13e118398445137aeafd657c856cdccfa2f5202f9534904771d8a049d5139f41a SHA512 6d3a9bb06018e2d54369139bbf0a768d3c4e39754b908c1e4294c79707c8b5b751141ae10bdf8456465bd9bf6e4e426a91bc6bef5a1c3563bf32adecc10582eb
 DIST kvirc-5.0_pre20180605072059.tar.gz 6048634 BLAKE2B db2a7a5ff0fa10a1eea6f011b6ea83301d434b08ba3ee61656ddd136ca027c8ce57a2565b491a69f6f1dff138e984ba76f81dc30ed25b6a0e54bb27821448f05 SHA512 f0da384990fc4a9cdf2727abdcc68cfc9c35e925379635acf02e91dc7d83d5ed584798a3d6ac41d259724993b48a67f8bfdae5e0a8d869f0189fbec3c6a652cf
+DIST kvirc-5.0_pre20180819121252.tar.gz 6049652 BLAKE2B b4712e089a26498a7a3e4df10fe0def377814a9cc4082f55c2177da4929bc2fb02fbc947ee0603b62175a5cee657f6316ca246a275e96df71bd9d938453d4604 SHA512 de7ccb0f698488599ba3f58ca46ef2427632bdf1870d576baea8634e530cbe7654f60d4cdd58447301c4401941ef8b4e810f4d3eb4d6468a2899b80484380ea7
 EBUILD kvirc-5.0_pre20180401054732.ebuild 3837 BLAKE2B 46f2db335a4cdefd2da23c4a13be5cbe87e098450e457862d2a6017210ad3dd89cad2e82d245de5fce97f3b3209c60b21123226f0b266667f5f6e2552df5875f SHA512 2bc026d32a22d75396c4921efdcaa4e35dad27ae0cc6cde18ac965a0cabd556ef68557a691467c88b3ac637d6a1dbf6ca4f1501772255a96be6d0d0311b46175
-EBUILD kvirc-5.0_pre20180605072059.ebuild 3822 BLAKE2B 907021ee297d4ed5f3e96d4faefc63a62af0fb4f0029cb7b8240f432453fda5fda861b4b9affb25108d6765f2b832abd53cf94eb78b5f1af2dc9f3cb18302cd4 SHA512 867ecc6d23d19248af13ec236c07c9814fd8001c843e54560734fd955ecc51e9f5077e702d9b47399f1c405bdde380805cf8ff18b2f3d9223f0f725be12a3dfd
+EBUILD kvirc-5.0_pre20180605072059.ebuild 3820 BLAKE2B ff7e9906b1239cf16c321e9ee4bcad4854671ac0c7a5a742f4b484b5079bf3c53b626980d3c0e4a08210b1a541b5aa93f61b53ec641c866325343cc41f04cde5 SHA512 79ce480e00deb9406d8416a60039e7fa4a621df2d97e4cf69b3ca9e84e2061616b605e2020bbb3e8b93a11760033e437f87232ecc6cdb18024784015dda51ae5
+EBUILD kvirc-5.0_pre20180819121252.ebuild 3822 BLAKE2B afe6090471b1c252b85dfeb45533bd338e8b2fd0306cc3505bd59e547a0e71378d5dbae59696098925d7d644f419a6a01b2f7eb5927f69ef5a248a47705dc963 SHA512 19ee1d7ddf04617955ce5d97e18312fa7b5ef6e760c3fd11f502554b35e24b1de1e4f205bed2b7d564b489538adc9ebb776064df54a7b94d53151db3a5dbcd85
 EBUILD kvirc-9999.ebuild 3759 BLAKE2B 3d8b72265f6f531fa139b64073f864efb70e0aa9725d43904e5e91dd27118917cdaa4ff775840d8f3e63dd4e00a32d060d5dc20128aeaede9b2eb8230c8d1850 SHA512 2875b8b78685e66c343213f9f82ba59107fc0082fc0fcfd410478beef315700a0cf250b1fc88212b6bfdb3d00ac3300ea835f7bc9afc5a33971acd5432eea18a
 MISC metadata.xml 618 BLAKE2B 5a6a28876a22cedbca154051a389fed0e7ef25039319786ed2303b580b1e421b648038237e0157678fb96e1b45839e725299e56584bcb770593f60f305932145 SHA512 af08ad67affb8dbe4ae6afbb2a251e5bd44e5fb30f9332dddebbb6dd504fa25b449b5b4c3a5c1f0337c6a7751b2395eb049cf94206a44cce2a7ab1df1d1b3eae
diff --git a/net-irc/kvirc/kvirc-5.0_pre20180605072059.ebuild b/net-irc/kvirc/kvirc-5.0_pre20180605072059.ebuild
index cf4358a57af0..67faa87dff73 100644
--- a/net-irc/kvirc/kvirc-5.0_pre20180605072059.ebuild
+++ b/net-irc/kvirc/kvirc-5.0_pre20180605072059.ebuild
@@ -30,7 +30,7 @@ fi
 
 LICENSE="kvirc"
 SLOT="0"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+KEYWORDS="amd64 ~ppc ~ppc64 x86"
 IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
 REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
 
diff --git a/net-irc/kvirc/kvirc-5.0_pre20180819121252.ebuild b/net-irc/kvirc/kvirc-5.0_pre20180819121252.ebuild
new file mode 100644
index 000000000000..0957c93760ac
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.0_pre20180819121252.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+PYTHON_COMPAT=(python2_7)
+
+inherit cmake-utils flag-o-matic gnome2-utils python-single-r1 xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	inherit vcs-snapshot
+
+	KVIRC_GIT_REVISION="abc7a305d16d5ff939959164cff856af8f6d6ca1"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="kvirc"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon[qt5(+)] )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant:0= )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webkit? ( dev-qt/qtwebkit:5 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+RDEPEND="${RDEPEND}
+	gsm? ( media-sound/gsm )"
+
+DOCS=()
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_ENV_FLAGS=yes
+		-DWANT_VERBOSE=yes
+
+		-DWANT_CRYPT=yes
+		-DWANT_DCC_VOICE=yes
+		-DWANT_IPC=yes
+		-DWANT_IPV6=yes
+		-DWANT_TRANSPARENCY=yes
+
+		-DWANT_AUDIOFILE=$(usex audiofile)
+		-DWANT_DCC_VIDEO=$(usex dcc_video)
+		-DWANT_DEBUG=$(usex debug)
+		-DWANT_DOXYGEN=$(usex doc)
+		-DWANT_GETTEXT=$(usex nls)
+		-DWANT_GSM=$(usex gsm)
+		-DWANT_KDE=$(usex kde)
+		-DWANT_MEMORY_PROFILE=$(usex profile)
+		-DWANT_OGG_THEORA=$(usex theora)
+		-DWANT_OPENSSL=$(usex ssl)
+		-DWANT_OSS=$(usex oss)
+		-DWANT_PERL=$(usex perl)
+		-DWANT_PHONON=$(usex phonon)
+		-DWANT_PYTHON=$(usex python)
+		-DWANT_QTDBUS=$(usex dbus)
+		-DWANT_QTWEBKIT=$(usex webkit)
+		-DWANT_SPELLCHECKER=$(usex spell)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=no
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}