gentoo resync : 22.10.2018

1 files changed, 56 insertions, 0 deletions

diff --git a/sys-apps/ethq/ethq-0.5.0.ebuild b/sys-apps/ethq/ethq-0.5.0.ebuild
new file mode 100644
index 000000000000..eaaf909be1af
--- /dev/null
+++ b/sys-apps/ethq/ethq-0.5.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PV=${PV//./_}
+MY_P=${PN}-${MY_PV}
+
+inherit toolchain-funcs
+
+DESCRIPTION="Ethernet NIC Queue stats viewer"
+HOMEPAGE="https://github.com/isc-projects/ethq"
+SRC_URI="https://github.com/isc-projects/ethq/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+DEPEND="sys-libs/ncurses:0"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+src_prepare() {
+	default
+
+	# Respect FLAGS
+	sed -i \
+		-e '/CXXFLAGS/s/= -O3/+=/' \
+		-e 's/ -Werror//' \
+		-e '/LDFLAGS/s/=/+=/' Makefile || die "sed failed for Makefile"
+
+	if ! use test ; then
+		sed -i '/TARGETS/s/ethq_test//' Makefile \
+			|| die "sed failed for USE flag test"
+	fi
+}
+
+src_compile() {
+	# override for ncurses[tinfo]
+	emake CXX="$(tc-getCXX)" LIBS_CURSES="$($(tc-getPKG_CONFIG) --libs ncurses)"
+}
+
+src_test() {
+	local driver
+	for driver in tests/* ; do
+		"${S}"/ethq_test "${driver##*/}" "${driver}" \
+			|| die "test failed on ${driver}"
+	done
+}
+
+src_install() {
+	einstalldocs
+	dobin ethq
+}