gentoo resync : 29.12.2022

2 files changed, 244 insertions, 0 deletions

diff --git a/net-mail/cyrus-imapd/Manifest b/net-mail/cyrus-imapd/Manifest
index 76c99de80e35..0d905c5498a0 100644
--- a/net-mail/cyrus-imapd/Manifest
+++ b/net-mail/cyrus-imapd/Manifest
@@ -8,8 +8,10 @@ DIST cyrus-imapd-3.0.16.tar.gz 10875516 BLAKE2B 10915418b4de3f460a20d3808274f9ea
 DIST cyrus-imapd-3.0.17.tar.gz 11445224 BLAKE2B bf2cd85f878c1b4198be5ce96cf6a4ae1e4fcc765b0c7fe60a6bfd04dd066c0420f86508cbfc1030831b57c2732715440cbf0e327f5147b074fe12926dcda85f SHA512 75519bf8a2ae4a8ff844338bee641d519eaf3419fb81b819dc7a42e5956ef57569e47a0e094ccb9726a9c43f0469cd3def6c62783565b2a2aaa863bda354a7da
 DIST cyrus-imapd-3.4.2.tar.gz 12603768 BLAKE2B 515c36fc3d6a29991283d47a3e523d87a68c3191b4aae85074f40b2416fe3a89793f1991dc5729912a3d56247f6fbf4aed52abcadbc37ca7cc9bf857a8641871 SHA512 4d7d14e222bc1e97b2d8188804139c4c477de66cb621caba475b57533739ee59d88504d4f47735bb6a6b3c9097dbec382ecfa2c678f978791b9a6956a3cd91d6
 DIST cyrus-imapd-3.4.3.tar.gz 13182110 BLAKE2B 485df8e2518a55a3b096d0c330d55f7ed93209ca4ab5851dda53083082e203ad9b1d9218c0863a9bd1e678a732427ef499ff78bacf2d3fb2fe18464186a9e6d2 SHA512 5c4db2a0c26d2323332c1ba67f7b207acfad15f0442f20c6c8a205b5423498465524398315946213c8168bc7eba1fd9f7dc573a91efac6708bfbaf2cb57e9276
+DIST cyrus-imapd-3.4.4.tar.gz 13236335 BLAKE2B 105ae3defcf321a01394b38672b080ea58f68ecdc41384af46186c6ef88c02061ac066bd3e382d7b649761d5e462f2310a4568989c87e5ec518e08051179f4b3 SHA512 7904a9d0535e9d606bbb7748a4886e10092e2b682180dddf94933199f19402ae6f5cc4472a3797decf9ef20d3a8b7f1715ab00f6751037f14b19cd7322942dc2
 EBUILD cyrus-imapd-3.0.16-r2.ebuild 6016 BLAKE2B e85d06a61f6c6573624cbbc92a118712dde2e095174fd7726ee09d4e765d435613e0534d7a76d0df4c94118207b799507d18d27670607c852c12c2b74cb127cb SHA512 35ac8660c0d6812b162083004559dd71ddaef2ea7d34320901b2639a4d6033bbe0d7b448292df2117a5cd03f3469e172cdc6b9645281979a6befe85ab56edcbe
 EBUILD cyrus-imapd-3.0.17-r1.ebuild 6022 BLAKE2B 619618570289290e0a697e9280a18f249ef8898d1324f77f43b8ae0b275694f7b4f94b34ad822e4c90a923ed86b5d542d8b232e3a762aa093f353c0aad721f74 SHA512 17bc28ca592afc4c6a29fc765738c41c753e1f58996c40017d24c81584bf58493bc9e619ed36b4a6b6c90003cc9c4cd6e392f89a7b252bde16ed07af30240dbc
 EBUILD cyrus-imapd-3.4.2-r2.ebuild 5964 BLAKE2B d3b7b21d6da88a922562ab86a32995c89c4e18b550b20eef3e1f7c7b152262b01c0b57839b12acbe7afff20be07908557a43669eb853c1cf44ad2899a3cdba30 SHA512 c7645c12b7506b83f7db973eea2719f9fb4ce902ac312338df9c5a2faca0e22520c8af04c9e0e65348b672d61796789952b910a8e60b8476c876360e05d85d63
 EBUILD cyrus-imapd-3.4.3-r2.ebuild 6312 BLAKE2B e9bf941312e9e622202abadc96e292449eb546c8dc8c432175ec15c723ddb18a5d46a66f86e4a93bbe5235c65458b14b6894d401b69879835a7598acf5fbaf7a SHA512 97056231855cdce65e008aa8b4bb56bd79c2c617606df61e0e662c7c818521567b04f7677b67684f06d87d813d4053d98b5d9b0ba61a1a68c08b9fba64a71527
+EBUILD cyrus-imapd-3.4.4.ebuild 6312 BLAKE2B e9bf941312e9e622202abadc96e292449eb546c8dc8c432175ec15c723ddb18a5d46a66f86e4a93bbe5235c65458b14b6894d401b69879835a7598acf5fbaf7a SHA512 97056231855cdce65e008aa8b4bb56bd79c2c617606df61e0e662c7c818521567b04f7677b67684f06d87d813d4053d98b5d9b0ba61a1a68c08b9fba64a71527
 MISC metadata.xml 756 BLAKE2B e67e371c0daf545e354680a35bbfda109d5bac966c75d048f3fef045def983410926fb02bd9f36906251b32696cba41733969912c0d5a5496717de0626fd10ae SHA512 0e558ce2562227134bb7c5ebc95b44b353b2e4361744366862708ff8942a1cddffb931d58811fa6c511b7057a083e05c47c76453ba3dfba89d77ba8db0402b7b
diff --git a/net-mail/cyrus-imapd/cyrus-imapd-3.4.4.ebuild b/net-mail/cyrus-imapd/cyrus-imapd-3.4.4.ebuild
new file mode 100644
index 000000000000..fd888906a05d
--- /dev/null
+++ b/net-mail/cyrus-imapd/cyrus-imapd-3.4.4.ebuild
@@ -0,0 +1,242 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# Keep an eye on https://www.cyrusimap.org/imap/developer/compiling.html!
+inherit autotools flag-o-matic pam ssl-cert
+
+DESCRIPTION="The Cyrus IMAP Server"
+HOMEPAGE="https://www.cyrusimap.org/"
+SRC_URI="https://github.com/cyrusimap/${PN}/releases/download/${P}/${P}.tar.gz"
+
+LICENSE="BSD-with-attribution GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="afs backup calalarm caps clamav http kerberos ldap \
+	mysql nntp pam perl postgres replication +server sieve \
+	sqlite ssl static-libs tcpd test xapian"
+RESTRICT="!test? ( test )"
+
+DEPEND="dev-libs/libpcre:3
+	>=dev-libs/cyrus-sasl-2.1.13:2
+	dev-libs/jansson:=
+	dev-libs/icu:=
+	sys-apps/util-linux
+	sys-fs/e2fsprogs:=
+	sys-libs/zlib:=
+	afs? ( net-fs/openafs )
+	calalarm? ( dev-libs/libical:= )
+	caps? ( sys-libs/libcap )
+	clamav? ( app-antivirus/clamav )
+	http? (
+		app-arch/brotli:=
+		app-arch/zstd:=
+		dev-libs/libxml2
+		dev-libs/libical:=
+		net-libs/nghttp2:=
+		sci-libs/shapelib:=
+	)
+	kerberos? ( virtual/krb5 )
+	ldap? ( net-nds/openldap:= )
+	mysql? ( dev-db/mysql-connector-c:= )
+	nntp? ( !net-nntp/leafnode )
+	pam? (
+		>=net-mail/mailbase-1
+		sys-libs/pam
+	)
+	perl? (
+		dev-lang/perl:=
+		virtual/perl-Term-ReadLine
+	)
+	postgres? ( dev-db/postgresql:* )
+	ssl? ( >=dev-libs/openssl-1.0.1e:=[-bindist(-)] )
+	sqlite? ( dev-db/sqlite:3 )
+	tcpd? ( >=sys-apps/tcp-wrappers-7.6 )
+	xapian? ( >=dev-libs/xapian-1.4.0:= )"
+# all blockers really needed?
+# file collision with app-arch/dump - bug 619584
+RDEPEND="${DEPEND}
+	acct-group/mail
+	acct-user/cyrus
+	!mail-mta/courier
+	!net-mail/bincimap
+	!net-mail/courier-imap
+	!net-mail/uw-imap
+	!app-arch/dump"
+DEPEND+=" test? ( dev-util/cunit )"
+BDEPEND="sys-devel/flex
+	virtual/pkgconfig
+	virtual/yacc"
+
+REQUIRED_USE="afs? ( kerberos )
+	backup? ( sqlite )
+	calalarm? ( http )
+	http? ( sqlite )"
+
+# https://bugs.gentoo.org/678754
+# TODO: check underlinking for other libraries
+#PATCHES=(
+#	"${FILESDIR}/cyrus-imapd-libcap-libs-r1.patch"
+#)
+
+src_prepare() {
+	default
+
+	# Fix master(8)->cyrusmaster(8) manpage.
+	for i in `grep -rl -e 'master\.8' -e 'master(8)' "${S}"` ; do
+		sed -i -e 's:master\.8:cyrusmaster.8:g' \
+			-e 's:master(8):cyrusmaster(8):g' \
+			"${i}" || die "sed failed" || die "sed failed"
+	done
+	mv man/master.8 man/cyrusmaster.8 || die "mv failed"
+	sed -i -e "s:MASTER:CYRUSMASTER:g" \
+		-e "s:Master:Cyrusmaster:g" \
+		-e "s:master:cyrusmaster:g" \
+		man/cyrusmaster.8 || die "sed failed"
+
+	# lock.h to afs/lock.h
+	sed -i -e '/lock.h/s:lock.h:afs/lock.h:' \
+		ptclient/afskrb.c || die
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+
+	# bug #604466
+	append-ldflags $(no-as-needed)
+
+	# Workaround runtime crash
+	# bug #834573
+	append-flags -fno-toplevel-reorder
+
+	if use afs ; then
+		myconf+=" --with-afs-libdir=/usr/$(get_libdir)"
+		myconf+=" --with-afs-incdir=/usr/include/afs"
+	fi
+
+	# TODO:
+	# - revisit --with-sphinx-build=no? (it's docs this time, not the search engine)
+	# - post-emerge message re lmdb removal?
+	econf \
+		--enable-murder \
+		--enable-idled \
+		--enable-autocreate \
+		--enable-pcre \
+		--with-com_err \
+		--with-cyrus-user=cyrus \
+		--with-sasl \
+		--with-sphinx-build=no \
+		--without-krb \
+		--without-krbdes \
+		--enable-squat \
+		--with-zlib \
+		--without-wslay \
+		--without-chardet \
+		--without-cld2 \
+		--disable-srs \
+		$(use_enable afs) \
+		$(use_enable afs krb5afspts) \
+		$(use_enable backup) \
+		$(use_enable calalarm calalarmd) \
+		$(use_with caps libcap) \
+		$(use_with clamav) \
+		$(use_enable nntp) \
+		$(use_enable http) \
+		$(use_with http nghttp2) \
+		$(use_enable replication) \
+		$(use_enable kerberos gssapi) \
+		$(use_with ldap) \
+		$(use_with mysql) \
+		$(use_with postgres pgsql) \
+		$(use_with perl) \
+		$(use_with sqlite) \
+		$(use_with ssl openssl) \
+		$(use_enable server) \
+		$(use_enable sieve) \
+		$(use_enable static-libs static) \
+		$(use_with tcpd libwrap) \
+		$(use_enable xapian) \
+		$(use_enable test unit-tests) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" INSTALLDIRS=vendor install
+
+	dodoc README*
+	dodoc -r doc
+
+	cp -r contrib tools "${ED}"/usr/share/doc/${PF} || die
+	rm -f doc/text/Makefile* || die
+
+	mv "${ED}"/usr/libexec/{master,cyrusmaster} || die
+
+	insinto /etc
+	newins "${ED}"/usr/share/doc/${PF}/doc/examples/cyrus_conf/normal.conf cyrus.conf
+	newins "${ED}"/usr/share/doc/${PF}/doc/examples/imapd_conf/normal.conf imapd.conf
+
+	sed -i -e '/^configdirectory/s|/var/.*|/var/imap|' \
+		-e '/^partition-default/s|/var/.*|/var/spool/imap|' \
+		-e '/^sievedir/s|/var/.*|/var/imap/sieve|' \
+		"${ED}"/etc/imapd.conf || die
+
+	sed -i -e 's|/var/imap/socket/lmtp|/run/cyrus/socket/lmtp|' \
+		-e 's|/var/imap/socket/notify|/run/cyrus/socket/notify|' \
+		"${ED}"/etc/cyrus.conf || die
+
+	# turn off sieve if not installed
+	if ! use sieve; then
+		sed -i -e "/sieve/s/^/#/" "${ED}"/etc/cyrus.conf || die
+	fi
+
+	# same thing for http(s) as well
+	if ! use http; then
+		sed -i -e "/http/s/^/#/" "${ED}"/etc/cyrus.conf || die
+	fi
+
+	newinitd "${FILESDIR}"/cyrus.rc8 cyrus
+	newconfd "${FILESDIR}"/cyrus.confd cyrus
+	newpamd "${FILESDIR}"/cyrus.pam-include sieve
+
+	for subdir in imap/{,db,log,msg,proc,socket,sieve} spool/imap/{,stage.} ; do
+		keepdir "/var/${subdir}"
+		fowners cyrus:mail "/var/${subdir}"
+		fperms 0750 "/var/${subdir}"
+	done
+
+	for subdir in imap/{user,quota,sieve} spool/imap ; do
+		for i in a b c d e f g h i j k l m n o p q r s t v u w x y z ; do
+			keepdir "/var/${subdir}/${i}"
+			fowners cyrus:mail "/var/${subdir}/${i}"
+			fperms 0750 "/var/${subdir}/${i}"
+		done
+	done
+}
+
+pkg_preinst() {
+	if ! has_version ${CATEGORY}/${PN} ; then
+		elog "For correct logging add the following to /etc/syslog.conf:"
+		elog "    local6.*         /var/log/imapd.log"
+		elog "    auth.debug       /var/log/auth.log"
+		echo
+
+		elog "You have to add user cyrus to the sasldb2. Do this with:"
+		elog "    saslpasswd2 cyrus"
+	fi
+}
+
+pkg_postinst() {
+	# do not install server.{key,pem) if they exist
+	if use ssl ; then
+		if [[ ! -f "${ROOT}"/etc/ssl/cyrus/server.key ]]; then
+			install_cert /etc/ssl/cyrus/server
+			chown cyrus:mail "${ROOT}"/etc/ssl/cyrus/server.{key,pem}
+		fi
+	fi
+
+	einfo "Please see https://www.cyrusimap.org/imap/download/upgrade.html"
+	einfo "for upgrade instructions."
+}