gentoo Easter resync : 12.04.2020

1 files changed, 69 insertions, 0 deletions

diff --git a/sci-mathematics/glpk/glpk-4.65.ebuild b/sci-mathematics/glpk/glpk-4.65.ebuild
new file mode 100644
index 000000000000..258796fa21ae
--- /dev/null
+++ b/sci-mathematics/glpk/glpk-4.65.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools flag-o-matic toolchain-funcs
+
+DESCRIPTION="GNU Linear Programming Kit"
+LICENSE="GPL-3"
+HOMEPAGE="https://www.gnu.org/software/glpk/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+SLOT="0/40"
+IUSE="doc examples gmp odbc mysql static-libs"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-macos"
+
+BDEPEND="virtual/pkgconfig"
+DEPEND="
+	sci-libs/amd:0=
+	sci-libs/colamd:=
+	sys-libs/zlib:0=
+	gmp? ( dev-libs/gmp:0= )
+	mysql? ( dev-db/mysql-connector-c )
+	odbc? ( || ( dev-db/libiodbc:0 dev-db/unixODBC:0 ) )"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-4.65-fix-mysql-include-prefix.patch"
+	"${FILESDIR}/${PN}-4.65-debundle-system-libs.patch"
+	"${FILESDIR}/${PN}-4.65-longstep_verbosity.patch"
+)
+
+src_prepare() {
+	# TODO: the ODBC library is dlopen()ed, so we only want to append
+	# -I<foo> to the preprocessor flags, and not all of the CFLAGS that
+	# were used to build libiodbc. That fix and the pkg-config fallback
+	# should be sent upstream, and placed into CPPFLAGS rather than
+	# CFLAGS (as configure.ac does now).
+	use odbc && [[ -z $(type -P odbc_config) ]] && \
+		append-cppflags $($(tc-getPKG_CONFIG) --cflags libiodbc)
+
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf
+	if use mysql || use odbc; then
+		myconf="--enable-dl"
+	else
+		myconf="--disable-dl"
+	fi
+
+	econf ${myconf} \
+		$(use_enable mysql) \
+		$(use_enable odbc) \
+		$(use_enable static-libs static) \
+		$(use_with gmp)
+}
+
+src_install() {
+	default
+	if use examples; then
+		insinto "/usr/share/doc/${PF}"
+		doins -r examples
+		docompress -x "/usr/share/doc/${PF}/examples"
+	fi
+	use doc && dodoc doc/*.pdf doc/notes/*.pdf doc/*.txt
+}