gentoo auto-resync : 21:04:2023 - 18:02:52

3 files changed, 395 insertions, 0 deletions

diff --git a/net-misc/Manifest.gz b/net-misc/Manifest.gz
index b343dc019bea..6ba62fb11569 100644
--- a/net-misc/Manifest.gz
+++ b/net-misc/Manifest.gz
diff --git a/net-misc/networkmanager/Manifest b/net-misc/networkmanager/Manifest
index 55b324180ee9..8f215a2732a4 100644
--- a/net-misc/networkmanager/Manifest
+++ b/net-misc/networkmanager/Manifest
@@ -4,6 +4,8 @@ AUX conf.d.NetworkManager 230 BLAKE2B 987b6b39c6c8b14a788575241575f9a0761f320117
 AUX init.d.NetworkManager-r2 1880 BLAKE2B d765a298955cdcf0c62518488fc9f02f97c31ee645c7b15ed73914397e02266e1b72a32af1d9f8007ae81119e9223b3e41184aa58b9fa328ed72e0ebec91acd8 SHA512 f06e7e6b6ebeb991471cf6e71c44687210a115fd008505ebe01de1b52a059952c2b191789d217412ae30daaaecf8bc028c89daf536af793eac23cfcd62ba9ad4
 DIST NetworkManager-1.42.2.tar.xz 6749184 BLAKE2B cf94f79bad373d1271f406392af595941c78d567cb28a6116b351093858bbce68acf4d115950582087687ea3b3fafad7a977361f6c7f5ce8565bc2eed0e6ab60 SHA512 6142aaa7da2ae0dc3c8c75dbf51619ff969ace61c8a2d4a72aa83c4eff69e8389b262941e1667d71cbb55fb0653b14798a3c169b39dfcfa084109ef9fb3a335a
 DIST NetworkManager-1.42.4.tar.xz 6659860 BLAKE2B 5f98dba82d2bf932d61dc44b263a0c3263a299cc06bb506a98ec822126edf8dd6dde1618f75943caaf49f85864cadcf1eaf2c12864cde5f7521a7dff9053571d SHA512 af51ce481b8a6c3ee6e8856400a19f3e94c1fb0d5b2750ccf48785374b59110b49aa2a90aae675d322d902ad0e3f6eef6188bb247067448de84272dc6b114acb
+DIST NetworkManager-1.42.6.tar.xz 6749088 BLAKE2B 9d583c163908ee4fe145cdbdaa657cbc682d9f6270efc7d7525acd86912a0da50f2ccf14810fdfe2998c6ce701dcabc2b5b39fa58ff9d3fe4f5630205b15f4c8 SHA512 606a996043d8fbc7972329b94bc9854557950f665790381611eddfc632850b31584a4ba2d773fa9d12127db4c37ea2076c657521b78cedb012144df6f41d3748
 EBUILD networkmanager-1.42.2.ebuild 11730 BLAKE2B 3fab705271b084282fb7324521717531504b6b877dde88dae7e41ae2d3a49272108a1793f0d9dc9603af0f4a9999e2a1386eb634936567166fcd3c547a16e73b SHA512 dee0d56a794d5497d8a6ba6a31dab4ce0ff2afeb87d01c1b8d3499e9e3dee2673c8dbcfe865cbd79beeac26a94da958d9cca2d60dcd76f2a8ac8d6f2d83c672b
 EBUILD networkmanager-1.42.4.ebuild 11736 BLAKE2B 815367546ba3cf57caa26f58708f6530e4dd9b4c7c704b0fe7fa52a81a9cc96f4712332470b6a380c96335a7c38e0a8b20e79d1b4fa07045ef0fd04d20b6d505 SHA512 a0bf9b646bc4f9bb802924a2169b13d047849e87eb648542a9f34d01ebd4b14f982d2e56470b7eab49a5c3b349d06d1fe26c66875e4aecf3b1d26292b2d970b5
+EBUILD networkmanager-1.42.6.ebuild 11739 BLAKE2B 9b4323473c5ae5ce583f8690b9d2163f9e36a2f1f9067f1d6b2e81e19e03c33f2a0aabfd493ac501df4677476440e6d64fc4e9f3d465ef178db07d7c48773f70 SHA512 75df38efe6158626c98de4d08f984626771360573053b86c3c3ed1154f4e5e0a5486915ebb50cec25a39c23b97e7651e26e170799d8a0df98e9943a206b43d78
 MISC metadata.xml 2430 BLAKE2B 564983bc42e2b87533286f90ad5e3988356169cf65436ec853a63183ae1086e5672afd7552c9a06fd17018158bab09acaedf015998eb4d10a9c11db1897b49a4 SHA512 39ae015637e571dc8268c750a6cf56c185a0716113670f58e4d33848c7d6c33b8decba6201a0600ab689d2bcc7d44a123003bcfc8696fd8b46eea376b498d6e2
diff --git a/net-misc/networkmanager/networkmanager-1.42.6.ebuild b/net-misc/networkmanager/networkmanager-1.42.6.ebuild
new file mode 100644
index 000000000000..fb476d87dcba
--- /dev/null
+++ b/net-misc/networkmanager/networkmanager-1.42.6.ebuild
@@ -0,0 +1,393 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+GNOME_ORG_MODULE="NetworkManager"
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit gnome.org linux-info meson-multilib python-any-r1 readme.gentoo-r1 systemd toolchain-funcs udev vala virtualx
+
+DESCRIPTION="A set of co-operative tools that make networking simple and straightforward"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0"
+
+IUSE="audit bluetooth +concheck connection-sharing debug dhclient dhcpcd elogind gnutls +gtk-doc +introspection iptables iwd psl libedit lto +nss nftables +modemmanager ofono ovs policykit +ppp resolvconf selinux syslog systemd teamd test +tools vala +wext +wifi"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	bluetooth? ( modemmanager )
+	connection-sharing? ( || ( iptables nftables ) )
+	gtk-doc? ( introspection )
+	iwd? ( wifi )
+	vala? ( introspection )
+	wext? ( wifi )
+	^^ ( gnutls nss )
+	?? ( elogind systemd )
+	?? ( dhclient dhcpcd )
+	?? ( syslog systemd )
+"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86"
+
+COMMON_DEPEND="
+	sys-apps/util-linux[${MULTILIB_USEDEP}]
+	elogind? ( >=sys-auth/elogind-219 )
+	>=virtual/libudev-175:=[${MULTILIB_USEDEP}]
+	sys-apps/dbus
+	net-libs/libndp
+	systemd? ( >=sys-apps/systemd-209:0= )
+	>=dev-libs/glib-2.40:2[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.10.3:= )
+	selinux? (
+		sec-policy/selinux-networkmanager
+		sys-libs/libselinux
+	)
+	audit? ( sys-process/audit )
+	teamd? (
+		>=dev-libs/jansson-2.7:=
+		>=net-misc/libteam-1.9
+	)
+	policykit? ( >=sys-auth/polkit-0.106 )
+	nss? (
+		dev-libs/nspr[${MULTILIB_USEDEP}]
+		>=dev-libs/nss-3.11[${MULTILIB_USEDEP}]
+	)
+	gnutls? (
+		>=net-libs/gnutls-2.12:=[${MULTILIB_USEDEP}]
+	)
+	ppp? ( >=net-dialup/ppp-2.4.5:=[ipv6(+)] )
+	modemmanager? (
+		net-misc/mobile-broadband-provider-info
+		>=net-misc/modemmanager-0.7.991:0=
+	)
+	bluetooth? ( >=net-wireless/bluez-5:= )
+	ofono? ( net-misc/ofono )
+	dhclient? ( >=net-misc/dhcp-4[client] )
+	dhcpcd? ( >=net-misc/dhcpcd-9.3.3 )
+	ovs? ( >=dev-libs/jansson-2.7:= )
+	resolvconf? ( virtual/resolvconf )
+	connection-sharing? (
+		net-dns/dnsmasq[dbus,dhcp]
+		iptables? ( net-firewall/iptables )
+		nftables? ( net-firewall/nftables )
+	)
+	psl? ( net-libs/libpsl )
+	concheck? ( net-misc/curl )
+	tools? (
+		>=dev-libs/newt-0.52.15
+		libedit? ( dev-libs/libedit )
+		!libedit? ( sys-libs/readline:= )
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	acct-group/plugdev
+	|| (
+		net-misc/iputils[arping(+)]
+		net-analyzer/arping
+	)
+	wifi? (
+		!iwd? ( >=net-wireless/wpa_supplicant-0.7.3-r3[dbus] )
+		iwd? ( net-wireless/iwd )
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=sys-kernel/linux-headers-3.18
+	net-libs/libndp[${MULTILIB_USEDEP}]
+	ppp? ( elibc_musl? ( net-libs/ppp-defs ) )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? (
+		dev-util/gtk-doc
+		app-text/docbook-xml-dtd:4.1.2
+	)
+	>=sys-devel/gettext-0.17
+	virtual/pkgconfig
+	introspection? (
+		$(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
+		dev-lang/perl
+		dev-libs/libxslt
+	)
+	vala? ( $(vala_depend) )
+	test? (
+		>=dev-libs/jansson-2.7
+		$(python_gen_any_dep '
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_USEDEP}]')
+	)
+"
+
+python_check_deps() {
+	if use introspection; then
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]" || return
+	fi
+	if use test; then
+		python_has_version "dev-python/dbus-python[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	if use connection-sharing; then
+		if kernel_is lt 5 1; then
+			CONFIG_CHECK="~NF_NAT_IPV4 ~NF_NAT_MASQUERADE_IPV4"
+		else
+			CONFIG_CHECK="~NF_NAT ~NF_NAT_MASQUERADE"
+		fi
+		linux-info_pkg_setup
+	fi
+
+	if use introspection || use test; then
+		python-any-r1_pkg_setup
+	fi
+
+	# bug 809695
+	if tc-is-clang && use lto; then
+		eerror "Clang does not support -flto-partition"
+		die "Please use gcc or turn off USE=lto flag when building with clang"
+	fi
+}
+
+src_prepare() {
+	DOC_CONTENTS="To modify system network connections without needing to enter the
+		root password, add your user account to the 'plugdev' group."
+
+	default
+	use vala && vala_setup
+
+	sed -i \
+		-e 's#/usr/bin/sed#/bin/sed#' \
+		data/84-nm-drivers.rules \
+		|| die
+}
+
+meson_nm_program() {
+	usex "$1" "-D${2:-$1}=$3" "-D${2:-$1}=no"
+}
+
+meson_nm_native_program() {
+	multilib_native_usex "$1" "-D${2:-$1}=$3" "-D${2:-$1}=no"
+}
+
+multilib_src_configure() {
+	local emesonargs=(
+		--localstatedir="${EPREFIX}/var"
+
+		-Dsystemdsystemunitdir=$(systemd_get_systemunitdir)
+		-Dsystem_ca_path=/etc/ssl/certs
+		-Dudev_dir=$(get_udevdir)
+		-Ddbus_conf_dir=/usr/share/dbus-1/system.d
+		-Dkernel_firmware_dir=/lib/firmware
+		-Diptables=/sbin/iptables
+		-Dnft=/sbin/nft
+		-Ddnsmasq=/usr/sbin/dnsmasq
+
+		-Ddist_version=${PVR}
+		$(meson_native_use_bool policykit polkit)
+		$(meson_native_use_bool policykit config_auth_polkit_default)
+		-Dmodify_system=true
+		-Dpolkit_agent_helper_1=/usr/lib/polkit-1/polkit-agent-helper-1
+		$(meson_native_use_bool selinux)
+		$(meson_native_use_bool systemd systemd_journal)
+		-Dhostname_persist=gentoo
+		-Dlibaudit=$(multilib_native_usex audit)
+
+		$(meson_native_use_bool wext)
+		$(meson_native_use_bool wifi)
+		$(meson_native_use_bool iwd)
+		$(meson_native_use_bool ppp)
+		-Dpppd=/usr/sbin/pppd
+		$(meson_native_use_bool modemmanager modem_manager)
+		$(meson_native_use_bool ofono)
+		$(meson_native_use_bool concheck)
+		$(meson_native_use_bool teamd teamdctl)
+		$(meson_native_use_bool ovs)
+		$(meson_native_use_bool tools nmcli)
+		$(meson_native_use_bool tools nmtui)
+		$(meson_native_use_bool tools nm_cloud_setup)
+		$(meson_native_use_bool bluetooth bluez5_dun)
+		-Debpf=true
+
+		-Dconfig_wifi_backend_default=$(multilib_native_usex iwd iwd default)
+		-Dconfig_plugins_default=keyfile
+		-Difcfg_rh=false
+		-Difupdown=false
+
+		$(meson_nm_native_program resolvconf "" /sbin/resolvconf)
+		-Dnetconfig=no
+		-Dconfig_dns_rc_manager_default=auto
+
+		$(meson_nm_program dhclient "" /sbin/dhclient)
+		-Ddhcpcanon=no
+		$(meson_nm_program dhcpcd "" /sbin/dhcpcd)
+
+		$(meson_native_use_bool introspection)
+		$(meson_native_use_bool vala vapi)
+		$(meson_native_use_bool gtk-doc docs)
+		-Dtests=$(multilib_native_usex test)
+		$(meson_native_true firewalld_zone)
+		-Dmore_asserts=0
+		$(meson_use debug more_logging)
+		-Dvalgrind=no
+		-Dvalgrind_suppressions=
+		-Dld_gc=false
+		$(meson_native_use_bool psl libpsl)
+		-Dqt=false
+
+		$(meson_use lto b_lto)
+	)
+
+	if multilib_is_native_abi && use systemd; then
+		emesonargs+=( -Dsession_tracking_consolekit=false )
+		emesonargs+=( -Dsession_tracking=systemd )
+		emesonargs+=( -Dsuspend_resume=systemd )
+	elif multilib_is_native_abi && use elogind; then
+		emesonargs+=( -Dsession_tracking_consolekit=false )
+		emesonargs+=( -Dsession_tracking=elogind )
+		emesonargs+=( -Dsuspend_resume=elogind )
+	else
+		emesonargs+=( -Dsession_tracking_consolekit=false )
+		emesonargs+=( -Dsession_tracking=no )
+		emesonargs+=( -Dsuspend_resume=auto )
+	fi
+
+	if multilib_is_native_abi && use syslog; then
+		emesonargs+=( -Dconfig_logging_backend_default=syslog )
+	elif multilib_is_native_abi && use systemd; then
+		emesonargs+=( -Dconfig_logging_backend_default=journal )
+	else
+		emesonargs+=( -Dconfig_logging_backend_default=default )
+	fi
+
+	if multilib_is_native_abi && use dhclient; then
+		emesonargs+=( -Dconfig_dhcp_default=dhclient )
+	elif multilib_is_native_abi && use dhcpcd; then
+		emesonargs+=( -Dconfig_dhcp_default=dhcpcd )
+	else
+		emesonargs+=( -Dconfig_dhcp_default=internal )
+	fi
+
+	if use nss; then
+		emesonargs+=( -Dcrypto=nss )
+	else
+		emesonargs+=( -Dcrypto=gnutls )
+	fi
+
+	if use tools ; then
+		emesonargs+=( -Dreadline=$(usex libedit libedit libreadline) )
+	else
+		emesonargs+=( -Dreadline=none )
+	fi
+
+	# Same hack as net-dialup/pptpd to get proper plugin dir for ppp, bug #519986
+	if use ppp; then
+		local PPPD_VER=`best_version net-dialup/ppp`
+		PPPD_VER=${PPPD_VER#*/*-} #reduce it to ${PV}-${PR}
+		PPPD_VER=${PPPD_VER%%[_-]*} # main version without beta/pre/patch/revision
+		emesonargs+=( -Dpppd_plugin_dir=/usr/$(get_libdir)/pppd/${PPPD_VER} )
+	fi
+
+	meson_src_configure
+}
+
+multilib_src_test() {
+	if use test && multilib_is_native_abi; then
+		python_setup
+		virtx meson_src_test
+	fi
+}
+
+multilib_src_install() {
+	meson_src_install
+	if ! multilib_is_native_abi; then
+		rm -r "${ED}"/{etc,usr/{bin,lib/NetworkManager,share},var} || die
+	fi
+}
+
+multilib_src_install_all() {
+	! use systemd && readme.gentoo_create_doc
+
+	newinitd "${FILESDIR}/init.d.NetworkManager-r2" NetworkManager
+	newconfd "${FILESDIR}/conf.d.NetworkManager" NetworkManager
+
+	# Need to keep the /etc/NetworkManager/dispatched.d for dispatcher scripts
+	keepdir /etc/NetworkManager/dispatcher.d
+
+	# Provide openrc net dependency only when nm is connected
+	exeinto /etc/NetworkManager/dispatcher.d
+	newexe "${FILESDIR}/10-openrc-status-r4" 10-openrc-status
+	sed -e "s:@EPREFIX@:${EPREFIX}:g" \
+		-i "${ED}/etc/NetworkManager/dispatcher.d/10-openrc-status" || die
+
+	keepdir /etc/NetworkManager/system-connections
+	chmod 0600 "${ED}"/etc/NetworkManager/system-connections/.keep* # bug #383765, upstream bug #754594
+
+	# Allow users in plugdev group to modify system connections
+	insinto /usr/share/polkit-1/rules.d/
+	doins "${FILESDIR}"/01-org.freedesktop.NetworkManager.settings.modify.system.rules
+
+	insinto /usr/lib/NetworkManager/conf.d #702476
+	doins "${S}"/examples/nm-conf.d/31-mac-addr-change.conf
+
+	if use iwd; then
+		# This goes to $nmlibdir/conf.d/ and $nmlibdir is '${prefix}'/lib/$PACKAGE, thus always lib, not get_libdir
+		cat <<-EOF > "${ED}"/usr/lib/NetworkManager/conf.d/iwd.conf || die
+		[device]
+		wifi.backend=iwd
+		EOF
+	fi
+
+	mv "${ED}"/usr/share/doc/{NetworkManager/examples/,${PF}} || die
+	rmdir "${ED}"/usr/share/doc/NetworkManager || die
+
+	# Empty
+	rmdir "${ED}"/var{/lib{/NetworkManager,},} || die
+}
+
+pkg_postinst() {
+	udev_reload
+
+	systemd_reenable NetworkManager.service
+	! use systemd && readme.gentoo_print_elog
+
+	if [[ -e "${EROOT}/etc/NetworkManager/nm-system-settings.conf" ]]; then
+		ewarn "The ${PN} system configuration file has moved to a new location."
+		ewarn "You must migrate your settings from ${EROOT}/etc/NetworkManager/nm-system-settings.conf"
+		ewarn "to ${EROOT}/etc/NetworkManager/NetworkManager.conf"
+		ewarn
+		ewarn "After doing so, you can remove ${EROOT}/etc/NetworkManager/nm-system-settings.conf"
+	fi
+
+	# NM fallbacks to plugin specified at compile time (upstream bug #738611)
+	# but still show a warning to remember people to have cleaner config file
+	if [[ -e "${EROOT}/etc/NetworkManager/NetworkManager.conf" ]]; then
+		if grep plugins "${EROOT}/etc/NetworkManager/NetworkManager.conf" | grep -q ifnet; then
+			ewarn
+			ewarn "You seem to use 'ifnet' plugin in ${EROOT}/etc/NetworkManager/NetworkManager.conf"
+			ewarn "Since it won't be used, you will need to stop setting ifnet plugin there."
+			ewarn
+		fi
+	fi
+
+	# NM shows lots of errors making nmcli almost unusable, bug #528748 upstream bug #690457
+	if grep -r "psk-flags=1" "${EROOT}"/etc/NetworkManager/; then
+		ewarn "You have psk-flags=1 setting in above files, you will need to"
+		ewarn "either reconfigure affected networks or, at least, set the flag"
+		ewarn "value to '0'."
+	fi
+
+	if use dhclient || use dhcpcd; then
+		ewarn "You have enabled USE=dhclient and/or USE=dhcpcd, but NetworkManager since"
+		ewarn "version 1.20 defaults to the internal DHCP client. If the internal client"
+		ewarn "works for you, and you're happy with, the alternative USE flags can be"
+		ewarn "disabled. If you want to use dhclient or dhcpcd, then you need to tweak"
+		ewarn "the main.dhcp configuration option to use one of them instead of internal."
+	fi
+}
+
+pkg_postrm() {
+	udev_reload
+}