gentoo auto-resync : 01:01:2025 - 06:30:57

2 files changed, 180 insertions, 0 deletions

diff --git a/sci-libs/dealii/Manifest b/sci-libs/dealii/Manifest
index 3e36eb7c1f23..9629e1669e0b 100644
--- a/sci-libs/dealii/Manifest
+++ b/sci-libs/dealii/Manifest
@@ -11,8 +11,11 @@ DIST dealii-9.5.2.tar.gz 31523493 BLAKE2B 4ad55b0c4c7b1c02de17007f44b345856ec181
 DIST dealii-9.5.2.tar.gz.asc 246 BLAKE2B bacd1dac5a6f3d0d6639329512f5c4cafe39ecd036a7a4e38b81d31b6ee452d496190e8ae26c814631cc62c42208a1df1cd081ac8accd97d2821d7091495b898 SHA512 1821b4763ddcda11baf37b88ae90ec73576d2cacdeb53f4196dcde9e1649e685eb1666b86317d4573944769642b09bc76fc1de34a5e8e436004552f8652cad23
 DIST dealii-9.6.0.tar.gz 40829532 BLAKE2B 0219f7586a79b22810ac4bb0aa6eba4630dd8002f39abb76c920c5456a7c9cf6e3c3eb66a2670f8a0fc1158a7a186482e65b210743b7f9900c081c67199e0d34 SHA512 d65b3c73900589f84713ff8e926d2cd566501c2498fd64d314f71d4d525009f36d194693f92608b83cacc1ac985ea1c413fc6a4bbf8c7ff598645f7773a632b4
 DIST dealii-9.6.0.tar.gz.asc 246 BLAKE2B 3b34f1cc6df91c9052a1c00ce66e462ad8e735a921a37bb2228dcf7b1725b44d543cef40823c4cab01e77e55f09becef8a192492d99f412b21d18f5fd7bf9d64 SHA512 9d9e390399792c6f9a19a4e9666ace7657abf01d1ba489084dfa8d9729635022ae25c2e1b02c8825bddc149c8249402d65e8cf5c1bbe1441858109d0c93826a5
+DIST dealii-9.6.2.tar.gz 40863604 BLAKE2B 5214b9cfd78e48f2588046b1a3d68837f9d856191c77d179c384ddaa524a464bd2cd9eef6597bdc036e9fa7121843c048ff035fa926aa67a1a15e1c1f85f276e SHA512 79fe3c3baba4bcb479f30ae863e577e64d0a6ea488172a9d6bacecf1e5ec845f47eff9a8bf3cb4651e6803b9b0c38dc32ca745abc64737d66aedf7ec73c2e362
+DIST dealii-9.6.2.tar.gz.asc 246 BLAKE2B 067b15614652e26a4ec16f8afc8b6842fbb8221b9840c54304611a0dcbedb9073209307bc2248e7b902738b3c120b31688df71b53efd8f603135b033811a8f53 SHA512 4845e485cf1f5b24efde38cd0da91a265e5dd73c81b5099e6638ee917e7e43c842688dac5388e0ec3306eae0aba28dac25ccc88f0d1680a9150d88aae4a6d6ee
 EBUILD dealii-9.4.2-r1.ebuild 6038 BLAKE2B c40eacc59221b91a342919237171fe16bc8092189d1c4cb57fc3bd4c5c05af3ee58619d8e613be2d6181c80138d0463169272fe8805fb766fce1cfea50ac5071 SHA512 194ae81deec32c3da98610f7e28714d9f59c963eeb33538a07de7db1efdc1816e9792450d6b7c7cf934982b2d7126b56b3513657d2b93ade208413e2dbc70464
 EBUILD dealii-9.5.2-r1.ebuild 5704 BLAKE2B f15b66758e594fba1726f5aa5263aa3ea7c046e1825da8118f0a30ea214e25abb295b305885d90b30263ed838b1eace390422cbddb75dc065a2e76ae25bfcc5e SHA512 ff7081a7fb8c24fdd428b64d4df567509dd9c30559d4fc787e2e6f6b4dc801af451400c6a5cf5554076e9884fc407495c9bd95eec9ab8fa6dff5d60ec07c29b2
 EBUILD dealii-9.6.0.ebuild 5562 BLAKE2B 644bd108d4ac9616a33aae98938322ad631bdc06cf8e52a36e40e7f28888ec1d67bf38e6213f027f0c8144ec8d3921d2e6b0c7d894b98148ab6744f7e9211588 SHA512 2df99eba95d375ad5c4a6dfc76e1a123f0e5d421d50f3289750fdfb364fde708a8cb52ff8dd3a5f1d500ffd1286258aa37ec8cf639d1edb5517b4ae6bc81dde7
+EBUILD dealii-9.6.2.ebuild 5562 BLAKE2B 644bd108d4ac9616a33aae98938322ad631bdc06cf8e52a36e40e7f28888ec1d67bf38e6213f027f0c8144ec8d3921d2e6b0c7d894b98148ab6744f7e9211588 SHA512 2df99eba95d375ad5c4a6dfc76e1a123f0e5d421d50f3289750fdfb364fde708a8cb52ff8dd3a5f1d500ffd1286258aa37ec8cf639d1edb5517b4ae6bc81dde7
 EBUILD dealii-9999.ebuild 5169 BLAKE2B 593ee88766dbcba2df2c6f06795f27b24fce1948b9cf8611e257662b9300b505b15623d79d7fef47060029b1982688040b28ada5622bc13380879d61142ffa51 SHA512 43ea2366f56d21e25e3a5c323daf63023e3dedcdb45908765fe1f8c31535fc6dd99a48c17f3000170347950bb844e56b58495c55613336698479bf87b25670db
 MISC metadata.xml 2301 BLAKE2B 27f29025acaf1cdf2637c9ce38b7d94cb63a29064c3fc315b86818e155cb675ac387998855498754d42f10abcbd3c14b92bd0d9ce503b24614490d2d45668166 SHA512 28ce9b2664538cdd933fe72fec79a85ad75fc5f451d14fb5946b92bba7d8c387e9e6226f831bc5b02e841f9e94c28d404f34a1211ed3a00a49eaff5a8d7dc8a1
diff --git a/sci-libs/dealii/dealii-9.6.2.ebuild b/sci-libs/dealii/dealii-9.6.2.ebuild
new file mode 100644
index 000000000000..bdf2169689c0
--- /dev/null
+++ b/sci-libs/dealii/dealii-9.6.2.ebuild
@@ -0,0 +1,177 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+# deal.II uses its own FindLAPACK.cmake file that calls into the system
+# FindLAPACK.cmake module and does additional internal setup. Do not remove
+# any of these modules:
+CMAKE_REMOVE_MODULES_LIST=""
+
+inherit cmake flag-o-matic verify-sig
+
+DESCRIPTION="Solving partial differential equations with the finite element method"
+HOMEPAGE="https://www.dealii.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/dealii/dealii.git"
+	SRC_URI=""
+else
+	DOC_PV=9.5.0
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz
+		verify-sig? ( https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz.asc )
+		doc? (
+			https://github.com/${PN}/${PN}/releases/download/v${DOC_PV}/${PN}-${DOC_PV}-offline_documentation.tar.gz
+			verify-sig? ( https://github.com/${PN}/${PN}/releases/download/v${DOC_PV}/${PN}-${DOC_PV}-offline_documentation.tar.gz.asc )
+			)"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="
+	adolc arborx assimp arpack cgal cpu_flags_x86_avx cpu_flags_x86_avx512f
+	cpu_flags_x86_sse2 cuda +debug doc +examples ginkgo gmsh +gsl hdf5
+	+lapack metis mpi muparser opencascade p4est petsc scalapack slepc
+	+sparse sundials symengine trilinos
+"
+
+# TODO: add slepc use flag once slepc is packaged for gentoo-science
+REQUIRED_USE="
+	arborx? ( trilinos )
+	p4est? ( mpi )
+	slepc? ( petsc )
+	trilinos? ( mpi )"
+
+RDEPEND="dev-libs/boost:=
+	app-arch/bzip2
+	sys-libs/zlib
+	dev-cpp/tbb:=
+	arborx? ( sci-libs/arborx[mpi=] )
+	adolc? ( sci-libs/adolc )
+	arpack? ( sci-libs/arpack[mpi=] )
+	assimp? ( media-libs/assimp:= )
+	cgal? ( sci-mathematics/cgal )
+	cuda? ( dev-util/nvidia-cuda-toolkit )
+	ginkgo? ( sci-libs/ginkgo )
+	gmsh? ( sci-libs/gmsh )
+	gsl? ( sci-libs/gsl:= )
+	hdf5? ( sci-libs/hdf5:=[mpi=] )
+	lapack? ( virtual/lapack )
+	metis? (
+		>=sci-libs/metis-5
+		mpi? ( >=sci-libs/parmetis-4 )
+	)
+	mpi? ( virtual/mpi[cxx] )
+	muparser? ( dev-cpp/muParser )
+	opencascade? ( sci-libs/opencascade:= )
+	p4est? ( sci-libs/p4est[mpi] )
+	petsc? ( sci-mathematics/petsc[mpi=] )
+	scalapack? ( sci-libs/scalapack )
+	slepc? ( sci-mathematics/slepc[mpi=] )
+	sparse? ( sci-libs/umfpack )
+	sundials? ( sci-libs/sundials:= )
+	symengine? ( >=sci-libs/symengine-0.4:= )
+	trilinos? ( sci-libs/trilinos )
+	|| (
+		dev-cpp/kokkos
+		sci-libs/trilinos
+	)
+	"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-text/doxygen[dot] dev-lang/perl )"
+
+BDEPEND="
+	verify-sig? ( >=sec-keys/openpgp-keys-dealii-20240811 )"
+
+PATCHES=(
+)
+
+VERIFY_SIG_OPENPGP_KEY_PATH="/usr/share/openpgp-keys/dealii.asc"
+
+src_configure() {
+	# deal.II needs a custom build type:
+	local CMAKE_BUILD_TYPE=$(usex debug DebugRelease Release)
+
+	local mycmakeargs=(
+		-DDEAL_II_PACKAGE_VERSION="${PV}"
+		-DCMAKE_INSTALL_RPATH_USE_LINK_PATH=OFF
+		-DDEAL_II_ALLOW_AUTODETECTION=OFF
+		-DDEAL_II_ALLOW_BUNDLED=OFF
+		-DDEAL_II_ALLOW_PLATFORM_INTROSPECTION=OFF
+		-DDEAL_II_COMPILE_EXAMPLES=OFF
+		-DDEAL_II_DOCHTML_RELDIR="share/doc/${P}/html"
+		-DDEAL_II_DOCREADME_RELDIR="share/doc/${P}"
+		-DDEAL_II_COMPILE_EXAMPLES=OFF
+		-DDEAL_II_EXAMPLES_RELDIR="share/doc/${P}/examples"
+		-DDEAL_II_LIBRARY_RELDIR="$(get_libdir)"
+		-DDEAL_II_SHARE_RELDIR="share/${PN}"
+		-DDEAL_II_WITH_ZLIB=ON
+		-DDEAL_II_WITH_ADOLC="$(usex adolc)"
+		-DDEAL_II_WITH_ARBORX="$(usex arborx)"
+		-DDEAL_II_WITH_ASSIMP="$(usex assimp)"
+		-DDEAL_II_WITH_ARPACK="$(usex arpack)"
+		-DDEAL_II_WITH_CGAL="$(usex cgal)"
+		-DDEAL_II_WITH_CUDA="$(usex cuda)"
+		-DDEAL_II_WITH_GINKGO="$(usex ginkgo)"
+		-DDEAL_II_COMPONENT_DOCUMENTATION="$(usex doc)"
+		-DDEAL_II_COMPONENT_EXAMPLES="$(usex examples)"
+		-DDEAL_II_WITH_GMSH="$(usex gmsh)"
+		-DDEAL_II_WITH_GSL="$(usex gsl)"
+		-DDEAL_II_WITH_HDF5="$(usex hdf5)"
+		-DDEAL_II_WITH_LAPACK="$(usex lapack)"
+		-DDEAL_II_WITH_METIS="$(usex metis)"
+		-DDEAL_II_WITH_MPI="$(usex mpi)"
+		-DDEAL_II_WITH_MUPARSER="$(usex muparser)"
+		-DDEAL_II_WITH_OPENCASCADE="$(usex opencascade)"
+		-DDEAL_II_WITH_P4EST="$(usex p4est)"
+		-DDEAL_II_WITH_PETSC="$(usex petsc)"
+		-DDEAL_II_WITH_SCALAPACK="$(usex scalapack)"
+		-DDEAL_II_WITH_SLEPC="$(usex slepc)"
+		-DDEAL_II_WITH_SUNDIALS="$(usex sundials)"
+		-DDEAL_II_WITH_SYMENGINE="$(usex symengine)"
+		-DDEAL_II_WITH_UMFPACK="$(usex sparse)"
+		-DDEAL_II_WITH_TBB=ON
+		-DDEAL_II_WITH_TASKFLOW=OFF
+		-DDEAL_II_WITH_TRILINOS="$(usex trilinos)"
+	)
+
+	use opencascade && mycmakeargs+=(
+		-DCMAKE_PREFIX_PATH="/usr/$(get_libdir)/opencascade"
+	)
+
+	# Do a little dance for purely cosmetic QA reasons. The build system
+	# does query for the highest instruction set first and skips the other
+	# variables if a "higher" variant is set
+	if use cpu_flags_x86_avx512f; then
+		mycmakeargs+=( -DDEAL_II_HAVE_AVX512=yes )
+		append-cxxflags "-mavx512f"
+	elif use cpu_flags_x86_avx; then
+		mycmakeargs+=( -DDEAL_II_HAVE_AVX=yes )
+		append-cxxflags "-mavx2"
+	elif use cpu_flags_x86_avx; then
+		mycmakeargs+=( -DDEAL_II_HAVE_SSE2=yes )
+		append-cxxflags "-msse2"
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	if use doc && [[ ${PV} != *9999* ]]; then
+		# copy missing images to the build directory:
+		cp -r "${WORKDIR}"/doc/doxygen/deal.II/images \
+			"${BUILD_DIR}"/doc/doxygen/deal.II || die
+		# replace links:
+		sed -i \
+			's#"http://www.dealii.org/images/steps/developer/\(step-.*\)"#"images/\1"#g' \
+			"${BUILD_DIR}"/doc/doxygen/deal.II/step_*.html || die "sed failed"
+	fi
+	cmake_src_install
+
+	# decompress the installed example sources:
+	use examples && docompress -x /usr/share/doc/${PF}/examples
+}