reinit the tree, so we can have metadata

1 files changed, 50 insertions, 0 deletions

diff --git a/net-libs/libnetfilter_acct/libnetfilter_acct-1.0.3.ebuild b/net-libs/libnetfilter_acct/libnetfilter_acct-1.0.3.ebuild
new file mode 100644
index 000000000000..07077ef36d8b
--- /dev/null
+++ b/net-libs/libnetfilter_acct/libnetfilter_acct-1.0.3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit eutils linux-info multilib
+
+DESCRIPTION="Userspace library providing interface to extended accounting infrastructure of NetFilter"
+HOMEPAGE="http://netfilter.org/projects/libnetfilter_acct"
+SRC_URI="http://www.netfilter.org/projects/${PN}/files/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~x86 ~amd64-linux"
+IUSE="examples"
+
+RDEPEND="
+	net-libs/libmnl
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+DOCS=( README )
+CONFIG_CHECK="~NETFILTER_NETLINK_ACCT"
+
+pkg_setup() {
+	kernel_is lt 3 3 && ewarn "This package will work with kernel version 3.3 or higher"
+	linux-info_pkg_setup
+}
+
+src_configure() {
+	econf \
+		--libdir="${EPREFIX}"/$(get_libdir)
+}
+
+src_install() {
+	default
+
+	dodir /usr/$(get_libdir)/pkgconfig/
+	mv "${ED}"/{,usr/}$(get_libdir)/pkgconfig/${PN}.pc || die
+
+	if use examples; then
+		find examples/ -name "Makefile*" -exec rm -f '{}' + || die 'find failed'
+		dodoc -r examples/
+		docompress -x /usr/share/doc/${P}/examples
+	fi
+
+	prune_libtool_files
+}