gentoo resync : 15.01.2020

1 files changed, 54 insertions, 0 deletions

diff --git a/sci-libs/libsigrokdecode/libsigrokdecode-0.5.3.ebuild b/sci-libs/libsigrokdecode/libsigrokdecode-0.5.3.ebuild
new file mode 100644
index 000000000000..1dd2104c01a3
--- /dev/null
+++ b/sci-libs/libsigrokdecode/libsigrokdecode-0.5.3.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit eutils python-single-r1
+
+if [[ ${PV} == "9999" ]]; then
+	EGIT_REPO_URI="git://sigrok.org/${PN}"
+	inherit git-r3 autotools
+else
+	SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="provide (streaming) protocol decoding functionality"
+HOMEPAGE="https://sigrok.org/wiki/Libsigrokdecode"
+
+LICENSE="GPL-3"
+SLOT="0/4"
+IUSE="static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND=">=dev-libs/glib-2.34.0
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	[[ ${PV} == "9999" ]] && eautoreconf
+
+	# Only a test program (not installed, and not used by src_test)
+	# is used by libsigrok, so disable it to avoid the compile.
+	sed -i \
+		-e '/build_runtc=/s:yes:no:' \
+		configure || die
+
+	eapply_user
+}
+
+src_configure() {
+	econf $(use_enable static-libs static)
+}
+
+src_test() {
+	emake check
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}