gentoo auto-resync : 04:06:2024 - 00:07:50

3 files changed, 212 insertions, 27 deletions

diff --git a/sys-fs/btrfs-progs/Manifest b/sys-fs/btrfs-progs/Manifest
index 68a29750d024..97fad910f2ed 100644
--- a/sys-fs/btrfs-progs/Manifest
+++ b/sys-fs/btrfs-progs/Manifest
@@ -6,6 +6,7 @@ DIST btrfs-progs-v6.8.1.tar.sign 566 BLAKE2B 843eada2b00a2370522edc95d79bcfed88b
 DIST btrfs-progs-v6.8.1.tar.xz 2652968 BLAKE2B 34406dedc6d97bd94a498c3bbb424d34a59b8251b37f9a40a87740f96db77780a4cd76c88055b4d9e4f673b4a3621503a6bedb67ceaf20870fb26c10f49b74e0 SHA512 b5f0694e56eecf1956313b3406610c2e22658ace51a636d79efe996780bb0b03fed95e68a8c9a11dd8649958c0e7dbc7417bb479859365d47b52e478f6830d46
 EBUILD btrfs-progs-6.6.3.ebuild 4581 BLAKE2B c5fd9d72bfe270bf54838e0b0eff08cb9405711792cdd1775f21ff853a6202ba0f7ccff8a043f39da02d8cdcd36a253d03c53812ad293f64b6ce26df9e1c505e SHA512 a8af6e0941002d70cebef2fd96838c1bf630ad95bd4871e83097fd552ec5f01d253f675c05551f56c92871d5a40acae697c1f69e194c1cc9b915bb9acdb1cdc9
 EBUILD btrfs-progs-6.7.1.ebuild 4581 BLAKE2B c5fd9d72bfe270bf54838e0b0eff08cb9405711792cdd1775f21ff853a6202ba0f7ccff8a043f39da02d8cdcd36a253d03c53812ad293f64b6ce26df9e1c505e SHA512 a8af6e0941002d70cebef2fd96838c1bf630ad95bd4871e83097fd552ec5f01d253f675c05551f56c92871d5a40acae697c1f69e194c1cc9b915bb9acdb1cdc9
+EBUILD btrfs-progs-6.8.1-r1.ebuild 4385 BLAKE2B 1a9ef892af338671a84f00beb26080dfc83b0ae5df4896bbdfe8524a4546b58467c7299e2aaf605d193d426278c44e26e6a1bfb7ae188ed9d033f98eb473a33c SHA512 836ac7cefa25d16d89be2afd5da74ae91c665dc231dc1dd3f3d1420f6aad0d8de44936da83cb932ebe467685150842ffb08feb6ac9b3df168cec04b87f5a29a1
 EBUILD btrfs-progs-6.8.1.ebuild 4581 BLAKE2B d396df46d93764918662ebef638bffd6383d959e924dcbd130851d8ea853d4e8999e4144b171080c694e1dd8d531fcaa0dfe7049a8b3479c2b40884d38f019b4 SHA512 7a26a82542bb82e3d429342b9421c8bda1b0ce5cfe516329dfca2ae8545ebdc97fa951a5755c43e981e5298a9a5bbf867e018929d74cc9bfb8b2486f4785e003
-EBUILD btrfs-progs-9999.ebuild 4587 BLAKE2B eeb427390e6c7cc2834214201d7eac292bdc83c305923110d9d512e103deb43b4206425b6efcd5843ec27dda8371755554a5e9d9ab3a6a5f1aa419351fc695ff SHA512 ff6baffe50f9c881ba5969403dd12c5d1f525677dc37acabb4344cf355ddd56328ad392e81708940582a3f93cdcbc130fa88a4935a9218258689d3d276caf5c6
+EBUILD btrfs-progs-9999.ebuild 4385 BLAKE2B 1a9ef892af338671a84f00beb26080dfc83b0ae5df4896bbdfe8524a4546b58467c7299e2aaf605d193d426278c44e26e6a1bfb7ae188ed9d033f98eb473a33c SHA512 836ac7cefa25d16d89be2afd5da74ae91c665dc231dc1dd3f3d1420f6aad0d8de44936da83cb932ebe467685150842ffb08feb6ac9b3df168cec04b87f5a29a1
 MISC metadata.xml 610 BLAKE2B 70361c4d5434a98f73a3d38ed47d7be830783529db6217396f2235cdedd58744fc6e52e4de1994d28184fe9d8aa5d2982c433d47eda1868cfdb79edf0769a620 SHA512 8958c02574adb1395a9d21d9e9ad5db38570b82a1c7211752eb007eecbd0e541e880a060649641f40be877f167e14f278f14d5ef8775766ef9a6fa5d3843dc53
diff --git a/sys-fs/btrfs-progs/btrfs-progs-6.8.1-r1.ebuild b/sys-fs/btrfs-progs/btrfs-progs-6.8.1-r1.ebuild
new file mode 100644
index 000000000000..59e32bcafd5d
--- /dev/null
+++ b/sys-fs/btrfs-progs/btrfs-progs-6.8.1-r1.ebuild
@@ -0,0 +1,191 @@
+# Copyright 2008-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+inherit bash-completion-r1 python-any-r1 udev
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git"
+	EGIT_BRANCH="devel"
+	WANT_LIBTOOL="none"
+	inherit autotools git-r3
+else
+	VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/dsterba.asc
+	inherit verify-sig
+
+	MY_PV="v${PV/_/-}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="
+		https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${MY_P}.tar.xz
+		verify-sig? ( https://www.kernel.org/pub/linux/kernel/people/kdave/${PN}/${MY_P}.tar.sign )
+	"
+	S="${WORKDIR}"/${PN}-${MY_PV}
+
+	if [[ ${PV} != *_rc* ]] ; then
+		KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
+	fi
+fi
+
+DESCRIPTION="Btrfs filesystem utilities"
+HOMEPAGE="https://btrfs.readthedocs.io/en/latest/"
+
+LICENSE="GPL-2"
+SLOT="0/0" # libbtrfs soname
+IUSE="+convert +man reiserfs static static-libs udev +zstd"
+# Could support it with just !systemd => eudev, see mdadm, but let's
+# see if someone asks for it first.
+REQUIRED_USE="static? ( !udev )"
+
+# Tries to mount repaired filesystems
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/lzo:2=
+	sys-apps/util-linux:=[static-libs(+)?]
+	sys-libs/zlib:=
+	convert? (
+		sys-fs/e2fsprogs:=
+		reiserfs? (
+			>=sys-fs/reiserfsprogs-3.6.27
+		)
+	)
+	udev? ( virtual/libudev:= )
+	zstd? ( app-arch/zstd:= )
+"
+DEPEND="
+	${RDEPEND}
+	>=sys-kernel/linux-headers-5.10
+	convert? ( sys-apps/acl )
+	static? (
+		dev-libs/lzo:2[static-libs(+)]
+		sys-apps/util-linux:0[static-libs(+)]
+		sys-libs/zlib:0[static-libs(+)]
+		convert? (
+			sys-fs/e2fsprogs[static-libs(+)]
+			reiserfs? (
+				>=sys-fs/reiserfsprogs-3.6.27[static-libs(+)]
+			)
+		)
+		zstd? ( app-arch/zstd[static-libs(+)] )
+	)
+"
+BDEPEND="
+	virtual/pkgconfig
+	man? (
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]')
+	)
+"
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+	python_has_version "dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
+}
+
+if [[ ${PV} == 9999 ]]; then
+	BDEPEND+=" sys-devel/gnuconfig"
+else
+	BDEPEND+=" verify-sig? ( sec-keys/openpgp-keys-dsterba )"
+fi
+
+pkg_setup() {
+	: # Prevent python-any-r1_python_setup
+}
+
+src_unpack() {
+	if [[ ${PV} == 9999 ]] ; then
+		git-r3_src_unpack
+		return
+	fi
+
+	if in_iuse verify-sig && use verify-sig ; then
+		mkdir "${T}"/verify-sig || die
+		pushd "${T}"/verify-sig &>/dev/null || die
+
+		# Upstream sign the decompressed .tar
+		# Let's do it separately in ${T} then cleanup to avoid external
+		# effects on normal unpack.
+		cp "${DISTDIR}"/${MY_P}.tar.xz . || die
+		xz -d ${MY_P}.tar.xz || die
+		verify-sig_verify_detached ${MY_P}.tar "${DISTDIR}"/${MY_P}.tar.sign
+
+		popd &>/dev/null || die
+		rm -r "${T}"/verify-sig || die
+	fi
+
+	default
+}
+
+src_prepare() {
+	default
+
+	if [[ ${PV} == 9999 ]]; then
+		local AT_M4DIR=config
+		eautoreconf
+
+		local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
+		[[ -e ${automakedir} ]] || die "Could not locate automake directory"
+
+		ln -s "${automakedir}"/install-sh config/install-sh || die
+		ln -s "${BROOT}"/usr/share/gnuconfig/config.guess config/config.guess || die
+		ln -s "${BROOT}"/usr/share/gnuconfig/config.sub config/config.sub || die
+	fi
+}
+
+src_configure() {
+	local myeconfargs=(
+		--bindir="${EPREFIX}"/sbin
+
+		--enable-lzo
+		--disable-experimental
+		--disable-python
+		$(use_enable convert)
+		$(use_enable man documentation)
+		$(use_enable elibc_glibc backtrace)
+		$(use_enable static-libs static)
+		$(use_enable udev libudev)
+		$(use_enable zstd)
+
+		# Could support libgcrypt, libsodium, libkcapi, openssl, botan
+		--with-crypto=builtin
+		--with-convert=ext2$(usev reiserfs ',reiserfs')
+	)
+
+	export EXTRA_PYTHON_CFLAGS="${CFLAGS}"
+	export EXTRA_PYTHON_LDFLAGS="${LDFLAGS}"
+
+	if use man; then
+		python_setup
+	fi
+
+	# bash as a temporary workaround for https://github.com/kdave/btrfs-progs/pull/721
+	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	emake V=1 all $(usev static)
+}
+
+src_test() {
+	emake V=1 -j1 -C tests test
+}
+
+src_install() {
+	local makeargs=(
+		$(usev static install-static)
+	)
+
+	emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
+
+	newbashcomp btrfs-completion btrfs
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}
diff --git a/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild b/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
index e83177d9b9ef..59e32bcafd5d 100644
--- a/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
+++ b/sys-fs/btrfs-progs/btrfs-progs-9999.ebuild
@@ -3,8 +3,8 @@
 
 EAPI=8
 
-PYTHON_COMPAT=( python3_{10..12} )
-inherit bash-completion-r1 python-single-r1 udev
+PYTHON_COMPAT=( python3_{10..13} )
+inherit bash-completion-r1 python-any-r1 udev
 
 if [[ ${PV} == 9999 ]]; then
 	EGIT_REPO_URI="https://github.com/kdave/btrfs-progs.git"
@@ -33,10 +33,10 @@ HOMEPAGE="https://btrfs.readthedocs.io/en/latest/"
 
 LICENSE="GPL-2"
 SLOT="0/0" # libbtrfs soname
-IUSE="+convert python +man reiserfs static static-libs udev +zstd"
+IUSE="+convert +man reiserfs static static-libs udev +zstd"
 # Could support it with just !systemd => eudev, see mdadm, but let's
 # see if someone asks for it first.
-REQUIRED_USE="static? ( !udev ) python? ( ${PYTHON_REQUIRED_USE} )"
+REQUIRED_USE="static? ( !udev )"
 
 # Tries to mount repaired filesystems
 RESTRICT="test"
@@ -51,7 +51,6 @@ RDEPEND="
 			>=sys-fs/reiserfsprogs-3.6.27
 		)
 	)
-	python? ( ${PYTHON_DEPS} )
 	udev? ( virtual/libudev:= )
 	zstd? ( app-arch/zstd:= )
 "
@@ -59,11 +58,6 @@ DEPEND="
 	${RDEPEND}
 	>=sys-kernel/linux-headers-5.10
 	convert? ( sys-apps/acl )
-	python? (
-		$(python_gen_cond_dep '
-			dev-python/setuptools[${PYTHON_USEDEP}]
-		')
-	)
 	static? (
 		dev-libs/lzo:2[static-libs(+)]
 		sys-apps/util-linux:0[static-libs(+)]
@@ -80,11 +74,16 @@ DEPEND="
 BDEPEND="
 	virtual/pkgconfig
 	man? (
-		dev-python/sphinx
-		dev-python/sphinx-rtd-theme
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]')
 	)
 "
 
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" &&
+	python_has_version "dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
+}
+
 if [[ ${PV} == 9999 ]]; then
 	BDEPEND+=" sys-devel/gnuconfig"
 else
@@ -92,7 +91,7 @@ else
 fi
 
 pkg_setup() {
-	use python && python-single-r1_pkg_setup
+	: # Prevent python-any-r1_python_setup
 }
 
 src_unpack() {
@@ -123,9 +122,9 @@ src_prepare() {
 	default
 
 	if [[ ${PV} == 9999 ]]; then
-		AT_M4DIR="m4" eautoreconf
+		local AT_M4DIR=config
+		eautoreconf
 
-		mkdir config || die
 		local automakedir="$(autotools_run_tool --at-output automake --print-libdir)"
 		[[ -e ${automakedir} ]] || die "Could not locate automake directory"
 
@@ -141,10 +140,10 @@ src_configure() {
 
 		--enable-lzo
 		--disable-experimental
+		--disable-python
 		$(use_enable convert)
 		$(use_enable man documentation)
 		$(use_enable elibc_glibc backtrace)
-		$(use_enable python)
 		$(use_enable static-libs static)
 		$(use_enable udev libudev)
 		$(use_enable zstd)
@@ -157,6 +156,10 @@ src_configure() {
 	export EXTRA_PYTHON_CFLAGS="${CFLAGS}"
 	export EXTRA_PYTHON_LDFLAGS="${LDFLAGS}"
 
+	if use man; then
+		python_setup
+	fi
+
 	# bash as a temporary workaround for https://github.com/kdave/btrfs-progs/pull/721
 	CONFIG_SHELL="${BROOT}"/bin/bash econf "${myeconfargs[@]}"
 }
@@ -167,26 +170,16 @@ src_compile() {
 
 src_test() {
 	emake V=1 -j1 -C tests test
-
-	if use python ; then
-		cd libbtrfsutil/python || die
-
-		local -x LD_LIBRARY_PATH="${S}:libbtrfsutil/python:${LD_LIBRARY_PATH}"
-		${EPYTHON} -m unittest tests/test_*.py || die "Tests failed with ${EPYTHON}"
-	fi
 }
 
 src_install() {
 	local makeargs=(
-		$(usev python install_python)
 		$(usev static install-static)
 	)
 
 	emake V=1 DESTDIR="${D}" install "${makeargs[@]}"
 
 	newbashcomp btrfs-completion btrfs
-
-	use python && python_optimize
 }
 
 pkg_postinst() {