gentoo auto-resync : 21:04:2023 - 00:01:05

2 files changed, 238 insertions, 0 deletions

diff --git a/sci-visualization/paraview/Manifest b/sci-visualization/paraview/Manifest
index ee89fcfce86b..1ebbfcc5e69b 100644
--- a/sci-visualization/paraview/Manifest
+++ b/sci-visualization/paraview/Manifest
@@ -1,6 +1,8 @@
 AUX paraview-5.5.0-allow_custom_build_type.patch 1036 BLAKE2B ff00093034196935e9075c5751f8a64027da009679de5c3f5b941681e65df9b91b0a05a3f0201a873313d859f029596739b1c5d705a1c35ae3cc83251312774e SHA512 0c79315d28b98d4cf45bfd48198dbb3315ebf6ffbd05e9720b35e7bdea05bd98c086dbb02cd7ac6d9580f504c7d29f498244d2b30d9e2932e881261a78b020c7
 DIST ParaView-v5.10.1.tar.xz 70218088 BLAKE2B 3134c5df35994a3a153ebd97770066b9963911ae7fb1877681135e01a19c4a879306ae844ef3a29719be5cd509f35117f74eb3c264f1a101fa19180d9a126011 SHA512 1feb855432ea7bc40f77ee214e5877d5170e4f31f520dc7198d72a271506b65a4bc79922875d2c176e54219818a428497c606390a2b9da2770de403bd1593e6c
 DIST ParaView-v5.11.0-RC2.tar.xz 79802928 BLAKE2B 5aefec385f479bfd4709175dce7c98528532068ba576f1f256fe86612f5119576318c4ef73f71e4d0f55c43d4a39ccda2773ec7fd3461acc41a0b9399f4c16fa SHA512 3bbc73d7e6fdd55adc29bdd05caf78d6db1fbd3f295ce63c2c60fa4870880fe4c8534ab5c1ae7cc8748f874b2ffca15cff38bcca2392d14e95ba81fcb9b8a9e5
+DIST ParaView-v5.11.1.tar.xz 79847556 BLAKE2B efef5e519a82ef1c0a7d532578778f6a95f07ebd72ebefd0cbdcff0bfc3af1773601cd102ff81f45f302fcaa4bb6ec7ee68f7dec77f5d4e137c2842fbbb54e11 SHA512 d0e666b49f49e41dba23e23d454a9462f018bd6d832628b0029e8d54760f0439ca97841a26da3126c5144780fc01dc25234a6624fb35346a98d35cbe0e0c98ca
 EBUILD paraview-5.10.1-r4.ebuild 5696 BLAKE2B 4f430bf4f2b420e6e8a80654aabeb0cc60e0d5ac4dab7df0ec7c59253527508d1b2715678fa61379239b3b34b15468d1129df03ef60a8af9a964b2354a441259 SHA512 c46c11d821517c15141c690fa08b3795a6f5927b9a89d9f584d1470c824a44a670da49fe2410ab3520ac6200308b8b3285e6cbb2537d360555ab212bc4331771
 EBUILD paraview-5.11.0_rc2-r1.ebuild 5804 BLAKE2B 75afaeb33184870d799a8cedbba7ee0d485f4080c34bdc79f739a978a33ab2fc5e5fd4439c64a0a7f47c30c1b4b8bd1006b3b2381d81cdc0097ad29b2a891fce SHA512 d5f8904aba191caf4465ffec5136a8cb07283c914d8b07c8bff6e4d25ac7362d0fc8111b157355ecf3cec44775fc021028292f780a6664705ac9913f663115f9
+EBUILD paraview-5.11.1.ebuild 6069 BLAKE2B d46e0d9aa82fc16a50f50cfa7c6470b757a02c74f9a23dca9519250b0e891f90f82687f07c33c906bc33601c36c036365d4444164fd6343a0acfc278edcef082 SHA512 97dc39a33345a71b7398e59b8c250190a806d290e727b448a773644decbbea654a333c11b47b65446c5aadd363d5c4eca2bd279e3ff46af7a4f1e779ace11906
 MISC metadata.xml 683 BLAKE2B 28b4017609ac733ac1c1ff4cb4ac3b5341f72180f487542b9db3b8bee59357ac9fed25bc0287a2f8c93f7429d098d1b26c74741b86b943564a4caafd7ee8450e SHA512 0bd4a1c8331532529d405f36c4556f57caecc299ceddd4ca8ff23138d96bd450c1d4fade7f02edddd8f9b3062d6b31bcb9a7696b2b628494c1d1b60d0312bc91
diff --git a/sci-visualization/paraview/paraview-5.11.1.ebuild b/sci-visualization/paraview/paraview-5.11.1.ebuild
new file mode 100644
index 000000000000..14339e04a447
--- /dev/null
+++ b/sci-visualization/paraview/paraview-5.11.1.ebuild
@@ -0,0 +1,236 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+DOCS_BUILDER="doxygen"
+inherit cmake flag-o-matic desktop docs python-single-r1 qmake-utils toolchain-funcs xdg
+
+MAIN_PV=$(ver_cut 0-1)
+MAJOR_PV=$(ver_cut 1-2)
+MY_P="ParaView-v${PV}"
+
+DESCRIPTION="Powerful scientific data visualization application"
+HOMEPAGE="https://www.paraview.org"
+SRC_URI="https://www.paraview.org/files/v${MAJOR_PV}/${MY_P}.tar.xz"
+S="${WORKDIR}/${MY_P}"
+
+# TODO: check licenses of plugins (USE=plugins)
+LICENSE="BSD MIT PSF-2 VTK"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="boost cg examples ffmpeg mpi nvcontrol openmp offscreen plugins python +qt5 +sqlite test tk +webengine"
+
+RESTRICT="mirror test"
+
+REQUIRED_USE="
+	python? ( mpi ${PYTHON_REQUIRED_USE} )
+	webengine? ( qt5 )
+	qt5? ( sqlite )
+	?? ( offscreen qt5 )"
+
+# TODO: Verify that these two are not needed any more for the catalyst
+# module:
+#  - dev-python/PyQt5
+#  - dev-qt/qtgui:5[-gles2-only]
+RDEPEND="
+	app-arch/lz4
+	dev-libs/expat
+	dev-libs/jsoncpp:=
+	dev-libs/libxml2:2
+	dev-libs/protobuf:=
+	dev-libs/pugixml
+	media-libs/freetype
+	media-libs/glew:0
+	media-libs/libpng:0
+	media-libs/libtheora
+	media-libs/tiff:=
+	sci-libs/cgnslib
+	sci-libs/hdf5:=[mpi=]
+	>=sci-libs/netcdf-4.2[hdf5]
+	>=sci-libs/netcdf-cxx-4.2:3
+	sys-libs/zlib
+	virtual/glu
+	media-libs/libjpeg-turbo:=
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXmu
+	x11-libs/libXt
+	ffmpeg? ( media-video/ffmpeg )
+	mpi? ( virtual/mpi[cxx,romio] )
+	offscreen? ( >=media-libs/mesa-18.3.6[osmesa] )
+	!offscreen? ( virtual/opengl )
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-python/constantly[${PYTHON_USEDEP}]
+			dev-python/incremental[${PYTHON_USEDEP}]
+			dev-python/matplotlib[${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+			dev-python/pygments[${PYTHON_USEDEP}]
+			dev-python/sip:5[${PYTHON_USEDEP}]
+			dev-python/six[${PYTHON_USEDEP}]
+			dev-python/twisted[${PYTHON_USEDEP}]
+			dev-python/zope-interface[${PYTHON_USEDEP}]
+			mpi? ( dev-python/mpi4py )
+			qt5? ( dev-python/PyQt5[opengl,${PYTHON_USEDEP}] )
+		')
+	)
+	qt5? (
+		dev-qt/designer:5
+		dev-qt/qtgui:5[-gles2-only]
+		dev-qt/qthelp:5
+		dev-qt/qtopengl:5[-gles2-only]
+		dev-qt/qtsql:5
+		dev-qt/qtsvg:5
+		dev-qt/qttest:5
+		dev-qt/qtx11extras:5
+		dev-qt/qtxmlpatterns:5
+	)
+	sqlite? ( dev-db/sqlite:3 )
+	tk? ( dev-lang/tk:0= )
+	webengine? ( dev-qt/qtwebengine:5[widgets] )"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	boost? (
+		$(python_gen_cond_dep '
+			dev-libs/boost[mpi?,python,${PYTHON_USEDEP}]
+		')
+	)
+"
+
+BDEPEND="
+	openmp? ( virtual/fortran )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.5.0-allow_custom_build_type.patch
+)
+
+pkg_pretend() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+}
+
+pkg_setup() {
+	[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
+	use python && python-single-r1_pkg_setup
+	PVLIBDIR=$(get_libdir)/${PN}-${MAJOR_PV}
+}
+
+src_prepare() {
+	# Bug #661812
+	mkdir -p Plugins/StreamLinesRepresentation/doc || die
+
+	cmake_src_prepare
+
+	# lib64 fixes
+	sed -i \
+		-e "s:/lib/python:/$(get_libdir)/python:g" \
+		VTK/ThirdParty/xdmf3/vtkxdmf3/CMakeLists.txt || die
+	sed -i \
+		-e "s:lib/paraview-:$(get_libdir)/paraview-:g" \
+		Remoting/Application/vtkInitializationHelper.cxx || die
+}
+
+src_configure() {
+	# Needed to compile bundled VTK in ParaView 5.11.1 with gcc 12
+	# see also, bug #863299
+	filter-lto
+	append-cflags $(test-flags-CC -fno-strict-aliasing -Wno-error=incompatible-function-pointer-types -Wno-error=int-conversion)
+	append-cxxflags $(test-flags-CXX -fno-strict-aliasing -Wno-error=incompatible-function-pointer-types -Wno-error=int-conversion)
+
+	# Make sure qmlplugindump is in path:
+	export PATH="$(qt5_get_bindir):${PATH}"
+
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_LIBDIR="${PVLIBDIR}"
+		-UBUILD_SHARED_LIBS
+		-DPARAVIEW_BUILD_SHARED_LIBS=ON
+		-DCMAKE_VERBOSE_MAKEFILE=ON
+
+		# boost
+		-DVTK_MODULE_ENABLE_VTK_IOInfovis="$(usex boost YES NO)"
+
+		# doc
+		-DPARAVIEW_BUILD_DEVELOPER_DOCUMENTATION="$(usex doc)"
+
+		# examples
+		-DBUILD_EXAMPLES="$(usex examples)"
+
+		# ffmpeg
+		-DPARAVIEW_ENABLE_FFMPEG="$(usex ffmpeg)"
+
+		# mpi
+		-DPARAVIEW_USE_MPI="$(usex mpi)"
+		-DXDMF_BUILD_MPI="$(usex mpi)"
+		-DVTK_GROUP_ENABLE_MPI="$(usex mpi YES NO)"
+
+		# offscreen
+		-DVTK_OPENGL_HAS_OSMESA="$(usex offscreen)"
+		-DVTK_OPENGL_HAS_OSMESA="$(usex offscreen)"
+
+		# plugins
+		-DPARAVIEW_PLUGINS_DEFAULT="$(usex plugins)"
+
+		# python
+		-DModule_pqPython="$(usex python)"
+		-DPARAVIEW_USE_PYTHON="$(usex python)"
+
+		# qt5
+		-DPARAVIEW_USE_QT="$(usex qt5)"
+		-DModule_pqPython="$(usex qt5 "$(usex python)" "off")"
+		-DVTK_USE_NVCONTROL="$(usex nvcontrol)"
+		-DVTK_GROUP_ENABLE_Qt="$(usex qt5 YES NO)"
+		-DCMAKE_INSTALL_QMLDIR="${EPREFIX}/usr/$(get_libdir)/qt5/qml"
+
+		# sqlite
+		-DVTK_MODULE_ENABLE_VTK_sqlite="$(usex sqlite YES NO)"
+
+		# test
+		-DBUILD_TESTING="$(usex test)"
+
+		# tk
+		-DVTK_USE_TK="$(usex tk)"
+		-DVTK_GROUP_ENABLE_Tk="$(usex tk YES NO)"
+
+		# webengine
+		-DPARAVIEW_USE_QTWEBENGINE="$(usex webengine)"
+		-DVTK_GROUP_ENABLE_Web="$(usex webengine YES NO)"
+	)
+
+	if use openmp; then
+		mycmakeargs+=( -DVTK_SMP_IMPLEMENTATION_TYPE=OpenMP )
+	fi
+
+	if use qt5; then
+		mycmakeargs+=(
+			-DOPENGL_gl_LIBRARY="${EPREFIX}"/usr/$(get_libdir)/libGL.so
+			-DOPENGL_glu_LIBRARY="${EPREFIX}"/usr/$(get_libdir)/libGLU.so
+			-DQT_MOC_EXECUTABLE="$(qt5_get_bindir)/moc"
+			-Dqt_xmlpatterns_executable="$(qt5_get_bindir)/xmlpatterns"
+		)
+	fi
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	# remove wrapper binaries and put the actual executable in place
+	for i in {paraview-config,pvserver,pvdataserver,pvrenderserver,pvbatch,pvpython,paraview}; do
+		if [ -f "${ED}"/usr/lib/"$i" ]; then
+			mv "${ED}"/usr/lib/"$i" "${ED}"/usr/bin/"$i" || die
+		fi
+	done
+
+	# set up the environment
+	echo "LDPATH=${EPREFIX}/usr/${PVLIBDIR}" > "${T}"/40${PN} || die
+	doenvd "${T}"/40${PN}
+
+	newicon "${S}"/Clients/ParaView/pvIcon-96x96.png paraview.png
+	make_desktop_entry paraview "Paraview" paraview
+
+	use python && python_optimize "${ED}/usr/$(get_libdir)/${PN}-${MAJOR_PV}"
+}