gentoo auto-resync : 19:09:2024 - 12:11:50

3 files changed, 221 insertions, 2 deletions

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index 5c8a34788044..3c149ab0541e 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -2,6 +2,8 @@ AUX fwupd-1.9.6-fragile_tests.patch 1051 BLAKE2B 01ae6cae17b911d055eb820a041329e
 AUX fwupd-r2 308 BLAKE2B 4494e69515347569965f0966ce2fe0779a6273df18412b4f6045c6186730dc8088f85eb029347b01c22897662d9205f98871752dee99690871a39cbb26db3899 SHA512 0f5070dc73cb6e0cfad7a66781afb85c695faffd05685e9df8c9798b94d55b31c0977134015d0d5418f5815d10529d79c898ae0efb2bdf0dc9ee44b696d5fdd7
 DIST fwupd-1.9.20.tar.xz 4290676 BLAKE2B da9c47df676fc6da059e6a2df60891ff3d9141280ee3be58079c7e07ea785e3129aa5140520dcb87cbd8df7833bc43c201217fac54099133cbab0143fc5dfae8 SHA512 3854421b99e4f6869f840bdf601d3fb61a60ef2875f829858809631f22d24060184c424ef7406ff7ede50ad7a2bcd8b93793244c84d88d2269776f0c26846ee9
 DIST fwupd-1.9.23.tar.xz 4300104 BLAKE2B d084244f99b5edccf4bf6a783846623876e9b4344c05bfe3cd412235bcde63d1f36db5528572e371fd0bde27f72c2bd61ba7b6472504ade4c9a068a00e34ca4e SHA512 379adcc79d40795f4895749bc944689ffee6fadc7c3dd1974df98c15120ca47d020ad4efabc68d0371cb36ebd3b549698c05a81bee0a673745a867bb32c4eeb5
+DIST fwupd-1.9.24.tar.xz 4305048 BLAKE2B 5ac7bbc5cdcee13a39fe25cd5b83dfbb9615e6349cd39e8b25cc654c0318870de603c1f6ce550da6662d3f9cd7d275cf6254058f6b71dcb9f7916329147ab771 SHA512 2f9935bbfc3ffc49bf0939a75dd52861eea9108d8f7026dbcdf4c07ad234f70f0b1cb6740eefe555dc2a49aba1ea4d65a78427aad7a0ba9de1fe318734255bfe
 EBUILD fwupd-1.9.20.ebuild 5381 BLAKE2B 38ada083d022ac68cdaa9c40b04ed6c649f78eebab0253d65ad5e03a1793d06447a3c01ed83a71bb996ecffbceb9c5102ef84a05c1d55d147e135f2aa5ab042f SHA512 72f48d900e3bfadd4b81fd68abf172647c17bf206dba8e8afbd92fc78807793039d9af1c28935522ad2ef85f3b7f18ff5861d6365f37cd57274be6372eff3e6e
 EBUILD fwupd-1.9.23.ebuild 5384 BLAKE2B e73525af331457608a02543c2d55b146720317a8b05382f664f55b7be727f4ab1bf33f49cbb2e594ec7353a96337d30de778dab27d7380c0595ccd5ce2c9b2ed SHA512 b9a746d5e8a419b691dcb9c8d7b5b750dc1c9fd43720662b77ce74920f143f20a904896cdbcde6b57775a8afbda918199ebdbec60d86f7a8fa16b3540ad97049
-MISC metadata.xml 1443 BLAKE2B 1bb0d5f92e73766f016cdc6cdd59a2a91204ca4d2097f2a4e3e03a4f3d16ef084cb260bc144aa388403c1b2cdda4c6638c178117d7ac2e158494bac3322678d3 SHA512 53c7739542ae4c03913bbdaa6e4b4a5c04b53b1eb8e16dd1e4b0036c4af9c019205c57b06a6a41e1ad4fb4be361ebaf0c15eba7f949f56f428d982cb4e3170a0
+EBUILD fwupd-1.9.24.ebuild 5384 BLAKE2B 7b53c04b0ef8ed45490ed0053169827e4eb901f285ea641448ac34ce995744108485e4eda15277abc8fef28d2284881675a07b704c618e6f2774bbc9d2121270 SHA512 1432bdaa43f7835f55295853bf5165a301a1d8b1b284d4cc7686649e2b63e2ca68de41f58ae70c8f5259cc404177bd4f2fc34fc54a37fc990f1d7b3cd30c6f14
+MISC metadata.xml 1674 BLAKE2B b451d794c2be5515f1f5889a88e5c512ab5e8c62f53105b68374cd07007f0032fdb5f99bf2c0c403f4f6ac558fc3fc4513a06cb1acb06dbd321e1e4814c220bf SHA512 e176cca39887ad3eaccf7699c8d8fb8bb76587bec0e797f1952ce8d83bd259e43334870232f9660fe29cf177a2abaa1ca8e8e5527e88ade43e6a7a022510c025
diff --git a/sys-apps/fwupd/fwupd-1.9.24.ebuild b/sys-apps/fwupd/fwupd-1.9.24.ebuild
new file mode 100644
index 000000000000..27af56f8a6be
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.9.24.ebuild
@@ -0,0 +1,210 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson python-single-r1 vala udev xdg
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="amdgpu amt +archive bash-completion bluetooth cbor elogind fastboot flashrom gnutls gtk-doc +gusb introspection logitech lzma minimal modemmanager nvme policykit spi +sqlite synaptics systemd test test-full tpm uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( elogind minimal systemd )
+	fastboot? ( gusb )
+	logitech? ( gusb )
+	minimal? ( !introspection )
+	modemmanager? ( gusb )
+	spi? ( lzma )
+	synaptics? ( gnutls )
+	test? ( archive gusb )
+	test-full? ( test )
+	uefi? ( gnutls )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	$(python_gen_cond_dep '
+		dev-python/jinja[${PYTHON_USEDEP}]
+	')
+	>=dev-build/meson-0.60.0
+	virtual/pkgconfig
+	gtk-doc? (
+		$(python_gen_cond_dep '
+			>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+		')
+		>=dev-util/gi-docgen-2021.1
+	)
+	bash-completion? ( >=app-shells/bash-completion-2.0 )
+	introspection? ( dev-libs/gobject-introspection )
+	test? (
+		net-libs/gnutls[tools]
+		test-full? ( dev-util/umockdev )
+	)
+"
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	app-arch/xz-utils
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/json-glib-1.6.0
+	>=dev-libs/libgudev-232:=
+	>=dev-libs/libjcat-0.1.4[gpg,pkcs7]
+	>=dev-libs/libxmlb-0.3.6:=[introspection?]
+	$(python_gen_cond_dep '
+		dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	')
+	>=net-misc/curl-7.62.0
+	archive? ( app-arch/libarchive:= )
+	cbor? ( >=dev-libs/libcbor-0.7.0:= )
+	elogind? ( >=sys-auth/elogind-211 )
+	flashrom? ( >=sys-apps/flashrom-1.2-r3 )
+	gnutls? ( >=net-libs/gnutls-3.6.0 )
+	gusb? ( >=dev-libs/libgusb-0.3.8[introspection?] )
+	logitech? ( dev-libs/protobuf-c:= )
+	lzma? ( app-arch/xz-utils )
+	modemmanager? ( net-misc/modemmanager[mbim,qmi] )
+	policykit? ( >=sys-auth/polkit-0.114 )
+	sqlite? ( dev-db/sqlite )
+	systemd? ( >=sys-apps/systemd-211 )
+	tpm? ( app-crypt/tpm2-tss:= )
+	uefi? (
+		sys-apps/fwupd-efi
+		sys-boot/efibootmgr
+		sys-fs/udisks
+		sys-libs/efivar
+	)
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	sys-apps/dbus
+"
+
+DEPEND="
+	${COMMON_DEPEND}
+	x11-libs/pango[introspection]
+	amdgpu? (
+		sys-kernel/linux-headers
+		x11-libs/libdrm[video_cards_amdgpu]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.9.6-fragile_tests.patch
+)
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != buildonly ]]; then
+		if use test-full && has sandbox ${FEATURES}; then
+			ewarn "Certain ${PN} tests are fragile with sandboxing enabled,"
+			ewarn "see https://github.com/fwupd/fwupd/issues/1414."
+			ewarn "When in doubt, emerge ${PN} with USE=-test-full."
+		fi
+	fi
+}
+
+src_prepare() {
+	default
+
+	vala_setup
+
+	sed -e "/install_dir.*'doc'/s/doc/gtk-doc/" \
+		-i docs/meson.build || die
+
+	python_fix_shebang "${S}"/contrib/*.py
+}
+
+src_configure() {
+	local plugins=(
+		-Dplugin_gpio="enabled"
+		$(meson_feature amdgpu plugin_amdgpu)
+		$(meson_feature amt plugin_intel_me)
+		$(meson_feature fastboot plugin_fastboot)
+		$(meson_feature flashrom plugin_flashrom)
+		$(meson_feature gusb plugin_uf2)
+		$(meson_feature logitech plugin_logitech_bulkcontroller)
+		$(meson_feature modemmanager plugin_modem_manager)
+		$(meson_feature nvme plugin_nvme)
+		$(meson_use spi plugin_intel_spi)
+		$(meson_feature synaptics plugin_synaptics_mst)
+		$(meson_feature synaptics plugin_synaptics_rmi)
+		$(meson_feature tpm plugin_tpm)
+		$(meson_feature uefi plugin_uefi_capsule)
+		$(meson_use uefi plugin_uefi_capsule_splash)
+		$(meson_feature uefi plugin_uefi_pk)
+	)
+	if use ppc64 || use riscv ; then
+		plugins+=( -Dplugin_msr="disabled" )
+	fi
+
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		-Dbuild="$(usex minimal standalone all)"
+		-Dconsolekit="disabled"
+		-Dcurl="enabled"
+		-Defi_binary="false"
+		-Dman="true"
+		-Dsupported_build="enabled"
+		-Dsystemd_unit_user=""
+		-Dudevdir="${EPREFIX}$(get_udevdir)"
+		$(meson_feature archive libarchive)
+		$(meson_use bash-completion bash_completion)
+		$(meson_feature bluetooth bluez)
+		$(meson_feature cbor)
+		$(meson_feature elogind)
+		$(meson_feature gnutls)
+		$(meson_feature gtk-doc docs)
+		$(meson_feature gusb)
+		$(meson_feature lzma)
+		$(meson_feature introspection)
+		$(meson_feature policykit polkit)
+		$(meson_feature sqlite)
+		$(meson_feature systemd)
+		$(meson_use test tests)
+		$(meson_use test-full)
+
+		${plugins[@]}
+	)
+	use uefi && emesonargs+=( -Defi_os_dir="gentoo" )
+	export CACHE_DIRECTORY="${T}"
+	meson_src_configure
+}
+
+src_test() {
+	LC_ALL="C" meson_src_test
+}
+
+src_install() {
+	meson_src_install
+
+	if ! use minimal ; then
+		newinitd "${FILESDIR}"/${PN}-r2 ${PN}
+	fi
+
+	if use test; then
+		# Preventing tests from being installed in the first place is a moving target,
+		# just axe them all afterwards.
+		rm -rf \
+			"${ED}"/usr/libexec/installed-tests \
+			"${ED}"/usr/share/fwupd/device-tests \
+			"${ED}"/usr/share/fwupd/host-emulate.d/thinkpad-p1-iommu.json.gz \
+			"${ED}"/usr/share/fwupd/remotes.d/fwupd-tests.conf \
+			"${ED}"/usr/share/installed-tests \
+		|| die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	use minimal || udev_reload
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	use minimal || udev_reload
+}
diff --git a/sys-apps/fwupd/metadata.xml b/sys-apps/fwupd/metadata.xml
index b19370c03702..f6aae5585891 100644
--- a/sys-apps/fwupd/metadata.xml
+++ b/sys-apps/fwupd/metadata.xml
@@ -1,7 +1,14 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-	<!-- maintainer-needed -->
+	<maintainer type="person" proxied="yes">
+		<email>johnmh@johnmh.me</email>
+		<name>John M. Harris, Jr.</name>
+	</maintainer>
+	<maintainer type="project" proxied="proxy">
+		<email>proxy-maint@gentoo.org</email>
+		<name>Proxy Maintainers</name>
+	</maintainer>
 	<use>
 		<flag name="archive">Use <pkg>app-arch/libarchive</pkg> for archives support</flag>
 		<flag name="amdgpu">Build and install AMD dGPU (Navi3x and above) plugin</flag>