gentoo resync : 04.08.2018

2 files changed, 70 insertions, 0 deletions

diff --git a/net-libs/gtk-vnc/Manifest b/net-libs/gtk-vnc/Manifest
index 36d8accb5ba0..0c9fec29b744 100644
--- a/net-libs/gtk-vnc/Manifest
+++ b/net-libs/gtk-vnc/Manifest
@@ -1,3 +1,5 @@
 DIST gtk-vnc-0.7.2.tar.xz 447088 BLAKE2B 539cc9214735cf73c6e578029b33892c3e2d0d1dc402f82fa6d8d107c9a410e551020d9201192b69e50b75bb8297919ab0961752251dcf0bd75823d7426e01b5 SHA512 b95b1da6ff512c466feaa6efc831e9c36c5a77390b518c647c60fddda9dd850eea8658174682ae135b95bfca7bf2b4e85a5e5ac9adb43e3ddd7aa690288655ce
+DIST gtk-vnc-0.8.0.tar.xz 448984 BLAKE2B e9de98a969297832ff6eaba79707a44494b20d944264ac6902596f882b95e8ab1bc6b7eb25e040d17f939d678a81eec730f983942db38d73c81751fc2afd45df SHA512 9b66e4028e56b01af8d0ded5b833fc6c0ba752ac72cd664293b0009868bbec0bc8750b619ece9786eddc06155e390ecccc4c5bc84717c49ac4bd866e6febd8e3
 EBUILD gtk-vnc-0.7.2.ebuild 1487 BLAKE2B 4aafa14d0d026398814a54f15dafd16d2ed594f31be836d6e1c31a8250fc5b55777e72b0bf191e14acbe382fee29ce41497cf5d18345055ff2e9be6eae7885ab SHA512 fa79e09cc5ef8d380f56a8c1bff4b498caf6348d32ba6e0862cd64458db489d923dae423897c846de4a73976fd81d9d079bdef7cc5960a2858d8a0e76765dadf
+EBUILD gtk-vnc-0.8.0.ebuild 1652 BLAKE2B 56a2454b09a91851c9d850f903ab53d880f4a748c1bb3f4ad43e24fc5567f7427d98b2c8df01530efe930f8ba73a4071cc904f32a4729003ab596051de529dc9 SHA512 0e6365d2864201fea24da1fe8f527eb52d66578710b043709f3439118703c2c32672a01e0d0e888f540e8e281e0270f8558b3dce16fae78a7414a2f6052a20e2
 MISC metadata.xml 397 BLAKE2B 0e99084e903bd50b1228c59e87a97bbec3d6c2543328b9ac42587969cc402e93537c360ca8e1df2e5a9bb1129473e8d6c698b373b3e65ee7b322bb87f01baf71 SHA512 eeedc7da2c6292330fa47841afdbf4038d1c3bec1b2803bd462ea4b13c6cd88448274a0814675d3d85ef89f2fd1aa9c45344412a9742e26214dfdf9d51a63d06
diff --git a/net-libs/gtk-vnc/gtk-vnc-0.8.0.ebuild b/net-libs/gtk-vnc/gtk-vnc-0.8.0.ebuild
new file mode 100644
index 000000000000..d974182179d5
--- /dev/null
+++ b/net-libs/gtk-vnc/gtk-vnc-0.8.0.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{4,5,6,7} )
+GNOME2_LA_PUNT="yes"
+VALA_MIN_API_VERSION="0.16"
+
+inherit vala gnome2 python-any-r1
+
+DESCRIPTION="VNC viewer widget for GTK"
+HOMEPAGE="https://wiki.gnome.org/Projects/gtk-vnc"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="examples +introspection pulseaudio sasl vala"
+REQUIRED_USE="
+	vala? ( introspection )
+"
+
+# libview is used in examples/gvncviewer -- no need
+# glib-2.30.1 needed to avoid linking failure due to .la files (bug #399129)
+RDEPEND="
+	>=dev-libs/glib-2.30.1:2
+	>=dev-libs/libgcrypt-1.4.2:0=
+	dev-libs/libgpg-error
+	>=net-libs/gnutls-3.0:0=
+	>=x11-libs/cairo-1.2
+	x11-libs/libX11
+	>=x11-libs/gtk+-3.0.0:3[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.4:= )
+	pulseaudio? ( media-sound/pulseaudio )
+	sasl? ( dev-libs/cyrus-sasl )
+"
+# Keymap databases code is generated with python3; configure picks up $PYTHON exported from python-any-r1_pkg_setup
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=dev-lang/perl-5
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-0.9.4 )
+"
+# eautoreconf requires gnome-common
+
+src_prepare() {
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		$(use_with examples)
+		$(use_enable introspection)
+		$(use_with pulseaudio)
+		$(use_with sasl)
+		--with-coroutine=gthread
+		--without-libview
+		--disable-static
+		--disable-vala
+		--with-gtk=3.0
+	)
+
+	gnome2_src_configure ${myconf[@]}
+}