gentoo auto-resync : 19:10:2023 - 03:53:34

2 files changed, 231 insertions, 0 deletions

diff --git a/net-mail/courier-imap/Manifest b/net-mail/courier-imap/Manifest
index 18b0f1fb365d..5d93116d8b10 100644
--- a/net-mail/courier-imap/Manifest
+++ b/net-mail/courier-imap/Manifest
@@ -30,6 +30,7 @@ DIST courier-imap-5.1.8.tar.bz2 3395074 BLAKE2B 1d563d49d61f3ab89297afdc9dd29472
 DIST courier-imap-5.2.1.tar.bz2 3411197 BLAKE2B 7b34b523f7c8df3127af6cc7d10ca0bc78638e60d0bc52871d762a4dc28e192b8b64dc1e1a0ee572f11afb4ebd889bfbe426e7520e43caef16d40bdf0224a4bf SHA512 88ce60b666bc1db10059ffd34f76d8275f399ac1833ee820308db25df49ab4914a03547e6d58075d5fecb34204b5fb958877db06b3bb4529eb8cb9e547bbcf63
 DIST courier-imap-5.2.3.tar.bz2 3410307 BLAKE2B d6f9aa02c2367bca898a7322f55a6f178984b0828e16fd4755d221b02384068a54b99c336e3aa4ed247eb04663be041af81803cb27fe6bae6b2f57dfe445f919 SHA512 6df3c12aea6004875c3f1e8dce46b0f199b7e3c881acf79fe6df507022b5e9dcd0cc4ddef6a94bf8763746f4db58f47066731b1f969afcf5f51bed451116af4f
 DIST courier-imap-5.2.4.tar.bz2 3411159 BLAKE2B a26b8b3a6893cfb83ba4d6fa24eb3ac391b200c9642618c48db09d37f40ba8e0409165a8c7b448ab22fe3dd32b613a1a7b5de96860f0e8854a5b037979ea4441 SHA512 db5a53f82b66b2ed99a66f13c97b041e6e275b3ea662b85ce19b0aa13dfeb4e60ec091d608992f52691e3514c3d3429f9249ce5322c5e247fc0058dfef92716b
+DIST courier-imap-5.2.5.tar.bz2 3411629 BLAKE2B 764ac51815777df53b3ce429a4f50ca70f4f2d8b1920f1332691f4ed951939099fa46c0a11301ee0cbcc2471f2f73b7c4dfd8fe5de9389e883552658cd73eea4 SHA512 f7864bc7c23ee08ab8c90b3d83e577c62c468f96b2481e909dc0eb5aab6c6ef141e164742458776dd1106e50d8752e6e8102971a4e3d75d6a108dd72fcae0de4
 EBUILD courier-imap-5.1.2-r1.ebuild 7055 BLAKE2B 490ff0c972159bee1718f0a8f3c51fb0a2789b2f488f9344045950c3d20f908164947c68bada94196972c2cd8b7eb3f9a24a91630646e803fb53d359aeebff1d SHA512 86e7d1a28d6a37dc22471b9c965188f61b4b99ab8e1981f27c4cedb02ce3dbbbb4d8a4d3cfb1ce961a2f9cdc4b4e4c9195bc27651651e889c81f3a93b44f3c0d
 EBUILD courier-imap-5.1.3-r1.ebuild 7062 BLAKE2B 65a4b28c409357713d9f7a3b337e46cccf01853ab7fac27dcd0c5895d5275a61de53350a6b7961739eae42d007fe811b1eecf66e07b955734f46f0d8afff1835 SHA512 e0538948fb23aecc78e5d62f3ec86344e42e751577aac6443f0e556a326a04e51c0ac6b53ce154f0ba53c019f46be3726f13b5b9a7c5576c6c5d07149d588ecf
 EBUILD courier-imap-5.1.4.ebuild 7056 BLAKE2B 56a06f662daa0b4e45c0ed755c536a2f29f5168cfc84fe62db809de2865cbb4c3e74c2104034d9dce707d9e405c09f4c8523cbd163f7a96adf9669c27446ec3e SHA512 381c68368c66c33f7a0f709ac0b3ab430e5b10b57c0bc12ac6943969c7bb3dca1780bc423437316203fc9ac0d7ab50ae7906ac50cba0fa9302a4d17704c2eb7f
@@ -39,4 +40,5 @@ EBUILD courier-imap-5.2.1-r2.ebuild 7011 BLAKE2B e26d3e3539b36fe6b38fb03e2887201
 EBUILD courier-imap-5.2.1.ebuild 7070 BLAKE2B dd69c32c0842f300301ff00e8b5da9f448c0197a8fa86301f8847ee27dae131d75a90a3facf4180b4564dbe4147e21caf13b3e7b9617fe4f0f4c0d298ede20ce SHA512 324e24e982e846ac4562ffc5952968cc81e7f644452086f08790aaa4529b79467140b29981fd4ab8686a904d8cec3447fcc0b0a18e7b6edeaeadfa4988c9a568
 EBUILD courier-imap-5.2.3.ebuild 7018 BLAKE2B d7e465c4c82484697fd8abb743c5fa2f72490a8d3cbaaff52ad76e0417db9515c223a0d32660d831064339479a29297ed738b188bcfa9a6a5db2cf4015833f26 SHA512 e30cb82c215fc83d0450e882388436de4f52d44cf6315d16b685b3ef6640d6bcb7892702dab0ebeddfd60b0555a6b50a3d7dc29e05704d0ff60e479745ee58d3
 EBUILD courier-imap-5.2.4.ebuild 7038 BLAKE2B 5f9dca20c3d3f8280d961c80dce418641bf97a0109f03ed5b7e58e032b28309b98656227c7304a120ba2f35962b0df6a58d0e2eae0266d890d3da74ff7f0f988 SHA512 9c583b5fde0477dab60167312cea66f65b191dc38fe69b77be656fc4ccea9fa22221f488685777e20aa116a1303e250c5582449912c90cd980ef02056953f1d0
+EBUILD courier-imap-5.2.5.ebuild 6500 BLAKE2B 7bda0928b8ee3aed8d859d4a30dcc8017ba5b7f34615d23b2be7dfb9d20b474338dccbf0e13520cf68d2c47a609f0dfff239efe481cc2efacb6a44ab980918f1 SHA512 f3eebb7f10e19d2ec290eda59a3d45ea728f8915859c080777dc54e0511af71a4f6243d631d1bbf0af46fa7713f7302a420d21266bdf9df2d76cf8ec551c50f4
 MISC metadata.xml 463 BLAKE2B 548ad09a1ed2b0c44cbb80ab66b653185b178873ae88f5a33545b759914fcb9e6491eef7c9e6da0a713f40c92b3b084cb36dec6f411ca8cba6db76767c8ca237 SHA512 d1aaf82b4ce4775d8e8f97f8900e10aaf403b1224744263d76c3eb890e0ec08c8e108b2f631498bd21ae3551c211747374526d73dd9764c01c4e6af5de78b950
diff --git a/net-mail/courier-imap/courier-imap-5.2.5.ebuild b/net-mail/courier-imap/courier-imap-5.2.5.ebuild
new file mode 100644
index 000000000000..4a3263fa21b3
--- /dev/null
+++ b/net-mail/courier-imap/courier-imap-5.2.5.ebuild
@@ -0,0 +1,229 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit readme.gentoo-r1 systemd
+
+DESCRIPTION="An IMAP daemon designed specifically for maildirs"
+HOMEPAGE="https://www.courier-mta.org/imap/"
+SRC_URI="mirror://sourceforge/courier/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86"
+
+IUSE="berkdb debug +gdbm gnutls ipv6 selinux trashquota"
+REQUIRED_USE="|| ( berkdb gdbm )"
+
+CDEPEND="
+	gnutls? ( net-libs/gnutls:=[tools] )
+	!gnutls? (
+		dev-libs/openssl:0=
+	)
+	net-libs/courier-authlib
+	net-libs/courier-unicode
+	net-mail/mailbase
+	net-dns/libidn:=
+	berkdb? ( sys-libs/db:= )
+	gdbm? ( sys-libs/gdbm:= )
+	!mail-mta/courier
+"
+DEPEND="${CDEPEND}
+	dev-lang/perl
+	sys-process/procps
+"
+RDEPEND="${CDEPEND}
+	selinux? ( sec-policy/selinux-courier )
+"
+
+RDEPEND="${RDEPEND}
+	!net-mail/cyrus-imapd
+	!net-mail/courier-common
+"
+
+RC_VER="4.0.6-r1"
+INITD_VER="4.0.6-r1"
+
+# make check is not supported by this package due to the
+# --enable-workarounds-for-imap-client-bugs option.
+RESTRICT="test"
+
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="
+Please read http://www.courier-mta.org/imap/INSTALL.html#upgrading
+and remove TLS_DHPARAMS from configuration files or run mkdhparams
+
+For a quick-start howto please refer to
+${PN}-gentoo.readme in /usr/share/doc/${PF}
+
+Please convert maildir to utf8
+and rerun mkdhparams if needed. Location has changed
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.1.8-aclocal-fix.patch"
+	"${FILESDIR}/${PN}-5.0.8-ar-fix.patch"
+)
+
+src_configure() {
+	local myconf=""
+
+	# Default to gdbm if both berkdb and gdbm are present.
+	if use gdbm ; then
+		einfo "Building with GDBM support"
+		myconf="${myconf} --with-db=gdbm"
+	elif use berkdb ; then
+		einfo "Building with BerkeleyDB support"
+		myconf="${myconf} --with-db=db"
+	fi
+
+	if use trashquota ; then
+		einfo "Building with Trash Quota Support"
+		myconf="${myconf} --with-trashquota"
+	fi
+
+	econf \
+		--with-notice=unicode \
+		--disable-root-check \
+		--bindir=/usr/sbin \
+		--sysconfdir="/etc/${PN}" \
+		--libexecdir="/usr/$(get_libdir)/${PN}" \
+		--localstatedir="/var/lib/${PN}" \
+		--enable-workarounds-for-imap-client-bugs \
+		--with-mailuser=mail \
+		--with-mailgroup=mail \
+		--with-certsdir="/etc/courier-imap" \
+		$(use_with ipv6) \
+		$(use_with gnutls) \
+		${myconf}
+}
+
+src_install() {
+	dodir "/var/lib/${PN}" /etc/pam.d
+	keepdir /var/lib/courier-imap
+
+	default
+	rm -r "${D}/etc/pam.d" || die
+
+	# Avoid name collisions in /usr/sbin wrt imapd and pop3d
+	for name in imapd pop3d ; do
+		mv "${D}/usr/sbin/"{,courier-}${name} \
+			|| die "failed to rename ${name} to courier-${name}"
+	done
+
+	# Hack /usr/lib/courier-imap/foo.rc to use ${MAILDIR} instead of
+	# 'Maildir', and to use /usr/sbin/courier-foo names.
+	for service in {imapd,pop3d}{,-ssl} ; do
+		sed -e 's/Maildir/${MAILDIR}/' \
+			-i "${D}/usr/$(get_libdir)/${PN}/${service}.rc" \
+			|| die "sed failed"
+		sed -e "s/\/usr\/sbin\/${service}/\/usr\/sbin\/courier-${service}/" \
+			-i "${D}/usr/$(get_libdir)/${PN}/${service}.rc" \
+			|| die "sed failed"
+	done
+
+	# Rename the config files correctly and add a value for ${MAILDIR}
+	# to them.
+	for service in {imapd,pop3d}{,-ssl} ; do
+		mv "${D}/etc/${PN}/${service}"{.dist,} \
+			|| die "failed to rename ${service}.dist to ${service}"
+		echo -e '\n# Hardwire a value for ${MAILDIR}' \
+			 >> "${D}/etc/${PN}/${service}"
+		echo 'MAILDIR=.maildir' >> "${D}/etc/${PN}/${service}"
+		echo 'MAILDIRPATH=.maildir' >> "${D}/etc/${PN}/${service}"
+	done
+
+	for service in imapd pop3d ; do
+		echo -e '# Put any program for ${PRERUN} here' \
+			 >> "${D}/etc/${PN}/${service}"
+		echo 'PRERUN=' >> "${D}/etc/${PN}/${service}"
+		echo -e '# Put any program for ${LOGINRUN} here' \
+			 >> "${D}/etc/${PN}/${service}"
+		echo -e '# this is for relay-ctrl-allow in 4*' \
+			 >> "${D}/etc/${PN}/${service}"
+		echo 'LOGINRUN=' >> "${D}/etc/${PN}/${service}"
+	done
+
+	for x in "${D}/usr/sbin"/* ; do
+		if [[ -L "${x}" ]] ; then
+			rm "${x}" || die "failed to remove ${x}"
+		fi
+	done
+
+	mv "${D}/usr/share"/* "${D}/usr/sbin/" || die
+	mv "${D}/usr/sbin/man" "${D}/usr/share/" || die
+
+	rm "${D}/usr/sbin/"{mkimapdcert,mkpop3dcert} || die
+
+	dosbin "${FILESDIR}/mkimapdcert" "${FILESDIR}/mkpop3dcert"
+
+	dosym ../../sbin/courierlogger "/usr/$(get_libdir)/${PN}/courierlogger"
+
+	for initd in courier-{imapd,pop3d}{,-ssl} ; do
+		sed -e "s:GENTOO_LIBDIR:$(get_libdir):g" \
+			"${FILESDIR}/${PN}-${INITD_VER}-${initd}.rc6" \
+			> "${T}/${initd}" \
+			|| die "initd libdir-sed failed"
+		doinitd "${T}/${initd}"
+	done
+
+	cp "${FILESDIR}"/courier-*-r1.service .
+
+	sed -i \
+		-e "s:/usr/lib/:/usr/$(get_libdir)/:" \
+		courier-*-r1.service \
+		|| die
+
+	systemd_newunit courier-authdaemond-r1.service \
+					courier-authdaemond.service
+	systemd_newunit courier-imapd-ssl-r1.service \
+					courier-imapd-ssl.service
+	systemd_newunit courier-imapd-r1.service \
+					courier-imapd.service
+
+	exeinto "/usr/$(get_libdir)/${PN}"
+	for exe in gentoo-{imapd,pop3d}{,-ssl}.rc courier-{imapd,pop3d}.indirect ; do
+		sed -e "s:GENTOO_LIBDIR:$(get_libdir):g" \
+			"${FILESDIR}/${PN}-${RC_VER}-${exe}" \
+			> "${T}/${exe}" \
+			|| die "exe libdir-sed failed"
+		doexe "${T}/${exe}"
+	done
+
+	# Avoid a collision with mail-mta/netqmail, bug 482098.
+	mv "${D}/usr/sbin/"{,courier-}maildirmake \
+		|| die "failed to rename maildirmake to courier-maildirmake"
+	mv "${D}/usr/share/man/man1/"{,courier-}maildirmake.1 \
+		|| die "failed to rename maildirmake.1 to courier-maildirmake.1"
+
+	rm -rf "${D}"/usr/sbin/doc
+
+	dodoc AUTHORS INSTALL NEWS README ChangeLog
+	readme.gentoo_create_doc
+	dodoc "${FILESDIR}/${PN}-gentoo.readme"
+	docinto imap
+	dodoc libs/imap/ChangeLog libs/imap/BUGS* libs/imap/README*
+	docinto maildir
+	dodoc libs/maildir/AUTHORS libs/maildir/*.html libs/maildir/README*
+	docinto rfc2045
+	dodoc libs/rfc2045/*.html
+	docinto tcpd
+	dodoc libs/tcpd/README* libs/tcpd/*.html
+	exeinto /etc/cron.monthly
+	newexe "${FILESDIR}"/${PN}.cron ${PN}
+}
+
+pkg_postinst() {
+	# Some users have been reporting that permissions on this directory were
+	# getting scrambled, so let's ensure that they are sane.
+	fperms 0755 "${ROOT}/usr/$(get_libdir)/${PN}"
+
+	readme.gentoo_print_elog
+
+	elog ""
+	elog "Courier Imap now run as user mail:mail."
+	elog ""
+	elog "This require you to enable read/write access to the caches:"
+	elog "/var/lib/courier-imap/courierssl*cache (chown mail:mail)"
+	elog "and read access to the certificates (e.g. /etc/courier-imap/pop3d.pem )"
+}