gentoo resync : 17.07.2021

3 files changed, 118 insertions, 12 deletions

diff --git a/sys-apps/firejail/Manifest b/sys-apps/firejail/Manifest
index 8ad17fba60b3..198bf00718af 100644
--- a/sys-apps/firejail/Manifest
+++ b/sys-apps/firejail/Manifest
@@ -1,4 +1,6 @@
 DIST firejail-0.9.64.4.tar.xz 431116 BLAKE2B 1e64af1459cdbd6e753299796b2521efdc1fe364a66b8f0f40df1adabec32d0673cb9805a2ab385b96b64aca16e038e615ab1e4dc4df1dbcaa0b5b24f54c89d0 SHA512 580a074cb40e7559f6d532418b5e05e042c30306e8507d32ac3c71a51dec6648035ad810d253da02caaa4adc41f773dfdab55528618f5ca30ff30d4e7bbd12c9
+DIST firejail-0.9.66.tar.xz 449992 BLAKE2B 43243e4d2773f007c9a7ce4e63b009b63113055baaffa5125d279124967f5c07d510edf431b568bbf5d6cf04501f5645accb5756af80298750d8f0ef35f9a88b SHA512 c00222f975df9832940b7e3ef71dc2d2bbab3540db259f8d3011fb6198f1b66d9191dff4609163a2cfe0e2a1f739e144b496260a457ea92601f163675735cbe7
 EBUILD firejail-0.9.64.4.ebuild 2514 BLAKE2B 5169243203fa8e77926aaccce08a9ad82277f8e9d272c99a87e885ab4a6bc251ec30b2c2e9f754ba35744f2933d0845a636ca15132c529a97f304a1be1828963 SHA512 da06a3199f3714b07bb99831d59e796b940d600334b9d8df8d4f2c887cdbd9205a9933e028353b41ae58afa3ecedd3f39c65c11ed01d2b344b4adb9cbc321082
-EBUILD firejail-9999.ebuild 2304 BLAKE2B 88ce4ea8d871af749c4f19ede13aa7d35b9037451b3e782b1a9558bf2a00274470b99d8e3d315f4a91af7084aabd5133562827e347852364ef0e0bbf07932f9e SHA512 c3c3c7d8e953630bb9f0765506780512e324ca8cf467a7a23568e2de3544c223bbe5e027b6fac32bb3be2716e64beb5084ca8959bd235b7638114e9e15be8814
+EBUILD firejail-0.9.66.ebuild 2627 BLAKE2B 33b429e1b4aa19a46242dae15fc02cbadc83acd170cfc143592e191c3fecee8fae48aa7a6ff4be3dcbea4c7fb5fc6a2552b6ef96380b4aa6277462905cce72b1 SHA512 ab36c185d9d890ff478334468d806d8c77fc5bea9fa834279e0721c42f2896331c20f5a7607604eee19f7c73053f346c8db25ee2a65fab530ecc606a37cd5813
+EBUILD firejail-9999.ebuild 2627 BLAKE2B 33b429e1b4aa19a46242dae15fc02cbadc83acd170cfc143592e191c3fecee8fae48aa7a6ff4be3dcbea4c7fb5fc6a2552b6ef96380b4aa6277462905cce72b1 SHA512 ab36c185d9d890ff478334468d806d8c77fc5bea9fa834279e0721c42f2896331c20f5a7607604eee19f7c73053f346c8db25ee2a65fab530ecc606a37cd5813
 MISC metadata.xml 1813 BLAKE2B 464550e81aed6c70688f7f146e0200fd351ae2a6163a41df836ece5e0dd54e0710ff3baefed509ac73ac81f37783acfe9baf3026f31ec4f668b2fb0f87e326d3 SHA512 23eee71dbf308db9f76cb42622442f9749b353577fb624bceb12c9e377fdcc0c45efe52c1c028d439835185502acf9822ffb53ee514ce5113710d036994ff6da
diff --git a/sys-apps/firejail/firejail-0.9.66.ebuild b/sys-apps/firejail/firejail-0.9.66.ebuild
new file mode 100644
index 000000000000..e3bf15c00bbd
--- /dev/null
+++ b/sys-apps/firejail/firejail-0.9.66.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9} )
+
+inherit toolchain-funcs python-single-r1 linux-info
+
+if [[ ${PV} != 9999 ]]; then
+	SRC_URI="https://github.com/netblue30/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+else
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/netblue30/firejail.git"
+	EGIT_BRANCH="master"
+fi
+
+DESCRIPTION="Security sandbox for any type of processes"
+HOMEPAGE="https://firejail.wordpress.com/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="apparmor +chroot contrib +dbusproxy +file-transfer +globalcfg +network +private-home +suid test +userns +whitelist X"
+# Needs a lot of work to function within sandbox/portage
+# bug #769731
+RESTRICT="test"
+
+RDEPEND="!sys-apps/firejail-lts
+	apparmor? ( sys-libs/libapparmor )
+	contrib? ( ${PYTHON_DEPS} )
+	dbusproxy? ( sys-apps/xdg-dbus-proxy )"
+
+DEPEND="${RDEPEND}
+	sys-libs/libseccomp
+	test? ( dev-tcltk/expect )"
+
+REQUIRED_USE="contrib? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	CONFIG_CHECK="~SQUASHFS"
+	local ERROR_SQUASHFS="CONFIG_SQUASHFS: required for firejail --appimage mode"
+	check_extra_config
+	use contrib && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	find -type f -name Makefile.in -exec sed -i -r -e '/CFLAGS/s: (-O2|-ggdb) : :g' {} + || die
+
+	sed -i -r -e '/CFLAGS/s: (-O2|-ggdb) : :g' ./src/common.mk.in || die
+
+	# fix up hardcoded paths to templates and docs
+	local files=$(grep -E -l -r '/usr/share/doc/firejail([^-]|$)' ./RELNOTES ./src/man/ ./etc/profile*/ ./test/ || die)
+	for file in ${files[@]} ; do
+		sed -i -r -e "s:/usr/share/doc/firejail([^-]|\$):/usr/share/doc/${PF}\1:" "${file}" || die
+	done
+
+	# remove compression of man pages
+	sed -i -r -e '/rm -f \$\$man.gz; \\/d; /gzip -9n \$\$man; \\/d; s|\*\.([[:digit:]])\) install -m 0644 \$\$man\.gz|\*\.\1\) install -m 0644 \$\$man|g' Makefile.in || die
+
+	if use contrib; then
+		python_fix_shebang -f contrib/*.py
+	fi
+}
+
+src_configure() {
+	econf \
+		--disable-firetunnel \
+		$(use_enable apparmor) \
+		$(use_enable chroot) \
+		$(use_enable dbusproxy) \
+		$(use_enable file-transfer) \
+		$(use_enable globalcfg) \
+		$(use_enable network) \
+		$(use_enable private-home) \
+		$(use_enable suid) \
+		$(use_enable userns) \
+		$(use_enable whitelist) \
+		$(use_enable X x11)
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	default
+
+	rm "${ED}"/usr/share/doc/${PF}/COPYING || die
+
+	if use contrib; then
+		python_scriptinto /usr/$(get_libdir)/firejail
+		python_doscript contrib/*.py
+		insinto /usr/$(get_libdir)/firejail
+		dobin contrib/*.sh
+	fi
+}
diff --git a/sys-apps/firejail/firejail-9999.ebuild b/sys-apps/firejail/firejail-9999.ebuild
index bcd7e7b29268..e3bf15c00bbd 100644
--- a/sys-apps/firejail/firejail-9999.ebuild
+++ b/sys-apps/firejail/firejail-9999.ebuild
@@ -3,13 +3,13 @@
 
 EAPI=7
 
-PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_COMPAT=( python3_{8,9} )
 
 inherit toolchain-funcs python-single-r1 linux-info
 
 if [[ ${PV} != 9999 ]]; then
-	KEYWORDS="~amd64 ~x86"
 	SRC_URI="https://github.com/netblue30/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~x86"
 else
 	inherit git-r3
 	EGIT_REPO_URI="https://github.com/netblue30/firejail.git"
@@ -21,7 +21,7 @@ HOMEPAGE="https://firejail.wordpress.com/"
 
 LICENSE="GPL-2"
 SLOT="0"
-IUSE="X apparmor +chroot contrib +dbusproxy +file-transfer +globalcfg +network +private-home +suid test +userns +whitelist"
+IUSE="apparmor +chroot contrib +dbusproxy +file-transfer +globalcfg +network +private-home +suid test +userns +whitelist X"
 # Needs a lot of work to function within sandbox/portage
 # bug #769731
 RESTRICT="test"
@@ -38,16 +38,25 @@ DEPEND="${RDEPEND}
 REQUIRED_USE="contrib? ( ${PYTHON_REQUIRED_USE} )"
 
 pkg_setup() {
-	python-single-r1_pkg_setup
+	CONFIG_CHECK="~SQUASHFS"
+	local ERROR_SQUASHFS="CONFIG_SQUASHFS: required for firejail --appimage mode"
+	check_extra_config
+	use contrib && python-single-r1_pkg_setup
 }
 
 src_prepare() {
 	default
 
-	find -type f -name Makefile.in -exec sed -i -r -e '/^\tinstall .*COPYING /d; /CFLAGS/s: (-O2|-ggdb) : :g' {} + || die
+	find -type f -name Makefile.in -exec sed -i -r -e '/CFLAGS/s: (-O2|-ggdb) : :g' {} + || die
 
 	sed -i -r -e '/CFLAGS/s: (-O2|-ggdb) : :g' ./src/common.mk.in || die
 
+	# fix up hardcoded paths to templates and docs
+	local files=$(grep -E -l -r '/usr/share/doc/firejail([^-]|$)' ./RELNOTES ./src/man/ ./etc/profile*/ ./test/ || die)
+	for file in ${files[@]} ; do
+		sed -i -r -e "s:/usr/share/doc/firejail([^-]|\$):/usr/share/doc/${PF}\1:" "${file}" || die
+	done
+
 	# remove compression of man pages
 	sed -i -r -e '/rm -f \$\$man.gz; \\/d; /gzip -9n \$\$man; \\/d; s|\*\.([[:digit:]])\) install -m 0644 \$\$man\.gz|\*\.\1\) install -m 0644 \$\$man|g' Makefile.in || die
 
@@ -79,6 +88,8 @@ src_compile() {
 src_install() {
 	default
 
+	rm "${ED}"/usr/share/doc/${PF}/COPYING || die
+
 	if use contrib; then
 		python_scriptinto /usr/$(get_libdir)/firejail
 		python_doscript contrib/*.py
@@ -86,9 +97,3 @@ src_install() {
 		dobin contrib/*.sh
 	fi
 }
-
-pkg_postinst() {
-	CONFIG_CHECK="~SQUASHFS"
-	local ERROR_SQUASHFS="CONFIG_SQUASHFS: required for firejail --appimage mode"
-	check_extra_config
-}