gentoo resync : 31.12.2018

1 files changed, 57 insertions, 0 deletions

diff --git a/sys-apps/nawk/nawk-20180827.ebuild b/sys-apps/nawk/nawk-20180827.ebuild
new file mode 100644
index 000000000000..0a5c7119b754
--- /dev/null
+++ b/sys-apps/nawk/nawk-20180827.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Brian Kernighan's pattern scanning and processing language"
+HOMEPAGE="https://www.cs.princeton.edu/~bwk/btl.mirror/"
+SRC_URI="https://github.com/onetrueawk/awk/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-macos"
+
+RDEPEND="
+	app-eselect/eselect-awk
+	!sys-freebsd/freebsd-ubin"
+
+DEPEND="
+	${RDEPEND}
+	virtual/yacc"
+
+S="${WORKDIR}/awk-${PV}"
+
+PATCHES=( "${FILESDIR}/${P}"-parallel-build.patch )
+
+DOCS=( README FIXES )
+
+src_compile() {
+	emake \
+		CC="$(tc-getCC)" \
+		CFLAGS="${CFLAGS}" \
+		CPPFLAGS=-DHAS_ISBLANK \
+		ALLOC="${LDFLAGS}" \
+		YACC=$(type -p yacc) \
+		YFLAGS="-d"
+}
+
+src_install() {
+	newbin a.out "${PN}"
+	sed \
+		-e 's/awk/nawk/g' \
+		-e 's/AWK/NAWK/g' \
+		-e 's/Awk/Nawk/g' \
+		awk.1 > "${PN}".1 || die "manpage patch failed"
+	doman "${PN}.1"
+	einstalldocs
+}
+
+pkg_postinst() {
+	eselect awk update ifunset
+}
+
+pkg_postrm() {
+	eselect awk update ifunset
+}