gentoo resync : 25.01.2019

2 files changed, 119 insertions, 0 deletions

diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 22cdebfa457f..4550921da2cc 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1,4 +1,6 @@
 DIST youtube-dl-2019.01.17.tar.gz 3088912 BLAKE2B 6cd46442d78126b3428135fcb820eb02bb2d567fe41fbfefcd80fc68a9ece0faaf2aa4981e31c619c3be1f789a9539236b1a71e72490c4ee667953837b25f0e5 SHA512 b8e81c2b2ec284033a5a92f49a965375d681d92435bc0402bb891b443f94d1321716a15717fe4e3c1fbc54ec610445282c52c18c046e140dd53731560230bd3f
+DIST youtube-dl-2019.01.24.tar.gz 3099596 BLAKE2B e8833a0432e32e843ed8a3e971b9572bc0f4f8e90ea9c26fe6426ccc95231d21cf85601615634611129405115fe1d3fc192f423c0d700beab7fbccfcfe25dc68 SHA512 23d81769dc202c6598a8ece772f104ed7a048464b3d14305492e562aa77dc77ef32e56ae7a1084b144460e18dcfb2a9d7813ef88f7fdc34760f62f4de23e4602
 EBUILD youtube-dl-2019.01.17.ebuild 3410 BLAKE2B f16485a95281547c0ad2b0f32d1005e7a1500f630d5894dac2f2ab3961de53d92fd535cb7b253ae566a5779e757f5439bdf68d204c9c8a8da8e8c816eda3f72a SHA512 c3745e5375971e638f46dd20389523d648c853aeaa03a36d982814158fd2a0561749e8704998617ef2983905be0f4dbc5b78f06b6faa965e6299487bb55991e0
+EBUILD youtube-dl-2019.01.24.ebuild 3416 BLAKE2B a006e2ef1f88a0867fd931e1bde00c35e211f2c4efde7f5c68348c012ebc22346b46d200a24aa50f86b5e3fdb1e5c9253527c284a949b3c1920f3c8034d3fb94 SHA512 b5f01ad65383548f81ce29a6ed77ba3e450f585a19557c73ea7215df434dcfc8b6f972d057b6b767462a454f6ae7c2162d71fdda8a1d575b0f74952ad655b465
 EBUILD youtube-dl-99999999.ebuild 3304 BLAKE2B 62e4cfa266a5c117633a91e9fe83648f42bbbbd60e8764adca0002a03fb55b06caf224fb7997bcc9073847ca7d0055037749fd45f7521757a8e1bf9d4cc7215b SHA512 70686e618298486fc81621671f687cf11a0b56a05041be6016f4e2eed97ea215c21e869f90b5f071111f229f0d3ee49be3b3d395cd8e28900cc985d1d9d8fd31
 MISC metadata.xml 218 BLAKE2B 717fcfd86a1f75e0ad21845c9b496cf01d7bc7c80b6be8c08143ea304a08fbb75352e82e8fc883398e96da9c037f8912c4a9612b5cf85ffb25b3a5f041b02fe2 SHA512 d36d668a636222ce6394eca2598850e68139819543fd3cf0e76301e2a61c9b9303026b49536d1ed1b52f44d5703dc5e4247df786e0b4a704b28872e0a4a71b27
diff --git a/net-misc/youtube-dl/youtube-dl-2019.01.24.ebuild b/net-misc/youtube-dl/youtube-dl-2019.01.24.ebuild
new file mode 100644
index 000000000000..6ef55f59a57e
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2019.01.24.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://rg3.github.com/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="+offensive test"
+
+RDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-python/nose[coverage(+)] )
+"
+
+S="${WORKDIR}/${PN}"
+
+python_prepare_all() {
+	if ! use offensive; then
+		sed -i -e "/..version../s|'$|+gentoo.no.offensive.sites'|g" \
+			youtube_dl/version.py || die
+		# these have single line import statements
+		local xxx=(
+			alphaporno anysex behindkink camwithher chaturbate eporner
+			eroprofile extremetube foxgay goshgay hellporno hentaistigma
+			hornbunny keezmovies lovehomeporn mofosex myvidster porn91 porncom
+			pornflip pornhd pornotube pornovoisines pornoxo ruleporn sexu
+			slutload spankbang spankwire sunporno thisav vporn watchindianporn
+			xbef xnxx xtube xvideos xxxymovies youjizz youporn
+		)
+		# these have multi-line import statements
+		local mxxx=(
+			drtuber fourtube motherless pornhub redtube tnaflix tube8 xhamster
+		)
+		# do single line imports
+		sed -i \
+			-e $( printf '/%s/d;' ${xxx[@]} ) \
+			youtube_dl/extractor/extractors.py \
+			|| die
+
+		# do multiple line imports
+		sed -i \
+			-e $( printf '/%s/,/)/d;' ${mxxx[@]} ) \
+			youtube_dl/extractor/extractors.py \
+			|| die
+
+		sed -i \
+			-e $( printf '/%s/d;' ${mxxx[@]} ) \
+			youtube_dl/extractor/generic.py \
+			|| die
+
+		rm \
+			$( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
+			$( printf 'youtube_dl/extractor/%s.py ' ${mxxx[@]} ) \
+			test/test_age_restriction.py \
+			|| die
+	fi
+
+	eapply_user
+
+	distutils-r1_python_prepare_all
+}
+
+src_compile() {
+	distutils-r1_src_compile
+}
+
+python_test() {
+	emake test
+}
+
+python_install_all() {
+	dodoc README.txt
+	doman ${PN}.1
+
+	newbashcomp ${PN}.bash-completion ${PN}
+
+	insinto /usr/share/zsh/site-functions
+	newins ${PN}.zsh _${PN}
+
+	insinto /usr/share/fish/vendor_completions.d
+	doins ${PN}.fish
+
+	distutils-r1_python_install_all
+
+	rm -r "${ED}"/usr/etc || die
+	rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+	elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+	elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+	elog
+	elog "${PN} works fine on its own on most sites. However, if you want"
+	elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+	elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+	elog "videos can be retrieved in a higher quality format without sound."
+	elog "${PN} will detect whether avconv/ffmpeg is present and"
+	elog "automatically pick the best option."
+	elog
+	elog "Videos or video formats streamed via RTMP protocol can only be"
+	elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+	elog "Downloading MMS and RTSP videos requires either mplayer"
+	elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+	elog
+	elog "If you want ${PN} to embed thumbnails from the metadata into the"
+	elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}