gentoo resync : 29.12.2022

1 files changed, 57 insertions, 0 deletions

diff --git a/net-vpn/tailscale/tailscale-1.24.2.ebuild b/net-vpn/tailscale/tailscale-1.24.2.ebuild
new file mode 100644
index 000000000000..c040af297b7f
--- /dev/null
+++ b/net-vpn/tailscale/tailscale-1.24.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit go-module systemd tmpfiles
+
+# These settings are obtained by running ./build_dist.sh shellvars` in
+# the upstream repo.
+VERSION_MINOR="1.24"
+VERSION_SHORT="1.24.2"
+VERSION_LONG="1.24.2-tdce2409b1"
+VERSION_GIT_HASH="dce2409b15837f30885405b8b1d27e7b7fd6bf7a"
+
+DESCRIPTION="Tailscale vpn client"
+HOMEPAGE="https://tailscale.com"
+SRC_URI="https://github.com/tailscale/tailscale/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+SRC_URI+=" https://dev.gentoo.org/~williamh/dist/${P}-deps.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="net-firewall/iptables"
+
+# This translates the build command from upstream's build_dist.sh to an
+# ebuild equivalent.
+build_dist() {
+	ego build -tags xversion -ldflags "
+		-X tailscale.com/version.Long=${VERSION_LONG}
+		-X tailscale.com/version.Short=${VERSION_SHORT}
+		-X tailscale.com/version.GitCommit=${VERSION_GIT_HASH}" "$@"
+}
+
+src_compile() {
+	build_dist ./cmd/tailscale
+	build_dist ./cmd/tailscaled
+}
+
+src_install() {
+	dosbin tailscaled
+	dobin tailscale
+
+	systemd_dounit cmd/tailscaled/tailscaled.service
+	insinto /etc/default
+	newins cmd/tailscaled/tailscaled.defaults tailscaled
+	keepdir /var/lib/${PN}
+	fperms 0750 /var/lib/${PN}
+
+	newtmpfiles "${FILESDIR}/${PN}.tmpfiles" ${PN}.conf
+
+	newinitd "${FILESDIR}/${PN}d.initd" ${PN}
+	newconfd "${FILESDIR}/${PN}d.confd" ${PN}
+}
+
+pkg_postinst() {
+	tmpfiles_process ${PN}.conf
+}