gentoo auto-resync : 07:11:2024 - 03:03:27

2 files changed, 107 insertions, 0 deletions

diff --git a/net-misc/remmina/Manifest b/net-misc/remmina/Manifest
index 2b37ee25bc57..48b62c1913ca 100644
--- a/net-misc/remmina/Manifest
+++ b/net-misc/remmina/Manifest
@@ -1,6 +1,8 @@
+DIST Remmina-ecb29e7830037dd3ee618472c80b5e8eaecf1ce0.tar.bz2 2152678 BLAKE2B 20e7f9cd20da9e5a504ec86f11a88eb5e96c04378a1ec4c4f656e32c67a92925ce32a1224054143688ef99251f1944334c446d569c415d18bbff968e7d76f510 SHA512 4f6afdebfdc810d6d6fefc8f0c4a717c1228fa7b57b23edd4415a08b271bdbb18ef34875e3515caadb9e1504fe3c5ae18c953681dcb91d0fec5655e45b75e509
 DIST Remmina-v1.4.35.tar.bz2 2150047 BLAKE2B 3ba730cd4009a797ee7d66bbe4390e9db221ee5cf0b008e0eb3df4a992d7260ddc65983c8c34d1aa1bb2190ed1104653e269369565d7e4eecaf3078ffc84330c SHA512 36dc419b4473c71f6b3e53338f4a3cf7a1fe60534ea0dce375b4c9fd00cd9d8a618c4376be4d031bdee1eed8b4aade4538a6cc414629ef6dde41cdcd513a6d36
 DIST Remmina-v1.4.36.tar.bz2 2153190 BLAKE2B 0d29adcb84b7c72ae2f2468e0ef56e6f16f49a0ff2774cf59df699cf721aabdabbde91799d9266295f30fa5789d33f4aab450924aa5a325aa3f1315332dd7d4e SHA512 bdf3604849238ca2e61b6f35bbfba1df5eedf1c2374897a565f1a1e0b76a285be93700d92a6912d33d73ab745fb412856ee14fd0eab3feec492bf1b5aa35bc38
 EBUILD remmina-1.4.35-r1.ebuild 2513 BLAKE2B 279cd3a256e970675609c4080a92a483eb16cc0034889c0f76b6167ae4e0937d68e43bdbdd8a818b95d77345057fd134744b67d5bb22ddc7cf197c965a95d994 SHA512 e24541a389a458f46a0e665749d59a8d52f6842d4d5b8e9cfd9095f2000806c4ce8456775e339fd7bfb124713e0cc9627492efbad5ead0c3a2c19a037acc5262
 EBUILD remmina-1.4.35-r2.ebuild 2524 BLAKE2B abda0c7a793dbcc9f2c74edd1675e3fe2bf6550739eef73bf93472450c52e0e25255b006dafd4a10698fe81f54e75fe149b3aa8f3de71b67d32213abf0a05544 SHA512 24cd3cd04a3fb12a674e06b7e43e26b27eda1bc2fd9a262e2d1d37347eda2f86a1e9ac63e1c583ccf156bf05d2d22bd3ced4a410db7c57ad32c0ef2ad226ed6e
 EBUILD remmina-1.4.36.ebuild 2525 BLAKE2B be88944c493c95cc255c35e3ad182c7f0bf3cb5702ed74a38e0e6f4c14721ead9832f2563b56f32719018dc3fb49249a7cd6b2511fae86fea55c9008a6c0ed44 SHA512 826c68b6ae045ddb7cece0485bbe68d72b6b990a5b398e6ee0c1ad27d1e291d34c96c91921b24579d61c675b4b27481a68f1a1239aac016a0127ffe8e091d65c
+EBUILD remmina-1.4.36_p20241106.ebuild 2589 BLAKE2B 9ef205088c18d787bb34fa4d7f20ed2d8c43a4515dcc1b9f233dec9ba61ed7bac51a9aa8ca928473e8bc82d87e247a13661c91aac23d07826cdb6d71a4d76d0c SHA512 c7b34317b6076adfd4835849411bc0517aab6a115612c9dff2662699afc40a923f52c092a538c3159e5c34f5113a5605652a82c34dfab0bedceafbcf6f1be84e
 MISC metadata.xml 1123 BLAKE2B 658714c247c6fbec6118a88bc5493a67aca30e949249407d421592b956c15b439b6d96c682d2d6d7cc9f1eb2dfdcc902c4c463c6a208af4bb9196656723f220a SHA512 cbf00348e2da27acbe9890ac2d6b19d5731496cf1aab303d64f036700fb779587cb7fe81a95d3a25f9ec5dcb79e2e7e880e345fc1ac267acd25da89844ab6f21
diff --git a/net-misc/remmina/remmina-1.4.36_p20241106.ebuild b/net-misc/remmina/remmina-1.4.36_p20241106.ebuild
new file mode 100644
index 000000000000..fdb17eaaf924
--- /dev/null
+++ b/net-misc/remmina/remmina-1.4.36_p20241106.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+COMMIT=ecb29e7830037dd3ee618472c80b5e8eaecf1ce0
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake python-single-r1 xdg
+
+MY_P="${PN^}-v${PV}"
+
+DESCRIPTION="A GTK+ RDP, SPICE, VNC and SSH client"
+HOMEPAGE="https://remmina.org/"
+SRC_URI="https://gitlab.com/Remmina/Remmina/-/archive/${COMMIT}/Remmina-${COMMIT}.tar.bz2"
+S="${WORKDIR}/${PN^}-${COMMIT}"
+
+LICENSE="GPL-2+-with-openssl-exception"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+appindicator crypt cups examples keyring gvnc kwallet nls python spice ssh rdp vnc wayland webkit zeroconf X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} ) || ( X wayland )"
+
+COMMON_DEPEND="
+	dev-libs/glib:2
+	dev-libs/json-glib
+	dev-libs/libpcre2
+	dev-libs/libsodium:=
+	dev-libs/openssl:0=
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3[X?,wayland?]
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+	appindicator? ( dev-libs/libayatana-appindicator )
+	crypt? ( dev-libs/libgcrypt:0= )
+	keyring? ( app-crypt/libsecret )
+	gvnc? ( net-libs/gtk-vnc )
+	kwallet? ( kde-frameworks/kwallet:5 )
+	python? ( ${PYTHON_DEPS} )
+	rdp? ( net-misc/freerdp:3=
+		cups? ( net-print/cups:= ) )
+	spice? ( net-misc/spice-gtk[gtk3] )
+	ssh? ( net-libs/libssh:0=[sftp]
+		x11-libs/vte:2.91 )
+	vnc? ( net-libs/libvncserver[jpeg] )
+	webkit? ( net-libs/webkit-gtk:4.1 )
+	zeroconf? ( >=net-dns/avahi-0.8-r2[dbus,gtk] )
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	spice? ( app-emulation/spice-protocol )
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+RDEPEND="
+	${COMMON_DEPEND}
+	virtual/freedesktop-icon-theme
+"
+
+DOCS=( AUTHORS CHANGELOG.md README.md THANKS.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_environment_reset
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DHAVE_LIBAPPINDICATOR=$(usex appindicator ON OFF)
+		-DWITH_AVAHI=$(usex zeroconf)
+		-DWITH_CUPS=$(usex cups)
+		-DWITH_EXAMPLES=$(usex examples)
+		-DWITH_FREERDP=$(usex rdp)
+		-DWITH_FREERDP3=ON
+		-DWITH_GCRYPT=$(usex crypt)
+		-DWITH_GETTEXT=$(usex nls)
+		-DWITH_ICON_CACHE=OFF
+		-DWITH_KF5WALLET=$(usex kwallet)
+		-DWITH_LIBSECRET=$(usex keyring)
+		-DWITH_LIBSSH=$(usex ssh)
+		-DWITH_LIBVNCSERVER=$(usex vnc)
+		-DWITH_PYTHONLIBS=$(usex python ON OFF)
+		-DWITH_SPICE=$(usex spice)
+		-DWITH_TRANSLATIONS=$(usex nls)
+		-DWITH_UPDATE_DESKTOP_DB=OFF
+		-DWITH_VTE=$(usex ssh)
+		-DWITH_WWW=$(usex webkit)
+		-DWITH_X2GO=OFF
+		# when this feature is stable, add python eclass usage to optionally enable
+		-DWITH_PYTHON=OFF
+	)
+	cmake_src_configure
+}