gentoo resync : 15.12.2019

3 files changed, 179 insertions, 3 deletions

diff --git a/net-irc/kvirc/Manifest b/net-irc/kvirc/Manifest
index 10ae24e87c9e..fc41a89ca9b1 100644
--- a/net-irc/kvirc/Manifest
+++ b/net-irc/kvirc/Manifest
@@ -1,5 +1,7 @@
 AUX kvirc-5.2_pre20190628041642-python-3.patch 2036 BLAKE2B 71de965fcd6d3ff6ec74c52662d894b60ff15d7b9dd895f18a6c31d4404291c227ae0f15362b0eebd86c377adce5ebd1a6a65975c40d2a391c928748dcb144d1 SHA512 3dcdf021f9c78df31031f25a86dea332996d489e482ba3da867856f262fd001c7858da51f5cb9dc0a3c208674a60105e484c3426d73816c61f0fbdca0a88b3cb
 DIST kvirc-5.2_pre20190628041642.tar.gz 5967194 BLAKE2B b1a2e2775056e2db058f82656ac90e43828d497019e9c6ae0431a1092423425558c6eb91a3a8301616cc4cdc7ef1acbab3729702484d703e00dc8e09f7cf243f SHA512 5f532739d9837f357a36fa1df67db0fbf8d8eddb990e686224e53c5678d26ba18c6c7c60422cef4e08ee587156638b278f534b1be1d49251fdeea19858227a5f
+DIST kvirc-5.2_pre20191202122540.tar.gz 5967654 BLAKE2B 059e57f0b8a789388f351c536dc3b57a7fc119cc78206a6a42266a1296e1edc6410ab9f564959d77aabb98ca55c9d4ec63505b4c1d46ad27a7f0f2ee748eae55 SHA512 2e3b7683070446a80642ef07abbc69912e47af59966cbc95698f5b8b1a1726b85ae78890dcc85d3f546f32b3c5f2a6c64ec4049467c6b336798ad91542d48c42
 EBUILD kvirc-5.2_pre20190628041642.ebuild 4322 BLAKE2B 1ffc73c27abbcb7a101829cf4a8197713e48d5bb3bdba3584beee23ba57c5f4c8cde9df6da004b7885b617929d88cc04aa72e7ed94474ef691eea74a582741da SHA512 cbb66d43ce0c829f82edecd611f7fcdfa27863a67d89d053a53f4529985c3b822c663eb93df023ae59feab7339bdf71926f94a4c2fdf5b9a51a56fbc789d7340
-EBUILD kvirc-9999.ebuild 4261 BLAKE2B 796cbac383831084f9b9677d7888b02a394b9ab1d9d5720b3660193d9f3accb2a6c44d850ee4f1756fb75640cc85f08bec8d237da8c1901c0fce3fefb893f4cf SHA512 6136cbaf6f4dd7d1c4effb3fabe341d69a2cee6e802e44f46d3ad400c920860e631d1a12b6ca1a5c900a220334ab182a096d3f20a0d8195c7bb9e23f2e132918
+EBUILD kvirc-5.2_pre20191202122540.ebuild 4325 BLAKE2B 7af23814810c6863700412b5307c4e6df818fd09ef859365ba1d8eae2172d896c408f4bcdbbfdca0e03c46c9445ea8154fe81877a17280a2ec042da6beaa5ce1 SHA512 b3dcb64f67dd31d4bdb80070c0de988c29855298e866c1d4c4e20752380b86440ff1d6e7fc451d2806cf75c9e0f31805d97152972046afb5c610b23f0c4667b0
+EBUILD kvirc-9999.ebuild 4262 BLAKE2B 8ab4e5e2a642574e0c812e89a9f05241eb093e9590d2e1eba6556393c6c9cf92eee0fdccc98c2efc138025f1e0ffb12ab8fb770f091d70ff133a9a2ea3152809 SHA512 ff91f6b7567ce639ac04ea4c184a9a51866802052c5e392ded07924472e93c74295975b941b6877e6dc84d1a1cfa7ce313d5e72043b56e3787ec5437472ae38e
 MISC metadata.xml 643 BLAKE2B 820a98f07a4cfb58e857d5c7b863ed7adc174497a7ea05e66245a2c40c328ee0bdb644b98ba1d923834ccf05f23f8128abfe462d433fe2136078225b152a633f SHA512 3dd50caac7ff50679cabad216d4ec28b60351febc419f5d32f60b785043eba6f2f379c06e5af28af26355845ebcfe8439bca9d141bc3b9d0401fb0ee0a0c704c
diff --git a/net-irc/kvirc/kvirc-5.2_pre20191202122540.ebuild b/net-irc/kvirc/kvirc-5.2_pre20191202122540.ebuild
new file mode 100644
index 000000000000..5a3b79274188
--- /dev/null
+++ b/net-irc/kvirc/kvirc-5.2_pre20191202122540.ebuild
@@ -0,0 +1,174 @@
+# Copyright 2009-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+CMAKE_MAKEFILE_GENERATOR="emake"
+PYTHON_COMPAT=(python{3_6,3_7,3_8})
+
+inherit cmake-utils flag-o-matic python-single-r1 xdg-utils
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/kvirc/KVIrc"
+	KVIRC_GIT_REVISION=""
+	KVIRC_GIT_SOURCES_DATE=""
+else
+	KVIRC_GIT_REVISION="0df9f22f2f4d013b91d5a8905cbd47c32e8fb9e5"
+	KVIRC_GIT_SOURCES_DATE="${PV#*_pre}"
+	KVIRC_GIT_SOURCES_DATE="${KVIRC_GIT_SOURCES_DATE:0:4}-${KVIRC_GIT_SOURCES_DATE:4:2}-${KVIRC_GIT_SOURCES_DATE:6:2}"
+fi
+
+DESCRIPTION="Advanced IRC Client"
+HOMEPAGE="https://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+if [[ "${PV}" == "9999" ]]; then
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/kvirc/KVIrc/archive/${KVIRC_GIT_REVISION}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="audiofile +dbus dcc_video debug doc gsm kde +nls oss +perl +phonon profile +python spell +ssl theora webkit"
+REQUIRED_USE="audiofile? ( oss ) python? ( ${PYTHON_REQUIRED_USE} )"
+
+BDEPEND="dev-lang/perl:0
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	kde? ( kde-frameworks/extra-cmake-modules:5 )
+	nls? ( sys-devel/gettext )"
+DEPEND="dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtmultimedia:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtprintsupport:5
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtx11extras:5
+	dev-qt/qtxml:5
+	sys-libs/zlib:0=
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	audiofile? ( media-libs/audiofile )
+	dbus? ( dev-qt/qtdbus:5 )
+	dcc_video? ( dev-qt/qtmultimedia:5[widgets] )
+	kde? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/ki18n:5
+		kde-frameworks/knotifications:5
+		kde-frameworks/kservice:5
+		kde-frameworks/kwindowsystem:5
+		kde-frameworks/kxmlgui:5
+	)
+	perl? ( dev-lang/perl:0= )
+	phonon? ( media-libs/phonon[qt5(+)] )
+	python? ( ${PYTHON_DEPS} )
+	spell? ( app-text/enchant:0= )
+	ssl? ( dev-libs/openssl:0= )
+	theora? (
+		media-libs/libogg
+		media-libs/libtheora
+		media-libs/libvorbis
+	)
+	webkit? ( dev-qt/qtwebkit:5 )"
+RDEPEND="${DEPEND}
+	gsm? ( media-sound/gsm )"
+
+if [[ "${PV}" != "9999" ]]; then
+	S="${WORKDIR}/KVIrc-${KVIRC_GIT_REVISION}"
+fi
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.2_pre20190628041642-python-3.patch"
+)
+
+DOCS=()
+
+pkg_setup() {
+	if use python; then
+		python-single-r1_pkg_setup
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	if [[ "${PV}" == "9999" ]]; then
+		KVIRC_GIT_REVISION="$(git show -s --format=%H)"
+		KVIRC_GIT_SOURCES_DATE="$(git show -s --format=%cd --date=short)"
+	fi
+	einfo "Setting of revision number to ${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE}"
+	sed -e "/#define KVI_DEFAULT_FRAME_CAPTION/s/KVI_VERSION/& \" (${KVIRC_GIT_REVISION} ${KVIRC_GIT_SOURCES_DATE})\"/" -i src/kvirc/ui/KviMainWindow.cpp || die "Setting of revision number failed"
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+
+	local libdir="$(get_libdir)"
+	local mycmakeargs=(
+		-DLIB_SUFFIX=${libdir#lib}
+		-DMANUAL_REVISION=${KVIRC_GIT_REVISION}
+		-DMANUAL_SOURCES_DATE=${KVIRC_GIT_SOURCES_DATE//-/}
+		-DWANT_ENV_FLAGS=ON
+		-DWANT_VERBOSE=ON
+
+		-DWANT_CRYPT=ON
+		-DWANT_DCC_VOICE=ON
+		-DWANT_IPC=ON
+		-DWANT_IPV6=ON
+		-DWANT_TRANSPARENCY=ON
+
+		-DWANT_AUDIOFILE=$(usex audiofile ON OFF)
+		-DWANT_DCC_VIDEO=$(usex dcc_video ON OFF)
+		-DWANT_DEBUG=$(usex debug ON OFF)
+		-DWANT_DOXYGEN=$(usex doc ON OFF)
+		-DWANT_GETTEXT=$(usex nls ON OFF)
+		-DWANT_GSM=$(usex gsm ON OFF)
+		-DWANT_KDE=$(usex kde ON OFF)
+		-DWANT_MEMORY_PROFILE=$(usex profile ON OFF)
+		-DWANT_OGG_THEORA=$(usex theora ON OFF)
+		-DWANT_OPENSSL=$(usex ssl ON OFF)
+		-DWANT_OSS=$(usex oss ON OFF)
+		-DWANT_PERL=$(usex perl ON OFF)
+		-DWANT_PHONON=$(usex phonon ON OFF)
+		-DWANT_PYTHON=$(usex python ON OFF)
+		-DWANT_QTDBUS=$(usex dbus ON OFF)
+		-DWANT_QTWEBKIT=$(usex webkit ON OFF)
+		-DWANT_SPELLCHECKER=$(usex spell ON OFF)
+
+		# COMPILE_SVG_SUPPORT not used in source code.
+		-DWANT_QTSVG=OFF
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	if use doc; then
+		cmake-utils_src_compile devdocs
+	fi
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	if use doc; then
+		(
+			docinto html
+			dodoc -r "${BUILD_DIR}/doc/api/html/"*
+		)
+	fi
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
diff --git a/net-irc/kvirc/kvirc-9999.ebuild b/net-irc/kvirc/kvirc-9999.ebuild
index 46a0772c2758..76c8d1a158fd 100644
--- a/net-irc/kvirc/kvirc-9999.ebuild
+++ b/net-irc/kvirc/kvirc-9999.ebuild
@@ -3,7 +3,7 @@
 
 EAPI="7"
 CMAKE_MAKEFILE_GENERATOR="emake"
-PYTHON_COMPAT=(python{2_7,3_6,3_7})
+PYTHON_COMPAT=(python{3_6,3_7,3_8})
 
 inherit cmake-utils flag-o-matic python-single-r1 xdg-utils
 
@@ -20,7 +20,7 @@ else
 fi
 
 DESCRIPTION="Advanced IRC Client"
-HOMEPAGE="http://www.kvirc.net/ https://github.com/kvirc/KVIrc"
+HOMEPAGE="https://www.kvirc.net/ https://github.com/kvirc/KVIrc"
 if [[ "${PV}" == "9999" ]]; then
 	SRC_URI=""
 else