gentoo auto-resync : 23:09:2022 - 05:29:13

2 files changed, 0 insertions, 162 deletions

diff --git a/sys-apps/file/Manifest b/sys-apps/file/Manifest
index 6442ad4df5f0..87bc1c66f534 100644
--- a/sys-apps/file/Manifest
+++ b/sys-apps/file/Manifest
@@ -8,7 +8,6 @@ DIST file-5.43.tar.gz 1162786 BLAKE2B aaaf32c5054fb83e912af6656e5e67947f45576ec3
 DIST file-5.43.tar.gz.asc 195 BLAKE2B d7f83b3e21d1390467989f8870e36daa48ebb8c5ac7ab8dc6d667a65d10561126d32cfc5ef3d81a130990b3e46bcba9b5e03f0a7dd169782351b02cebec2471f SHA512 c565958840f2f5c62821cd08d4149ec97c574232913ec00400473364e160250cfaced8c715e109c4c617359e33d2470f7ca6af1891cbdf994329e890f90c8be3
 EBUILD file-5.41.ebuild 3347 BLAKE2B 413305c675ac4b0af437e2ca48d4edd3ca29bbd3cfac376ebaed000142eb5a191f7d1c85449838ae204ec6c294828af68cfd7e6fe885b82c255d0570bc16b18d SHA512 396ef33817680b5bd48d7239e455f3c798f8813267ab7ea19dae7f845ad039164b88c6600887aba4254916a4ec857baaf01b949c6276510490e089d1f5b52f9b
 EBUILD file-5.42-r1.ebuild 3760 BLAKE2B 218d9cdc0b2c4387c6ba06729b56e4d886639ce8fe883a5be1593acdd2204012a88748afa76654f600ad38e88132c6cb6d73853dab5d717cdee8be1cb0a82d66 SHA512 dc21797dd4a187abf91d3f52bdc798e3c1838c6bd4930de4a209d46fdb7331268ad5710f062436b9208f21cc7618dd6c49a71e10e09a60643cfd6a288d939108
-EBUILD file-5.42.ebuild 3712 BLAKE2B 5f769622b69aa3836386f50da10da5f9e8ef8bc0e8ae82637686a791d6b2c20261056f8386ba896aa0d9450367127312c601d9371da1fa5c912900deeb1d505d SHA512 eac92daa30a5c84a9205498d1bf994a17f84b8d815b62b5c580c783cedf845d45a0d55d7f29a088306b4b40386bc819f13b8f929d988f1770388a1d16d42efc3
 EBUILD file-5.43.ebuild 3712 BLAKE2B 3081dc9e676be42da2cbc8fb34018b2e4f63ffb9c0854346325c574d71942608db81463fd5c80756455e1541c838e3d27f51f7d228a16549316fcc51954acfc0 SHA512 25de2f67fabd5f276a52c271ff1627a3387ffaf1f7d1b12893e5b6c6f56c2a64b54f2011787260bf7283cfe7a3e807631da8c0c2ede3e9237e39cd450cde7cd9
 EBUILD file-9999.ebuild 3870 BLAKE2B ac7f37d005c94d589cf9663a2443d7ea49df93e52da2b66c60d1e755ba787810c1885d47268e424857e19755786d69660415f137baf3f4b2325b40e94dc998a3 SHA512 d44ae484b41b20df592a0b69ce054557a963f8b63b956f9ec70564351d7c23ab26d969bc3f1d914a0440da7dad72b1ae413193c1e6cc1a1263e4052a64028309
 MISC metadata.xml 565 BLAKE2B 737512e354fedb4483608b04c594a486c0d8a0f70d23d306c59c78dedb0c8116f80ff558926444b9d9b9ef15805b3826163523b5644c88f01a330be1b8c9a76f SHA512 f240bf9e064c6e6f5b63e3265dfe3adf5b1d2c2b5b2456b79ea7451580150271ccb4097d33967de57ba767fecbdbea51fb62ccb683fcc5e1cca101be660ffd19
diff --git a/sys-apps/file/file-5.42.ebuild b/sys-apps/file/file-5.42.ebuild
deleted file mode 100644
index 0b9cc3af8dba..000000000000
--- a/sys-apps/file/file-5.42.ebuild
+++ /dev/null
@@ -1,161 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-DISTUTILS_USE_PEP517=setuptools
-DISTUTILS_OPTIONAL=1
-PYTHON_COMPAT=( python3_{8..11} )
-
-inherit distutils-r1 libtool toolchain-funcs multilib-minimal
-
-if [[ ${PV} == 9999 ]] ; then
-	EGIT_REPO_URI="https://github.com/glensc/file.git"
-	inherit autotools git-r3
-else
-	VERIFY_SIG_OPENPGP_KEY_PATH="${BROOT}"/usr/share/openpgp-keys/file.asc
-	inherit verify-sig
-	SRC_URI="ftp://ftp.astron.com/pub/file/${P}.tar.gz"
-	SRC_URI+=" verify-sig? ( ftp://ftp.astron.com/pub/file/${P}.tar.gz.asc )"
-
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
-
-	BDEPEND="verify-sig? ( sec-keys/openpgp-keys-file )"
-fi
-
-DESCRIPTION="Identify a file's format by scanning binary data for patterns"
-HOMEPAGE="https://www.darwinsys.com/file/"
-
-LICENSE="BSD-2"
-SLOT="0"
-IUSE="bzip2 lzma python seccomp static-libs zlib"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-
-DEPEND="
-	bzip2? ( app-arch/bzip2[${MULTILIB_USEDEP}] )
-	lzma? ( app-arch/xz-utils[${MULTILIB_USEDEP}] )
-	python? (
-		${PYTHON_DEPS}
-		dev-python/setuptools[${PYTHON_USEDEP}]
-	)
-	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )"
-RDEPEND="${DEPEND}
-	python? ( !dev-python/python-magic )
-	seccomp? ( sys-libs/libseccomp[${MULTILIB_USEDEP}] )"
-BDEPEND+="
-	python? (
-		${PYTHON_DEPS}
-		${DISTUTILS_DEPS}
-	)"
-
-PATCHES=(
-	"${FILESDIR}/file-5.39-portage-sandbox.patch" #713710 #728978
-	"${FILESDIR}/file-5.40-seccomp-fstatat64-musl.patch" #789336, not upstream yet
-)
-
-src_prepare() {
-	default
-
-	if [[ ${PV} == 9999 ]] ; then
-		eautoreconf
-	else
-		elibtoolize
-	fi
-
-	# don't let python README kill main README, bug ##60043
-	mv python/README.md python/README.python.md || die
-	# bug #662090
-	sed 's@README.md@README.python.md@' -i python/setup.py || die
-}
-
-multilib_src_configure() {
-	local myeconfargs=(
-		--enable-fsect-man5
-		$(use_enable bzip2 bzlib)
-		$(use_enable lzma xzlib)
-		$(use_enable seccomp libseccomp)
-		$(use_enable static-libs static)
-		$(use_enable zlib)
-	)
-	econf "${myeconfargs[@]}"
-}
-
-build_src_configure() {
-	local myeconfargs=(
-		--disable-shared
-		--disable-libseccomp
-		--disable-bzlib
-		--disable-xzlib
-		--disable-zlib
-	)
-
-	econf_build "${myeconfargs[@]}"
-}
-
-need_build_file() {
-	# when cross-compiling, we need to build up our own file
-	# because people often don't keep matching host/target
-	# file versions, bug #362941
-	tc-is-cross-compiler && ! has_version -b "~${CATEGORY}/${P}"
-}
-
-src_configure() {
-	local ECONF_SOURCE="${S}"
-
-	if need_build_file ; then
-		mkdir -p "${WORKDIR}"/build || die
-		cd "${WORKDIR}"/build || die
-		build_src_configure
-	fi
-
-	multilib-minimal_src_configure
-}
-
-multilib_src_compile() {
-	if multilib_is_native_abi ; then
-		emake
-	else
-		# bug #586444
-		emake -C src magic.h
-		emake -C src libmagic.la
-	fi
-}
-
-src_compile() {
-	if need_build_file ; then
-		# bug #586444
-		emake -C "${WORKDIR}"/build/src magic.h
-		emake -C "${WORKDIR}"/build/src file
-		local -x PATH="${WORKDIR}/build/src:${PATH}"
-	fi
-
-	multilib-minimal_src_compile
-
-	if use python ; then
-		cd python || die
-		distutils-r1_src_compile
-	fi
-}
-
-multilib_src_install() {
-	if multilib_is_native_abi ; then
-		default
-	else
-		emake -C src install-{nodist_includeHEADERS,libLTLIBRARIES} DESTDIR="${D}"
-	fi
-}
-
-multilib_src_install_all() {
-	dodoc ChangeLog MAINT # README
-
-	# Required for `file -C`
-	insinto /usr/share/misc/magic
-	doins -r magic/Magdir/*
-
-	if use python ; then
-		cd python || die
-		distutils-r1_src_install
-	fi
-
-	find "${ED}" -type f -name "*.la" -delete || die
-}