gentoo resync : 20.10.2021

1 files changed, 55 insertions, 0 deletions

diff --git a/net-libs/czmq/czmq-4.2.1.ebuild b/net-libs/czmq/czmq-4.2.1.ebuild
new file mode 100644
index 000000000000..4811dcd20d22
--- /dev/null
+++ b/net-libs/czmq/czmq-4.2.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+DESCRIPTION="High-level C Binding for ZeroMQ"
+HOMEPAGE="http://czmq.zeromq.org"
+SRC_URI="https://github.com/zeromq/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0/4"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~x86"
+IUSE="curl drafts http-client http-server lz4 nss static-libs systemd +uuid"
+
+BDEPEND="app-text/asciidoc
+	app-text/xmlto
+	virtual/pkgconfig"
+
+RDEPEND=">=net-libs/zeromq-4:=[drafts?]
+	http-client? ( net-misc/curl )
+	http-server? ( net-libs/libmicrohttpd:= )
+	lz4? ( app-arch/lz4:= )
+	nss? (
+		dev-libs/nspr
+		dev-libs/nss
+	)
+	systemd? ( sys-apps/systemd )
+	uuid? ( sys-apps/util-linux:0 )"
+
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS NEWS README.md )
+
+src_configure() {
+	local myeconfargs=(
+		--enable-drafts=$(usex drafts)
+		--with-docs=no
+		--with-uuid=$(usex uuid)
+		--with-libcurl=$(usex http-client)
+		--with-libmicrohttpd=$(usex http-server)
+		--with-libsystemd=$(usex systemd)
+		--with-liblz4=$(usex lz4)
+		--with-nss=$(usex nss)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+
+	if ! use static-libs ; then
+		find "${ED}" -type f \( -name "*.a" -o -name "*.la" \) -delete || die
+	fi
+}