gentoo resync : 10.01.2018

4 files changed, 207 insertions, 12 deletions

diff --git a/sys-apps/kmod/Manifest b/sys-apps/kmod/Manifest
index 8c938c2135ea..005741c11d8f 100644
--- a/sys-apps/kmod/Manifest
+++ b/sys-apps/kmod/Manifest
@@ -1,7 +1,9 @@
 AUX kmod-static-nodes-r1 500 BLAKE2B 44ae03377e6cc7b5a271063828fcb39ec6925d82e52207771e1b6b4f921d0a07e51e97a8e6f432b542d88fb0195e1298cd54ba92d462a828ddd94dab7f924eb3 SHA512 8210d90f5d0702aea626b6db00adbabbd550009d8275fe430c8b113fcb0593a4dfb9efb22c061dde259e1bd94390be49823415d3fd99909e22a2bbf7ae349f63
 DIST kmod-23.tar.xz 450376 BLAKE2B dd38b6d8853e40cb8c9939cd3c68bfe3b36e58445cac994dbdcc92790c5a2bc40eb9bef0d4188b7ea113665d297ec4fc089f8ea77ab87971c598ff6b4a17ce85 SHA512 84b18d35117b33c48fd9b732a584a9f94caef553e371bd4e68953540f46fc6c7145c8c7163df898875437ad56e1a47e89be26531314299bce0026c46da9dd3c0
 DIST kmod-24.tar.xz 536864 BLAKE2B 2d61a4a5e598c864cc1bae4f3d2dc5e434e1df8685ceb2462315c0e5dc955b58f02ffd0504a77859b7030c3619f1b5f6a7fa3fb25ec99d90ac67f0167b1eb889 SHA512 58c8da100418b6325de1595bceee4115cbdd7151d03a028c0b1f6d5d3e6611c667e27f3a0245d29781125581849fd1e854fa8d87b63c4b8fa3f196d0a97e1779
+DIST kmod-25.tar.xz 545416 BLAKE2B 2ad428f70630a1ef509be888a9ebc45f164695365f0f722f5e7793e96b60c035040b4d9a27f926361cea6d665310fc6cc5599ff4aefeda0fae8571c6510a25a7 SHA512 d579cd0cea24a06362a74927b7a3c777e9e01c990306e1032e4781cd441ffe435c70f2c2c4f6ae39eb1d857e622746411d5824d0c0d8bb79f91dc9fa51956252
 EBUILD kmod-23.ebuild 4902 BLAKE2B 22ef9ed75e115712545c6923ba982d5e1a271b4a61576760a2af471885a32727d70c5e44542d68b545e333440e417052c16f069b50efe92c54b3d480ae1e09ae SHA512 b38be77d4f89ffda2551a3c5ef2b85146ba27254d0c109425b7ad0fbfdc1528381f605a1e354a06f3321eb5b63bba6d6ec955245135f54a3a2a5d131667360e5
-EBUILD kmod-24.ebuild 4919 BLAKE2B 3f3c0239e529fc1a0c8f52f82982ff4f38eb968ba5227b4640f4fa8ded8d9b8e0599a9adf04a21d8817b9557ac20a30eb3b8e202cab8262ac584dd0f39baffd3 SHA512 635dbf84a67d2a45c7fdee994ab906cc015dbec731b31f73d1f4af8a1d5fb823cb6494e9f2f0c1ea695cd69d802a4aa304c587c4022d094e642cdbd52c8fc1c4
-EBUILD kmod-9999.ebuild 4919 BLAKE2B 3f3c0239e529fc1a0c8f52f82982ff4f38eb968ba5227b4640f4fa8ded8d9b8e0599a9adf04a21d8817b9557ac20a30eb3b8e202cab8262ac584dd0f39baffd3 SHA512 635dbf84a67d2a45c7fdee994ab906cc015dbec731b31f73d1f4af8a1d5fb823cb6494e9f2f0c1ea695cd69d802a4aa304c587c4022d094e642cdbd52c8fc1c4
+EBUILD kmod-24.ebuild 4917 BLAKE2B 948c3e51bd2fbb7270dda317ea6baecf40e736082a9af262a3afe86684348f689349ca3d81930a454980077466cd0250dbe534196cbf8261d25f9add57e23008 SHA512 c8715b0176a7c02da837e6ee113f576b115febe9f5b93636bc5438b2c11d4a005bda1569fb414a50cc4fa115bd5e32bb66615cd75a2af4712f73c3fa49a993f7
+EBUILD kmod-25.ebuild 4931 BLAKE2B 99cf8a56f86668414041e08c2d07664d55696d70bdf7c6230a9e5fa0dcf0080aac13308c13c201ba4687fd66cff78f130192ce07cf6f8fa5a2033d57c5199027 SHA512 27aa9d2c5e85af98778df261cda4e5aae65a6490f2f28b72dd9475e22eb0b75a5ad1bd4207462b21c60a04265cab91027d628a0dee12d8444fa450318514e6d6
+EBUILD kmod-9999.ebuild 4931 BLAKE2B 99cf8a56f86668414041e08c2d07664d55696d70bdf7c6230a9e5fa0dcf0080aac13308c13c201ba4687fd66cff78f130192ce07cf6f8fa5a2033d57c5199027 SHA512 27aa9d2c5e85af98778df261cda4e5aae65a6490f2f28b72dd9475e22eb0b75a5ad1bd4207462b21c60a04265cab91027d628a0dee12d8444fa450318514e6d6
 MISC metadata.xml 540 BLAKE2B ec5ee262fe76215688d99e32778848e71de5825f488eea2219e076290e020aa86de6138ab8366d5e077d44797789a27c22fea1c64f9c6e2713cf315b4b891455 SHA512 c4f47a77dfa7bc4cbaa61744fc46c5547763b51b48521cd229ac89680325ecbf415bd9e1ce9c71982ea721d0d5c4cf3677a0f70e8dad65235f523840cd14de94
diff --git a/sys-apps/kmod/kmod-24.ebuild b/sys-apps/kmod/kmod-24.ebuild
index 3a82094b0518..77b0a8b5ccdf 100644
--- a/sys-apps/kmod/kmod-24.ebuild
+++ b/sys-apps/kmod/kmod-24.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=5
@@ -12,7 +12,7 @@ if [[ ${PV} == 9999* ]]; then
 	inherit autotools git-2
 else
 	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
-	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh sparc ~x86"
 	inherit libtool
 fi
 
diff --git a/sys-apps/kmod/kmod-25.ebuild b/sys-apps/kmod/kmod-25.ebuild
new file mode 100644
index 000000000000..1ffba7ee85cc
--- /dev/null
+++ b/sys-apps/kmod/kmod-25.ebuild
@@ -0,0 +1,191 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit bash-completion-r1 ltprune multilib python-r1
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
+	inherit autotools git-r3
+else
+	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+	inherit libtool
+fi
+
+DESCRIPTION="library and tools for managing linux kernel modules"
+HOMEPAGE="https://git.kernel.org/?p=utils/kernel/kmod/kmod.git"
+
+LICENSE="LGPL-2"
+SLOT="0"
+IUSE="debug doc lzma python static-libs +tools zlib"
+
+# Upstream does not support running the test suite with custom configure flags.
+# I was also told that the test suite is intended for kmod developers.
+# So we have to restrict it.
+# See bug #408915.
+RESTRICT="test"
+
+# Block systemd below 217 for -static-nodes-indicate-that-creation-of-static-nodes-.patch
+RDEPEND="!sys-apps/module-init-tools
+	!sys-apps/modutils
+	!<sys-apps/openrc-0.13.8
+	!<sys-apps/systemd-216-r3
+	lzma? ( >=app-arch/xz-utils-5.0.4-r1 )
+	python? ( ${PYTHON_DEPS} )
+	zlib? ( >=sys-libs/zlib-1.2.6 )" #427130
+DEPEND="${RDEPEND}
+	doc? ( dev-util/gtk-doc )
+	lzma? ( virtual/pkgconfig )
+	python? (
+		dev-python/cython[${PYTHON_USEDEP}]
+		virtual/pkgconfig
+		)
+	zlib? ( virtual/pkgconfig )"
+if [[ ${PV} == 9999* ]]; then
+	DEPEND="${DEPEND}
+		dev-libs/libxslt"
+fi
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+DOCS="NEWS README TODO"
+
+src_prepare() {
+	default
+
+	if [ ! -e configure ]; then
+		if use doc; then
+			gtkdocize --copy --docdir libkmod/docs || die
+		else
+			touch libkmod/docs/gtk-doc.make
+		fi
+		eautoreconf
+	else
+		elibtoolize
+	fi
+
+	# Restore possibility of running --enable-static wrt #472608
+	sed -i \
+		-e '/--enable-static is not supported by kmod/s:as_fn_error:echo:' \
+		configure || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}/bin"
+		--enable-shared
+		--with-bashcompletiondir="$(get_bashcompdir)"
+		--with-rootlibdir="${EPREFIX}/$(get_libdir)"
+		$(use_enable debug)
+		$(use_enable doc gtk-doc)
+		$(use_enable static-libs static)
+		$(use_enable tools)
+		$(use_with lzma xz)
+		$(use_with zlib)
+	)
+
+	local ECONF_SOURCE="${S}"
+
+	kmod_configure() {
+		mkdir -p "${BUILD_DIR}" || die
+		run_in_build_dir econf "${myeconfargs[@]}" "$@"
+	}
+
+	BUILD_DIR="${WORKDIR}/build"
+	kmod_configure --disable-python
+
+	if use python; then
+		python_foreach_impl kmod_configure --enable-python
+	fi
+}
+
+src_compile() {
+	emake -C "${BUILD_DIR}"
+
+	if use python; then
+		local native_builddir=${BUILD_DIR}
+
+		python_compile() {
+			emake -C "${BUILD_DIR}" -f Makefile -f - python \
+				VPATH="${native_builddir}:${S}" \
+				native_builddir="${native_builddir}" \
+				libkmod_python_kmod_{kmod,list,module,_util}_la_LIBADD='$(PYTHON_LIBS) $(native_builddir)/libkmod/libkmod.la' \
+				<<< 'python: $(pkgpyexec_LTLIBRARIES)'
+		}
+
+		python_foreach_impl python_compile
+	fi
+}
+
+src_install() {
+	emake -C "${BUILD_DIR}" DESTDIR="${D}" install
+	einstalldocs
+
+	if use python; then
+		local native_builddir=${BUILD_DIR}
+
+		python_install() {
+			emake -C "${BUILD_DIR}" DESTDIR="${D}" \
+				VPATH="${native_builddir}:${S}" \
+				install-pkgpyexecLTLIBRARIES \
+				install-dist_pkgpyexecPYTHON
+		}
+
+		python_foreach_impl python_install
+	fi
+
+	prune_libtool_files --modules
+
+	if use tools; then
+		local bincmd sbincmd
+		for sbincmd in depmod insmod lsmod modinfo modprobe rmmod; do
+			dosym ../bin/kmod /sbin/${sbincmd}
+		done
+
+		# These are also usable as normal user
+		for bincmd in lsmod modinfo; do
+			dosym kmod /bin/${bincmd}
+		done
+	fi
+
+	cat <<-EOF > "${T}"/usb-load-ehci-first.conf
+	softdep uhci_hcd pre: ehci_hcd
+	softdep ohci_hcd pre: ehci_hcd
+	EOF
+
+	insinto /lib/modprobe.d
+	doins "${T}"/usb-load-ehci-first.conf #260139
+
+	newinitd "${FILESDIR}"/kmod-static-nodes-r1 kmod-static-nodes
+}
+
+pkg_postinst() {
+	if [[ -L ${EROOT%/}/etc/runlevels/boot/static-nodes ]]; then
+		ewarn "Removing old conflicting static-nodes init script from the boot runlevel"
+		rm -f "${EROOT%/}"/etc/runlevels/boot/static-nodes
+	fi
+
+	# Add kmod to the runlevel automatically if this is the first install of this package.
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		if [[ ! -d ${EROOT%/}/etc/runlevels/sysinit ]]; then
+			mkdir -p "${EROOT%/}"/etc/runlevels/sysinit
+		fi
+		if [[ -x ${EROOT%/}/etc/init.d/kmod-static-nodes ]]; then
+			ln -s /etc/init.d/kmod-static-nodes "${EROOT%/}"/etc/runlevels/sysinit/kmod-static-nodes
+		fi
+	fi
+
+	if [[ -e ${EROOT%/}/etc/runlevels/sysinit ]]; then
+		if [[ ! -e ${EROOT%/}/etc/runlevels/sysinit/kmod-static-nodes ]]; then
+			ewarn
+			ewarn "You need to add kmod-static-nodes to the sysinit runlevel for"
+			ewarn "kernel modules to have required static nodes!"
+			ewarn "Run this command:"
+			ewarn "\trc-update add kmod-static-nodes sysinit"
+		fi
+	fi
+}
diff --git a/sys-apps/kmod/kmod-9999.ebuild b/sys-apps/kmod/kmod-9999.ebuild
index 3a82094b0518..1ffba7ee85cc 100644
--- a/sys-apps/kmod/kmod-9999.ebuild
+++ b/sys-apps/kmod/kmod-9999.ebuild
@@ -1,15 +1,15 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=6
 
 PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
 
-inherit bash-completion-r1 eutils multilib python-r1
+inherit bash-completion-r1 ltprune multilib python-r1
 
 if [[ ${PV} == 9999* ]]; then
 	EGIT_REPO_URI="git://git.kernel.org/pub/scm/utils/kernel/${PN}/${PN}.git"
-	inherit autotools git-2
+	inherit autotools git-r3
 else
 	SRC_URI="mirror://kernel/linux/utils/kernel/kmod/${P}.tar.xz"
 	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
@@ -55,6 +55,8 @@ REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 DOCS="NEWS README TODO"
 
 src_prepare() {
+	default
+
 	if [ ! -e configure ]; then
 		if use doc; then
 			gtkdocize --copy --docdir libkmod/docs || die
@@ -75,15 +77,15 @@ src_prepare() {
 src_configure() {
 	local myeconfargs=(
 		--bindir="${EPREFIX}/bin"
-		--with-rootlibdir="${EPREFIX}/$(get_libdir)"
 		--enable-shared
-		$(use_enable static-libs static)
-		$(use_enable tools)
+		--with-bashcompletiondir="$(get_bashcompdir)"
+		--with-rootlibdir="${EPREFIX}/$(get_libdir)"
 		$(use_enable debug)
 		$(use_enable doc gtk-doc)
+		$(use_enable static-libs static)
+		$(use_enable tools)
 		$(use_with lzma xz)
 		$(use_with zlib)
-		--with-bashcompletiondir="$(get_bashcompdir)"
 	)
 
 	local ECONF_SOURCE="${S}"