gentoo resync : 13.10.2019

2 files changed, 91 insertions, 0 deletions

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index 08e1d04b72df..8c70f8f338b8 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,3 +1,5 @@
 DIST nextcloud-client-2.5.2.tar.gz 18995992 BLAKE2B 6ad23962d327c1feeec34f59092021f7f82f4baeaf973fac0572db55cb03bc8ba2ed0c5037bcbfa80ca057d3976aaf6e402e129f2ec963b3a9c432330ef6aaf3 SHA512 1000b420355d7a4104ca5b41e813d467dcb345b60c79c78ce532de9c58ea89cad10d5565a433409bd512f0f7771c18c7c27974b968c74f84ccfda1ed3510d3ae
+DIST nextcloud-client-2.6.0.tar.gz 18789917 BLAKE2B db5c703ecf630a96c141c9c8a7b15894c5a679e1b36217f38a02cd55307fadb5ea19c13ab44371fbbcf0610ddafdd2fb0c1ef6119db04808b94a72dbfb27da9a SHA512 161733540de85c436e204b150fb91b527737fee213e569335248ce7c6e1446497aad5e3fa814b3f98a1ec0cdb94fad64ccc0807eb953a94170f9d40abb478545
 EBUILD nextcloud-client-2.5.2.ebuild 2006 BLAKE2B 2e5da149dd376fef452c36eb7279ce4a0e7832219d5edc25f823bc691b2d5c37c838b148c2affef9854532625292a99282cfdfe073cc6e6ea3e0f9d67a7a6bfc SHA512 cdc60ee671e822eef98ec463382afe43997a0f220f7bde50cb0a20940131c4262384ccc767db2e5dcb86c7ba86eed1b7f80508764530569a122a648a9c0f83a7
+EBUILD nextcloud-client-2.6.0.ebuild 1997 BLAKE2B 93dcb863a801307fc378326d0d3027e23b6db25d70cadd8c58d5a5cc5a17d4847f8018574823a933b634c76b2018590a64083ef12cc7b4384d1d0e8701c1739b SHA512 39367dad554bbf6a6d062dc1f85474b931d6a92d099957f0322ec100eaa540c925574afefbd69407a007509bf2f0ba2960065aafe61d5538d2f5c86b48e21a0b
 MISC metadata.xml 590 BLAKE2B 6ddde648f1b75a5ac3b83ff6b24cdef05b016052257dc99d152db249b029c88854a2b44a2d5a5e7a2b87b9148dbb677fa5bf12066c7f59a9ef5812bdbd57964b SHA512 27f8098bbdec79e03007513d2f4bd6799a399fc5930871542eedf3d018a13cacc1c4dfa23f9c78275c8e5a61830b1b6d4ebe667e3a4ff42541581d5287e940b4
diff --git a/net-misc/nextcloud-client/nextcloud-client-2.6.0.ebuild b/net-misc/nextcloud-client/nextcloud-client-2.6.0.ebuild
new file mode 100644
index 000000000000..e931c2d92649
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-2.6.0.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus shibboleth test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	shibboleth? ( dev-qt/qtwebkit:5 )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=$(usex !shibboleth)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}