gentoo resync : 05.04.2019

2 files changed, 89 insertions, 0 deletions

diff --git a/net-misc/owncloud-client/Manifest b/net-misc/owncloud-client/Manifest
index 1ef06b4a3f7a..ae51520f5830 100644
--- a/net-misc/owncloud-client/Manifest
+++ b/net-misc/owncloud-client/Manifest
@@ -1,3 +1,5 @@
 DIST owncloudclient-2.5.3.11470.tar.xz 16719780 BLAKE2B 0c10d95ef2d851ba3f728dfe1c55c4143cf9d1542c1f9e77904324f598ecbfa29e54119d12ebef78b8eafa1188e7359ce11d01034ff34a55a80d31d1d3b1db35 SHA512 331d8e8e71d64cf9c958f9391001c6fdff45795e7caad2ce7bf6802c4f0959adf694712cd298fb8702cd4e93577282957cabc61ccc5f4f3a57edc9ddf1c7c2a0
+DIST owncloudclient-2.5.4.11654.tar.xz 16720764 BLAKE2B f970e3ed5fbe465f93e9c4f4c2106604a08ada765f8692e1287878b7deb44ac92c53608f34b24a9c913510a5625c4e980c9ac2646689700e38e78822d3e98d21 SHA512 70b687d7ace4d1335388ebf60bf65137943ff0cadfefdcaffb09539c656889233100033f28db7d03f3d48f4b956aeed476bb458f8ef16ac5461287cf02e226d9
 EBUILD owncloud-client-2.5.3.11470-r1.ebuild 1915 BLAKE2B 7f1927b02f1726ef0052b3ea1a981d9cb7e8def3dca2ceca810c15812c9496ab3e1376032e49ee2105820ee9b467476ac5859661d4209832b84bd1405f578f05 SHA512 3f8868e83c006325135b7a9887747a36cffb6b4b4c93d26a0064f5e15683f7dce443c92470be3ba25127d1d4983a30b900200e996781d4a17c60ccb0b445c6fb
+EBUILD owncloud-client-2.5.4.11654.ebuild 1915 BLAKE2B 7f1927b02f1726ef0052b3ea1a981d9cb7e8def3dca2ceca810c15812c9496ab3e1376032e49ee2105820ee9b467476ac5859661d4209832b84bd1405f578f05 SHA512 3f8868e83c006325135b7a9887747a36cffb6b4b4c93d26a0064f5e15683f7dce443c92470be3ba25127d1d4983a30b900200e996781d4a17c60ccb0b445c6fb
 MISC metadata.xml 508 BLAKE2B cbba1d7edcfe92d38f2f0d959695cac4f2c1eef8949e9816a995b18432a5c372185094cfa2548787ee63d58175b2110792f5e51688bc456c6376d86a7e8d9864 SHA512 1e757d6db30a7d5d90f317325fa96a1bdf46029e79846d17637f699d07ffa9f489f2d66855c647896a7b932e545b91242cc9df1dbb4bcce83e266c13c8fcf6c1
diff --git a/net-misc/owncloud-client/owncloud-client-2.5.4.11654.ebuild b/net-misc/owncloud-client/owncloud-client-2.5.4.11654.ebuild
new file mode 100644
index 000000000000..37f3df0acddb
--- /dev/null
+++ b/net-misc/owncloud-client/owncloud-client-2.5.4.11654.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils
+
+DESCRIPTION="Synchronize files from ownCloud Server with your computer"
+HOMEPAGE="https://owncloud.org/"
+SRC_URI="https://download.owncloud.com/desktop/stable/${P/-}.tar.xz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc dolphin nautilus shibboleth test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	shibboleth? ( dev-qt/qtwebkit:5 )"
+
+RDEPEND="${COMMON_DEPEND}"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)"
+
+S=${WORKDIR}/${P/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=$(usex !shibboleth)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}