gentoo auto-resync : 22:11:2022 - 01:05:27

3 files changed, 108 insertions, 0 deletions

diff --git a/sys-apps/Manifest.gz b/sys-apps/Manifest.gz
index cea4bad0eb38..8fd2391aa41f 100644
--- a/sys-apps/Manifest.gz
+++ b/sys-apps/Manifest.gz
diff --git a/sys-apps/flatpak/Manifest b/sys-apps/flatpak/Manifest
index 468559ad178a..f3ec4d4f4c29 100644
--- a/sys-apps/flatpak/Manifest
+++ b/sys-apps/flatpak/Manifest
@@ -1,5 +1,7 @@
 DIST flatpak-1.12.3.tar.xz 1555340 BLAKE2B 512b3f6abfb06d242aedad2c27c9870750254a9d0a3769999739f8885bbf1740b649e2a41f2c079532b049fcce8b58529572ea35e930437ed6b62194a73bcbb6 SHA512 2f39665457b4c3b99e32ebc88cf5b70202dba6118887617d3d7faa20f688f3f3fc14e343b70c0d11eb15ee743a68d07078e6cda14fd91aa10ca375797cfc95bc
 DIST flatpak-1.14.0.tar.xz 1636864 BLAKE2B f7f211480577eb5bd422c49790ebfb84da5e5a03cc6dee3815af786bfcd347bd7b01e853c027a42a1510fba68d667c4a25f6b9f998753466baae61a765c73864 SHA512 88f011534a8da6c2421d7d24043756bfe6c46957b6d09ba96b269002a5f0d0372b51f4a8643af2020ef4ed8c5b5f102994ddab54a7052cfba15f8e3b160e8a83
+DIST flatpak-1.14.1.tar.xz 1626500 BLAKE2B bf33dcd5a0f0289e5bff32794012dcfc45dcdbb11ef0da5c68769c18b1bcd12fcc0308ea275a7532f59998db6afa019746313387b0f9636c7d9b91ceb7d66665 SHA512 1f22622b9a797b644b5fe9d26c3c4ec3f6b1a3b81a12d498e5aeeecb1a965c9aaa5c1d18843c938f116855bbbed3a8d9866997440f86241abe70eae13be7cdcb
 EBUILD flatpak-1.12.3-r1.ebuild 2404 BLAKE2B ec7e7b7f9fea4af149f10f3aac81e0b4649c92c985e1953034fa8c1fc4dbb9259c30946e07320580f57ba9698f8a120cb51bfb8979ab021afff6a6dfb4d264f6 SHA512 0e0ad59daff87d9c4ef730f1ebd79bbea917a0a2bf1b6c97c859b9acf7438ab4130829c8d84483a0aaba2f33b22328dc50bf3a0f7166483228d40da5c88c0c8f
 EBUILD flatpak-1.14.0-r1.ebuild 2538 BLAKE2B 9a29e556126e44d18135e66d6d72b4ee2db2208e87dae9afcf4d3a44501b3bdb497f5ffc10ee69f8d2315433f775ab0580147516936678fbc1cca09c45ea6110 SHA512 2ff4901f478e209845c205d6eb0a552752299e0ccfaf73ff36d0375d2b8f4901273445bdf766f3a6507a54969c86151378cc3e2368da15c6ae9c5f0320e44513
+EBUILD flatpak-1.14.1.ebuild 2541 BLAKE2B acdb00e09d6f758d8f83d4dfecd4e5c34e06c111868ce40eea83cb4012c81de1f9b840e691f33d8b87ba9e6af4aa2c110224977ba79799f21006714cab6eb6e9 SHA512 d2132d971dad35d84417252e5a398e61b112dfcf0eb48f3d6c69d731e9d2d2cd58513fde56d5c4450fb7ba23e8fbcf629831f9095701ccf36c994fcccedbaa22
 MISC metadata.xml 325 BLAKE2B a8ca5c0feaab721a66653a8d5e084d2bba127d75faa0975a4dac7d4d7395801fc69bed88bf13663826188696ee5e25e18afc1b0d5161d27e15f36b9c88487146 SHA512 2736f22e733f2214b80c46b3280f90103e21c3211bea129614bcf372f05803b5d5148d34406e8aa332f7b21090e8aaa698bb1a25d767ccea21d3977f0894f464
diff --git a/sys-apps/flatpak/flatpak-1.14.1.ebuild b/sys-apps/flatpak/flatpak-1.14.1.ebuild
new file mode 100644
index 000000000000..d69ef1b584b3
--- /dev/null
+++ b/sys-apps/flatpak/flatpak-1.14.1.ebuild
@@ -0,0 +1,106 @@
+# Copyright 2020-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{8,9,10,11} )
+
+inherit linux-info python-any-r1
+
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.xz"
+DESCRIPTION="Linux application sandboxing and distribution framework"
+HOMEPAGE="https://flatpak.org/"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="doc introspection policykit seccomp systemd X"
+RESTRICT+=" test"
+
+RDEPEND="
+	acct-group/flatpak
+	acct-user/flatpak
+	>=app-arch/libarchive-2.8:=
+	app-arch/zstd:=
+	>=app-crypt/gpgme-1.1.8:=
+	>=dev-libs/appstream-0.12:=
+	>=dev-libs/appstream-glib-0.5.10:=
+	>=dev-libs/glib-2.56:2=
+	>=dev-libs/libxml2-2.4:=
+	dev-libs/json-glib:=
+	dev-libs/libassuan:=
+	>=dev-util/ostree-2020.8:=[gpg(+)]
+	dev-util/ostree[curl]
+	>=gnome-base/dconf-0.26:=
+	gnome-base/gsettings-desktop-schemas
+	net-misc/curl:=
+	>=sys-apps/bubblewrap-0.5.0
+	sys-apps/dbus
+	>=sys-fs/fuse-2.9.9:0=
+	sys-apps/xdg-dbus-proxy
+	X? (
+		x11-apps/xauth
+		x11-libs/libXau:=
+	)
+	x11-libs/gdk-pixbuf:2=
+	policykit? ( >=sys-auth/polkit-0.98:= )
+	seccomp? ( sys-libs/libseccomp:= )
+	systemd? ( sys-apps/systemd:= )
+"
+
+DEPEND="${RDEPEND}"
+# pyparsing version pinned for https://bugs.gentoo.org/825230
+BDEPEND="
+	>=sys-devel/automake-1.13.4
+	>=sys-devel/gettext-0.18.2
+	virtual/pkgconfig
+	dev-util/gdbus-codegen
+	sys-devel/bison
+	introspection? ( >=dev-libs/gobject-introspection-1.40 )
+	doc? (
+		app-text/xmlto
+		dev-libs/libxslt
+	)
+	$(python_gen_any_dep 'dev-python/pyparsing[${PYTHON_USEDEP}]')
+"
+
+PDEPEND="sys-apps/xdg-desktop-portal"
+
+python_check_deps() {
+	has_version -b "dev-python/pyparsing[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	local CONFIG_CHECK="~USER_NS"
+	linux-info_pkg_setup
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	# This line fails because locales are in /usr/lib/locale/locale-archive.
+	sed -i 's:^cp -r /usr/lib/locale/C.*:#\0:' tests/make-test-runtime.sh || die
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-sandboxed-triggers
+		--localstatedir="${EPREFIX}"/var
+		--with-system-bubblewrap
+		--with-system-dbus-proxy
+		$(use_enable X xauth)
+		$(use_enable doc documentation)
+		$(use_enable doc docbook-docs)
+		$(use_enable introspection)
+		$(use_enable policykit system-helper)
+		$(use_enable seccomp)
+		$(use_with systemd)
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	default
+	# https://projects.gentoo.org/qa/policy-guide/installed-files.html#pg0303
+	find "${ED}" -name '*.la' -delete || die
+}