gentoo resync : 14.05.2020

4 files changed, 116 insertions, 94 deletions

diff --git a/sci-libs/coinor-utils/Manifest b/sci-libs/coinor-utils/Manifest
index 717c88951fa4..797078c92536 100644
--- a/sci-libs/coinor-utils/Manifest
+++ b/sci-libs/coinor-utils/Manifest
@@ -1,3 +1,3 @@
-DIST CoinUtils-2.9.11.tgz 1740411 BLAKE2B 7adce4e17d31f8187c7959140f7cb5c537d6454b2e82c9cede7625bcff2b490e50dea190838f598b5fcc55a42ec2beea3982b14dc7bc8432e86ab82475462bc1 SHA512 3cbbce47cda4d5f63338644853601bf0a3dd9b9388e71a7aea7fedd51dfc007134359e5f12f24d8f6135d86b77a88a95bcb88249b1ba880eb3cd9cf41d039424
-EBUILD coinor-utils-2.9.11.ebuild 1940 BLAKE2B 5753a0e83714cbb4aed642f837a5ff00faf21b350efcf241c236157536a60465923695efa88b3868b663edaf3b14449c11ff4ca96e40942c6fe71cd8607c39cf SHA512 3385727a0a1b848f3edbf80f16b7314a5ddbd63a57eecb864636c92ab33f42379e06d595ae87d9e2c4f1fd37bc3f3aaf96fe4db079adb41dcef016252f70a20b
-MISC metadata.xml 653 BLAKE2B 937ed215f67bdd1d369d467af0f15ae05c8eb78726434509fc1fa2c2e777eb269eae21d09dda6ddcde589c3496e5f187a053dba7648a11efea9934940ff99bff SHA512 73fed876146a5d2aea6d7fd5bfb99d938f316cb92022e299c01e04aad218cb75b2745c8e064b9218a96c9b9f9c9e9efb089d38ba930677ce18b71f27667bd0c9
+DIST coinor-utils-2.11.4.tar.gz 1225148 BLAKE2B d55f9b3efbb3ce1c04fb9193ec70f62d8f130cd2f7ddf033c0df35f37006c542bd39e345662c271b4466b00c4bb1ec3cc14965bfe35f5b89370071d675113f4d SHA512 a7ac337b0f0bb11d578c44fd12d292ba8e77568362eaaaecbed8f4bc22ed85aaee911e2dd3153a2197b0165df082821969336d73fe1c5f0374a4636755d9a4ad
+EBUILD coinor-utils-2.11.4.ebuild 2468 BLAKE2B 20370781d360e6177492a20cc8f7cbb969855ce896ea219509f707e4bf47b7dd15e0f71bab6f748477fd5e96945123f3f4fb6f59417e6b1a6add85496854c3d1 SHA512 f8994e6f9d5f27fd084ebf62e6ba7f7904bd1fc03b4a74ca154a052ba18a9de1bf2440279fe0f67f8730d9824c854bf7b02e2067f8f4634f709593f7bc90f0f4
+MISC metadata.xml 765 BLAKE2B 874bf50ec76340996854eab79228aff15fa384d553c392384ff9ef6b04ef7eadd7f955e28b227dbc57ff80d2c4f3baf6172828e5c4d679ccdcc3848e71cd9f3b SHA512 e240fae1af1946c99dc5dd2574f9106c6d9cee1d2b29f0fb8b905a532c37a42e0c39a4b07df1d16f4ad321bd5c404c6d4bb4221f0b609529b5b3ceff6021ed03
diff --git a/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild b/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild
new file mode 100644
index 000000000000..d969f9d022ed
--- /dev/null
+++ b/sci-libs/coinor-utils/coinor-utils-2.11.4.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+MY_PN=CoinUtils
+
+DESCRIPTION="COIN-OR Matrix, Vector and other utility classes"
+HOMEPAGE="https://github.com/coin-or/CoinUtils/"
+SRC_URI="https://github.com/coin-or/${MY_PN}/archive/releases/${PV}.tar.gz
+	-> ${P}.tar.gz"
+LICENSE="EPL-1.0"
+
+# major soname component
+SLOT="0/3"
+
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="bzip2 doc glpk blas lapack static-libs test zlib"
+RESTRICT="!test? ( test )"
+
+# Fortran is NOT needed, but the ./configure scripts for all of the CoinOR
+# packages contain a check for it. Gentoo bug 601648 and upstream issue,
+#
+#   https://github.com/coin-or/CoinUtils/issues/132
+#
+BDEPEND="virtual/fortran
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] )
+	test? ( sci-libs/coinor-sample )"
+DEPEND="sys-libs/readline:0=
+	blas? ( virtual/blas )
+	bzip2? ( app-arch/bzip2 )
+	glpk? ( sci-mathematics/glpk:= )
+	lapack? ( virtual/lapack )
+	zlib? ( sys-libs/zlib )"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_PN}-releases-${PV}/${MY_PN}"
+
+src_prepare() {
+	# Needed to make the --with-coin-instdir in src_configure happy.
+	dodir /usr
+
+	# They don't need to guess at this, but they do, and get it wrong...
+	sed -e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
+		-i configure \
+		|| die "failed to fix the pkgconfig path in ${S}/configure"
+
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-dependency-linking
+		--with-coin-instdir="${ED}/usr"
+		$(use_enable zlib)
+		$(use_enable bzip2 bzlib)
+		$(use_with doc dot)
+	)
+	if use blas; then
+		myeconfargs+=( --with-blas-lib="$($(tc-getPKG_CONFIG) --libs blas)" )
+	else
+		myeconfargs+=( --without-blas )
+	fi
+	if use glpk; then
+		myeconfargs+=(
+			--with-glpk-incdir="${EPREFIX}"/usr/include
+			--with-glpk-lib=-lglpk
+		)
+	else
+		myeconfargs+=( --without-glpk )
+	fi
+	if use lapack; then
+		myeconfargs+=( --with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)" )
+	else
+		myeconfargs+=( --without-lapack )
+	fi
+
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake all $(usex doc doxydoc "")
+}
+
+src_test() {
+	# NOT redundant! The build system has a "make check" target that does
+	# nothing, so if you don't specify "test" here, you'll get a no-op.
+	emake test
+}
+
+src_install() {
+	use doc && HTML_DOC=("${BUILD_DIR}/doxydocs/html/")
+
+	emake DESTDIR="${D}" install
+
+	# Duplicate junk, and in the wrong location.
+	rm -r "${ED}/usr/share/coin/doc/${MY_PN}" || die
+}
diff --git a/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild b/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild
deleted file mode 100644
index 29e79cb5bf8a..000000000000
--- a/sci-libs/coinor-utils/coinor-utils-2.9.11.ebuild
+++ /dev/null
@@ -1,84 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-
-inherit autotools-utils multilib toolchain-funcs
-
-MYPN=CoinUtils
-
-DESCRIPTION="COIN-OR Matrix, Vector and other utility classes"
-HOMEPAGE="https://projects.coin-or.org/CoinUtils/"
-SRC_URI="http://www.coin-or.org/download/source/${MYPN}/${MYPN}-${PV}.tgz"
-
-LICENSE="EPL-1.0"
-SLOT="0/3"
-KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
-IUSE="bzip2 doc glpk blas lapack static-libs test zlib"
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	sys-libs/readline:0=
-	bzip2? ( app-arch/bzip2 )
-	blas? ( virtual/blas )
-	glpk? ( sci-mathematics/glpk:= )
-	lapack? ( virtual/lapack )
-	zlib? ( sys-libs/zlib )"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	doc? ( app-doc/doxygen[dot] )
-	test? ( sci-libs/coinor-sample )"
-
-S="${WORKDIR}/${MYPN}-${PV}/${MYPN}"
-
-src_prepare() {
-	dodir /usr
-	sed \
-		-e "s:lib/pkgconfig:$(get_libdir)/pkgconfig:g" \
-		-i configure || die
-	autotools-utils_src_prepare
-}
-
-src_configure() {
-	local myeconfargs=(
-		--enable-dependency-linking
-		--with-coin-instdir="${ED}"/usr
-		$(use_enable zlib)
-		$(use_enable bzip2 bzlib)
-		$(use_with doc dot)
-	)
-	if use blas; then
-		myeconfargs+=( --with-blas-lib="$($(tc-getPKG_CONFIG) --libs blas)" )
-	else
-		myeconfargs+=( --without-blas )
-	fi
-	if use glpk; then
-		myeconfargs+=(
-			--with-glpk-incdir="${EPREFIX}"/usr/include
-			--with-glpk-lib=-lglpk
-		)
-	else
-		myeconfargs+=( --without-glpk )
-	fi
-	if use lapack; then
-		myeconfargs+=( --with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)" )
-	else
-		myeconfargs+=( --without-lapack )
-	fi
-	autotools-utils_src_configure
-}
-
-src_compile() {
-	autotools-utils_src_compile all $(usex doc doxydoc "")
-}
-
-psrc_test() {
-	autotools-utils_src_test test
-}
-
-src_install() {
-	use doc && HTML_DOC=("${BUILD_DIR}/doxydocs/html/")
-	autotools-utils_src_install
-	# already installed
-	rm "${ED}"/usr/share/coin/doc/${MYPN}/{README,AUTHORS,LICENSE} || die
-}
diff --git a/sci-libs/coinor-utils/metadata.xml b/sci-libs/coinor-utils/metadata.xml
index 871e40d0656c..c4ba4a30fb7c 100644
--- a/sci-libs/coinor-utils/metadata.xml
+++ b/sci-libs/coinor-utils/metadata.xml
@@ -6,13 +6,18 @@
     <name>Gentoo Science Project</name>
   </maintainer>
   <longdescription lang="en">
-  CoinUtils (Coin-or Utilities) is a collection of classes that are
-  generally useful to COmputational INfrastructure for Operations
-  Research (COIN-OR) projects. These include vector, matrix, mps file
-  reading classes.
-</longdescription>
+    CoinUtils (Coin-or Utilities) is a collection of classes that are
+    generally useful to COmputational INfrastructure for Operations
+    Research (COIN-OR) projects. These include vector, matrix, mps
+    file reading classes.
+  </longdescription>
   <use>
-    <flag name="glpk">Enable GNU Linear Programming Kit
-  <pkg>sci-mathematics/glpk</pkg> support</flag>
+    <flag name="glpk">
+      Enable GNU Linear Programming Kit
+      <pkg>sci-mathematics/glpk</pkg> support
+    </flag>
   </use>
+  <upstream>
+    <remote-id type="github">coin-or/CoinUtils</remote-id>
+  </upstream>
 </pkgmetadata>