gentoo resync : 30.04.2018

2 files changed, 223 insertions, 0 deletions

diff --git a/net-mail/cyrus-imapd/Manifest b/net-mail/cyrus-imapd/Manifest
index 6c92c3173ac0..3daaa2f19404 100644
--- a/net-mail/cyrus-imapd/Manifest
+++ b/net-mail/cyrus-imapd/Manifest
@@ -13,8 +13,10 @@ DIST cyrus-imapd-2.5.10.tar.gz 3103914 BLAKE2B 588764d47b3d458633e0ced2619cc1ccc
 DIST cyrus-imapd-2.5.11.tar.gz 3109188 BLAKE2B 9382d8e4b9317f7fa12f63f7262eb0c6a1571d405665694f735fb72b6de76058ea586172f2001babe280170f122c887374b1378f51fe9c89a522aaeb74b885c9 SHA512 bbb0e11f31d91d85037306321165e3608f8d5e2699b971fc4fbdd1630ec0a1485c8f6f17900142dec584ab41b0ec0c65c11cfaf8c5bbf1054b194a8f5f361538
 DIST cyrus-imapd-3.0.4.tar.gz 10819487 BLAKE2B 209e379731c996ee083b0de61d6122b3756d1f6880071ebf015157057cf45845961d762ee762ae56213f72f15c01df29ab2d2661c4e352c6b4a680924d15d7b0 SHA512 9ceb7ac837c932c70fa0c1583bf8700b3ec27568d72538ae8d59f2f551e3007b3c2fc68fd29c009597c3949345dbe1bf2eb614bea038d70a5b49e5507df6b69a
 DIST cyrus-imapd-3.0.5.tar.gz 10910080 BLAKE2B a7914ab189a290427ddc0d013c19ff0c36f3a6c4fc016f50013d0f6abb11ae2f7d067b71df99b7f00ba4e8a2170e0f068baa170458b0dc1e94d69d8e4b814873 SHA512 262806729d5ee5d753732603aa7af33c6f96bc5145b7a951b8668ffdee0dcd4a90bd287da0949e85c4596cccb471a688f7f8b6f3e39194e1cff311950d4d4410
+DIST cyrus-imapd-3.0.6.tar.gz 10734548 BLAKE2B d16d1093b17f632fa75e77c1b923deb0c5a76de4c06a657c4c1dd2f9498ac0abd81ecee58c64378118d4b09be872957afc6db5d8deebf72c819623d6ea5aa0a9 SHA512 375e3936465e9ee448996cf738ebe93a35697a58a7784cf6f7a8be25e3e03925fb4f44ff98a0aacbc5b9e3ef39fc8a0e51acb4ea26cbbfbc8e492556fdc03a03
 EBUILD cyrus-imapd-2.5.10.ebuild 4676 BLAKE2B 4e3960ade8b08e85a9beec894dd11bd144b218ca665fb4ddd762db8e881dbaa8a1f814fdf8e811e7d54e5d4f6456d601898f2fd1b7065be6edfa6c38dd83b965 SHA512 80bd9c18c80d5408862f4ad20b4f0f82c21b3a11f5ef54e504cdea454e0a7fde5f0cd8ffbf455665b0a907eadc243c45d5ccae9a08dde5faca7ff2f9cddb1ceb
 EBUILD cyrus-imapd-2.5.11-r1.ebuild 4772 BLAKE2B 72c2a8d1927728dfb638eac22ed3ecff4651dcee12250e169683dc910c8132320ec23b09408eace65799be99629c529a37298f5cb51d91817fa7c44899d02fac SHA512 c14ac12b41bb9594b7686ff6f1fe44e9af160f8eed4cfa7e1c94d1c5098fb55ec160b7b6bfe30bfca494278d18bfd3c9c37a8ed3991e02889512d43f9dd4ceb1
 EBUILD cyrus-imapd-3.0.4.ebuild 5896 BLAKE2B 933086d8d6d45ec33a5a82a0a4a90b1c83848a9d59e39d2027da4ea52a28e9302040e39f61a28ef6112d012cd7bd4b9934506993cb2b8d6a1de75a15a59828d0 SHA512 e0ebe34958c93003798a045c64287dda83d97d1d829889f4601446567ac2f0334a03acd554f0cacdd86b90fbf167f13c020e5b3edbdf78f3d9f9a9d871ea140f
 EBUILD cyrus-imapd-3.0.5.ebuild 5944 BLAKE2B 43fa76c0bda73b8e67440692b3f5586c6bd4435a852c90c63b986db724eca95c12056182e6f52bbdab827aea004e75257a6bf7ff5b0d1ae66d54a865c5b22d5b SHA512 2e9f38bb940bf33982b5879e39106e195dadc47c75772951cfc077873c40d38bcbf479c42ab915b620c1d442d454fc8314f10a98400464f11d2798ced74fa536
+EBUILD cyrus-imapd-3.0.6.ebuild 5946 BLAKE2B 39e6abd36bcc447a79b6b6e34f051090237ee96996f00980e3f1ebf70fa66b1791ac2ad3ed42f1038ffcbf32a650b3d9e29b3d19e5aede7c960ce11d23377a7f SHA512 66fd355b5c1f3f1b99f96829de8f5d670edaaa0cc4129a8a08d8b30509b86104456fcb912f1a444bba2132d0724530b7978d1d9dab220a5cdfc906506583c8e1
 MISC metadata.xml 871 BLAKE2B 4fe48aebf6e59d75cf53cafc92d5bf4668c4a489dba3a43d6df6c4efaeb74590c49f083e03ee9d5eed32ee09b324d8116bcb0fc77576f8aa77a96c56a739dfae SHA512 25449c1218dfad7b692b37b799a659b6a10e0e31bb003fbed27b3b43ce3610f9ee5f17a995cf9244d5027ad84889a8e79a774f63101bb6ea35054ce9dbb1fe20
diff --git a/net-mail/cyrus-imapd/cyrus-imapd-3.0.6.ebuild b/net-mail/cyrus-imapd/cyrus-imapd-3.0.6.ebuild
new file mode 100644
index 000000000000..b5c209187c18
--- /dev/null
+++ b/net-mail/cyrus-imapd/cyrus-imapd-3.0.6.ebuild
@@ -0,0 +1,221 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools flag-o-matic pam ssl-cert user
+
+MY_P=${P/_/}
+
+DESCRIPTION="The Cyrus IMAP Server"
+HOMEPAGE="http://www.cyrusimap.org/"
+SRC_URI="ftp://ftp.cyrusimap.org/cyrus-imapd/${MY_P}.tar.gz"
+
+LICENSE="BSD-with-attribution"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="afs backup calalarm caps clamav http kerberos ldap lmdb \
+	mysql nntp pam perl postgres replication +server sieve snmp \
+	sphinx sqlite ssl static-libs tcpd test xapian"
+
+# virtual/mysql-5.5 added for the --variable= option below
+CDEPEND="sys-libs/zlib
+	dev-libs/libpcre
+	>=dev-libs/cyrus-sasl-2.1.13
+	dev-libs/jansson
+	dev-libs/icu:=
+	sys-libs/e2fsprogs-libs
+	afs? ( net-fs/openafs )
+	calalarm? ( dev-libs/libical )
+	caps? ( sys-libs/libcap )
+	clamav? ( app-antivirus/clamav )
+	http? ( dev-libs/libxml2 dev-libs/libical )
+	kerberos? ( virtual/krb5 )
+	ldap? ( net-nds/openldap )
+	lmdb? ( dev-db/lmdb )
+	mysql? ( >=virtual/mysql-5.5 )
+	nntp? ( !net-nntp/leafnode )
+	pam? (
+			virtual/pam
+			>=net-mail/mailbase-1
+		)
+	perl? ( dev-lang/perl:= )
+	postgres? ( dev-db/postgresql:* )
+	snmp? ( >=net-analyzer/net-snmp-5.2.2-r1 )
+	ssl? ( >=dev-libs/openssl-1.0.1e:0[-bindist] )
+	sqlite? ( dev-db/sqlite:3 )
+	tcpd? ( >=sys-apps/tcp-wrappers-7.6 snmp? ( net-analyzer/net-snmp[tcpd=] ) )
+	xapian? ( >=dev-libs/xapian-1.4.0 )"
+
+DEPEND="${CDEPEND}
+	test? ( dev-util/cunit )"
+
+# all blockers really needed?
+# file collision with app-arch/dump - bug 619584
+RDEPEND="${CDEPEND}
+	!mail-mta/courier
+	!net-mail/bincimap
+	!net-mail/courier-imap
+	!net-mail/uw-imap
+	!net-mail/cyrus-imap-admin
+	!app-arch/dump"
+
+REQUIRED_USE="afs? ( kerberos )
+	backup? ( sqlite )
+	calalarm? ( http )
+	http? ( sqlite )
+	sphinx? ( mysql )"
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	enewuser cyrus -1 -1 /usr/cyrus mail
+	append-ldflags $(no-as-needed)
+}
+
+src_prepare() {
+	# bug 604470
+	eapply -p1 "${FILESDIR}/${PN}-sieve-libs-v4.patch"
+	eapply -p1 "${FILESDIR}/${PN}-libcap-libs.patch"
+	# Fix master(8)->cyrusmaster(8) manpage.
+	for i in `grep -rl -e 'master\.8' -e 'master(8)' "${S}"` ; do
+		sed -i -e 's:master\.8:cyrusmaster.8:g' \
+			-e 's:master(8):cyrusmaster(8):g' \
+			"${i}" || die "sed failed" || die "sed failed"
+	done
+	mv man/master.8 man/cyrusmaster.8 || die "mv failed"
+	sed -i -e "s:MASTER:CYRUSMASTER:g" \
+		-e "s:Master:Cyrusmaster:g" \
+		-e "s:master:cyrusmaster:g" \
+		man/cyrusmaster.8 || die "sed failed"
+
+	# lock.h to afs/lock.h
+	sed -i -e '/lock.h/s:lock.h:afs/lock.h:' \
+		ptclient/afskrb.c || die
+
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+	if use afs ; then
+		myconf+=" --with-afs-libdir=/usr/$(get_libdir)"
+		myconf+=" --with-afs-incdir=/usr/include/afs"
+	fi
+	econf \
+		--enable-unit-tests \
+		--enable-murder \
+		--enable-idled \
+		--enable-event-notification \
+		--enable-autocreate \
+		--enable-pcre \
+		--with-cyrus-user=cyrus \
+		--with-cyrus-group=mail \
+		--with-sasl \
+		--without-krb \
+		--without-krbdes \
+		--enable-squat \
+		--with-zlib \
+		$(use_enable afs) \
+		$(use_enable afs krb5afspts) \
+		$(use_enable backup) \
+		$(use_enable calalarm calalarmd) \
+		$(use_with caps libcap) \
+		$(use_with clamav) \
+		$(use_enable nntp) \
+		$(use_enable http) \
+		$(use_enable replication) \
+		$(use_enable kerberos gssapi) \
+		$(use_with ldap) \
+		$(use_with lmdb) \
+		$(use_with mysql) \
+		$(use_with postgres pgsql) \
+		$(use_with perl) \
+		$(use_with sqlite) \
+		$(use_with ssl openssl) \
+		$(use_enable server) \
+		$(use_enable sieve) \
+		$(use_with snmp) \
+		$(use_enable sphinx) \
+		$(use_enable static-libs static) \
+		$(use_with tcpd libwrap) \
+		$(use_enable xapian) \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" INSTALLDIRS=vendor install
+
+	dodoc README*
+	dodoc -r doc
+	cp -r contrib tools "${D}/usr/share/doc/${PF}"
+	rm -f doc/text/Makefile*
+
+	mv "${D}"usr/libexec/{master,cyrusmaster} || die
+
+	insinto /etc
+	newins "${D}usr/share/doc/${PF}/doc/examples/cyrus_conf/normal.conf" cyrus.conf
+	newins "${D}usr/share/doc/${PF}/doc/examples/imapd_conf/normal.conf" imapd.conf
+
+	sed -i -e '/^configdirectory/s|/var/.*|/var/imap|' \
+		-e '/^partition-default/s|/var/.*|/var/spool/imap|' \
+		-e '/^sievedir/s|/var/.*|/var/imap/sieve|' \
+		"${D}"etc/imapd.conf
+
+	sed -i -e 's|/var/imap/socket/lmtp|/run/cyrus/socket/lmtp|' \
+		-e 's|/var/imap/socket/notify|/run/cyrus/socket/notify|' \
+		"${D}"etc/cyrus.conf
+
+	# turn off sieve if not installed
+	if ! use sieve; then
+		sed -i -e "/sieve/s/^/#/" "${D}/etc/cyrus.conf" || die
+	fi
+	# same thing for http(s) as well
+	if ! use http; then
+		sed -i -e "/http/s/^/#/" "${D}/etc/cyrus.conf" || die
+	fi
+
+	newinitd "${FILESDIR}/cyrus.rc8" cyrus
+	newconfd "${FILESDIR}/cyrus.confd" cyrus
+	newpamd "${FILESDIR}/cyrus.pam-include" sieve
+
+	for subdir in imap/{,db,log,msg,proc,socket,sieve} spool/imap/{,stage.} ; do
+		keepdir "/var/${subdir}"
+		fowners cyrus:mail "/var/${subdir}"
+		fperms 0750 "/var/${subdir}"
+	done
+	for subdir in imap/{user,quota,sieve} spool/imap ; do
+		for i in a b c d e f g h i j k l m n o p q r s t v u w x y z ; do
+			keepdir "/var/${subdir}/${i}"
+			fowners cyrus:mail "/var/${subdir}/${i}"
+			fperms 0750 "/var/${subdir}/${i}"
+		done
+	done
+}
+
+pkg_preinst() {
+	if ! has_version ${CATEGORY}/${PN} ; then
+		elog "For correct logging add the following to /etc/syslog.conf:"
+		elog "    local6.*         /var/log/imapd.log"
+		elog "    auth.debug       /var/log/auth.log"
+		echo
+
+		elog "You have to add user cyrus to the sasldb2. Do this with:"
+		elog "    saslpasswd2 cyrus"
+	fi
+}
+
+pkg_postinst() {
+	# do not install server.{key,pem) if they exist
+	if use ssl ; then
+		if [ ! -f "${ROOT}"etc/ssl/cyrus/server.key ]; then
+			install_cert /etc/ssl/cyrus/server
+			chown cyrus:mail "${ROOT}"etc/ssl/cyrus/server.{key,pem}
+		fi
+	fi
+
+	echo
+	einfo "Please see http://www.cyrusimap.org/imap/download/upgrade.html"
+	einfo "for upgrade instructions."
+	echo
+}