gentoo resync : 25.04.2020

3 files changed, 156 insertions, 2 deletions

diff --git a/sys-devel/gettext/Manifest b/sys-devel/gettext/Manifest
index 6f81c7e830e3..a3d53dfa8d28 100644
--- a/sys-devel/gettext/Manifest
+++ b/sys-devel/gettext/Manifest
@@ -3,7 +3,9 @@ AUX gettext-0.20-avoid_eautomake.patch 878 BLAKE2B 6272d4445501c1f96c40bbc506d64
 AUX gettext-0.20-parallel_install.patch 1494 BLAKE2B 58bd84878c351e29acac861f29854eeb442179a415b5b3cab554b3aa4e2e3b06dabaa3e78ab506bb3b88b55a3fe4d53f1e43718bc6935a84dd477320c9349b70 SHA512 a15e8c415facd7b36761a747da9a0dfc47588d253a84b693c7f1f6e6334c6db5350af41f4c6c1dd83ae61695b2f761cc3b24339d7bb8f4dce972a672312ad942
 AUX gettext-0.21_rc1-avoid_eautomake.patch 1362 BLAKE2B eed15ecde829aa63859dc196052f97abc0386e6c496b7d7e073769e0ad6208623cc1fb6322ff422647f3a55aac6453bd6390432d707d179da7cfc820d487c23a SHA512 5089af3dabb2459345aec6196de70591dafabfc292495f052dd67ce3d2566c4b62a8554eb11db7499378e16a8d11953f044fcfd23c77a71ad01feec4c0c41956
 DIST gettext-0.20.1.tar.gz 23267473 BLAKE2B 34e776b985c7db105f8029e0f3400aa645ff6843cd35f778d48450368a31218ddcf590fbc7fd2d10f716b63094d6a15bf40b358e8a6f498d450d2420e7e7a5f2 SHA512 af6d74986da285df0bdd59524bdf01bb12db448e5ea659dda3b60b660c4a9063c80e8c74cc8751334e065e98348ee0db0079e43c67d485a15e86ae236115fe06
+DIST gettext-0.20.2.tar.gz 23717789 BLAKE2B f0db5eacc93501020f31d80e4b11df708d5ce1ae76f9c35587c830c064a4b712284df4645cedf054a41e66ab08d14d080c4fe1d316a108b997207b78148ed579 SHA512 50b0520230dba5da6e04e51b2317e073cacf1536d73ea88e4b5dc6cc5bd97cf2c9a279c3c3ada1067f39c8b3bb0b1ce8e0823cc1dd4c33f4f10860bdf787009d
 DIST gettext-0.21-rc1.tar.bz2 16947151 BLAKE2B 9bd846afdbe0b5cb82ce7d3b962fdaf6282be000d692d1109ffb7197fc081442f42b83f8c9332c430f2ce9676e15faba180c4ebfde81bc76545480830bf2fd80 SHA512 f8236062456e823f7e14b2bc9fbaaa82c7772605e3624e0114f6fc5a122c935ac5bf7015d35df694f69de8127b6f17a2862a3761a2a97dc3b4c19b768dbbc909
-EBUILD gettext-0.20.1.ebuild 4050 BLAKE2B db78ac840a542fba492bb46160923cb25ccfdc7a35f9603704a2c1181bd730a09561ef83f3794c67fd641d73845d4cf8e5447c7909ed8c540da048b342ba457a SHA512 ba0ee7e5b7006cdb48fce1b46760c67dee4464218ebce7ff572018ae825254b5b7fffa3c620e77991d7bf9b01f5344b2f10d58937c9e6557ac549606eb203524
+EBUILD gettext-0.20.1.ebuild 4051 BLAKE2B 7cf8fff49475516e43f9e20e7338f9097fa78bf9814940ec61077af84d7410d38a68d7ca5e5abf665ac5bd9d80e87644209ff3f83cd55c3086799ae78cf848e5 SHA512 6750748e84cc0c8fb6f795083c8df9574957e688646227671928417d0eca990949a5a0c85a4f54867a8829082bea8c3918bf5c571da4d49774e2226cfa5aab86
+EBUILD gettext-0.20.2.ebuild 4064 BLAKE2B 53adfd3381e4cbb1f9be77c17924c665d4c9523c2030dda953a7ee45e46dcb4dd1e907da031bcf386b1a515b896228ea977e20839bfcef6265fd5b98152df296 SHA512 65d4242a6f12eb30b402172fdd2f7b2ceda8d6aacb26b36b552fa7ba1005b9fe3d8cf9fe14f3a13998adf5d116fe51906361eacae5964df61dfc0ae612da2042
 EBUILD gettext-0.21_rc1.ebuild 4184 BLAKE2B e26e4dcff3b20b349fa8d4d93be9eca758a3af6e721a8955816010793f051444d9d68ed1a232e15434f8fa6c78e26d34f396c2c633b02451f5b70e348443fe84 SHA512 cfa31d901b80dd375836ee010290e668874d62cb14faf7c42f1659a5983367384066873f23da3695454edb3d3d60f23885163e339df903f4285597da4fdcfd14
 MISC metadata.xml 630 BLAKE2B 4e89248161acde4bca6252961fdf9227a08c528cfb91c7c06f85e4573bac6d0c3c7543ddd582b36cfbaedb7acf5139216e4518af4f7f310b1a9a1fd5b960fa5d SHA512 2eac2c110dde44856c6b45a3a1f5d58e26b887041fe8250c17ee6ca555240204296592a25122cf7595551b83b6414a4890a0886458dc4ff4e9135e2bbfc86507
diff --git a/sys-devel/gettext/gettext-0.20.1.ebuild b/sys-devel/gettext/gettext-0.20.1.ebuild
index 03ba2345d043..a36da278b93b 100644
--- a/sys-devel/gettext/gettext-0.20.1.ebuild
+++ b/sys-devel/gettext/gettext-0.20.1.ebuild
@@ -15,7 +15,7 @@ SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
 # so put that license behind USE=cxx.
 LICENSE="GPL-3+ cxx? ( LGPL-2.1+ )"
 SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 ~riscv s390 sparc x86"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv s390 sparc x86"
 IUSE="acl -cvs +cxx doc emacs git java ncurses nls openmp static-libs"
 
 # only runtime goes multilib
diff --git a/sys-devel/gettext/gettext-0.20.2.ebuild b/sys-devel/gettext/gettext-0.20.2.ebuild
new file mode 100644
index 000000000000..5474d54c6bc8
--- /dev/null
+++ b/sys-devel/gettext/gettext-0.20.2.ebuild
@@ -0,0 +1,152 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# Note: Keep version bumps in sync with dev-libs/libintl.
+
+EAPI=7
+
+inherit mono-env libtool java-pkg-opt-2 multilib-minimal
+
+DESCRIPTION="GNU locale utilities"
+HOMEPAGE="https://www.gnu.org/software/gettext/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+# Only libasprintf is under the LGPL (and libintl is in a sep package),
+# so put that license behind USE=cxx.
+LICENSE="GPL-3+ cxx? ( LGPL-2.1+ )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="acl -cvs +cxx doc emacs git java ncurses nls openmp static-libs"
+
+# only runtime goes multilib
+# Note: The version of libxml2 corresponds to the version bundled via gnulib.
+# If the build detects too old of a system version, it will end up falling back
+# to the bundled copy.  #596918
+# Note: expat lacks a subslot because it is dynamically loaded at runtime.  We
+# would depend on older subslots if they were available (based on the ABIs that
+# are explicitly handled), but expat doesn't currently use subslots.
+DEPEND=">=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]
+	>=virtual/libintl-0-r2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.3:=
+	dev-libs/expat
+	acl? ( virtual/acl )
+	ncurses? ( sys-libs/ncurses:0= )
+	java? ( >=virtual/jdk-1.4:= )"
+RDEPEND="${DEPEND}
+	!git? ( cvs? ( dev-vcs/cvs ) )
+	git? ( dev-vcs/git )
+	java? ( >=virtual/jre-1.4 )"
+BDEPEND="
+	git? ( dev-vcs/git )
+"
+PDEPEND="emacs? ( app-emacs/po-mode )"
+
+MULTILIB_WRAPPED_HEADERS=(
+	# only installed for native ABI
+	/usr/include/gettext-po.h
+
+	/usr/include/autosprintf.h
+	/usr/include/textstyle.h
+	/usr/include/textstyle/stdbool.h
+	/usr/include/textstyle/version.h
+	/usr/include/textstyle/woe32dll.h
+)
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.19.7-disable-libintl.patch #564168
+	"${FILESDIR}"/${PN}-0.20-parallel_install.patch #685530
+	"${FILESDIR}"/${PN}-0.21_rc1-avoid_eautomake.patch
+)
+
+QA_SONAME_NO_SYMLINK=".*/preloadable_libintl.so"
+
+pkg_setup() {
+	mono-env_pkg_setup
+	java-pkg-opt-2_pkg_setup
+}
+
+src_prepare() {
+	java-pkg-opt-2_src_prepare
+
+	default
+
+	elibtoolize
+}
+
+multilib_src_configure() {
+	local myconf=(
+		# switches common to runtime and top-level
+		--cache-file="${BUILD_DIR}"/config.cache
+		#--docdir="\$(datarootdir)/doc/${PF}"
+
+		# Emacs support is now in a separate package
+		--without-emacs
+		--without-lispdir
+		# glib depends on us so avoid circular deps
+		--with-included-glib
+		# libcroco depends on glib which ... ^^^
+		--with-included-libcroco
+		# this will _disable_ libunistring (since it is not bundled),
+		# see bug #326477
+		--with-included-libunistring
+		# Never build libintl since it's in dev-libs/libintl now.
+		--without-included-gettext
+		# Never build bundled copy of libxml2.
+		--without-included-libxml
+
+		$(use_enable acl)
+		$(use_enable cxx c++)
+		$(use_enable cxx libasprintf)
+		$(use_with git)
+		$(usex git --without-cvs $(use_with cvs))
+		$(use_enable java)
+		$(use_enable ncurses curses)
+		$(use_enable nls)
+		$(use_enable openmp)
+		$(use_enable static-libs static)
+	)
+
+	local ECONF_SOURCE="${S}"
+	if ! multilib_is_native_abi ; then
+		# for non-native ABIs, we build runtime only
+		ECONF_SOURCE+=/gettext-runtime
+	fi
+
+	econf "${myconf[@]}"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+
+	if multilib_is_native_abi ; then
+		dosym msgfmt /usr/bin/gmsgfmt #43435
+		dobin gettext-tools/misc/gettextize
+	fi
+}
+
+multilib_src_install_all() {
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	if use java ; then
+		java-pkg_dojar "${ED}"/usr/share/${PN}/*.jar
+		rm "${ED}"/usr/share/${PN}/*.jar || die
+		rm "${ED}"/usr/share/${PN}/*.class || die
+		if use doc ; then
+			java-pkg_dojavadoc "${ED}"/usr/share/doc/${PF}/html/javadoc2
+		fi
+	fi
+
+	dodoc AUTHORS ChangeLog NEWS README THANKS
+
+	if use doc ; then
+		docinto html
+		dodoc "${ED}"/usr/share/doc/${PF}/*.html
+	else
+		rm -rf "${ED}"/usr/share/doc/${PF}/{csharpdoc,examples,javadoc2,javadoc1}
+	fi
+	rm "${ED}"/usr/share/doc/${PF}/*.html || die
+}
+
+pkg_preinst() {
+	java-pkg-opt-2_pkg_preinst
+}