gentoo resync : 15.01.2020

1 files changed, 48 insertions, 0 deletions

diff --git a/sys-fs/hfsutils/hfsutils-3.2.6-r6.ebuild b/sys-fs/hfsutils/hfsutils-3.2.6-r6.ebuild
new file mode 100644
index 000000000000..23076395fd73
--- /dev/null
+++ b/sys-fs/hfsutils/hfsutils-3.2.6-r6.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit toolchain-funcs
+
+DESCRIPTION="HFS FS Access utils"
+HOMEPAGE="https://www.mars.org/home/rob/proj/hfs/"
+SRC_URI="ftp://ftp.mars.org/pub/hfs/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 ~arm ppc ppc64 sparc x86"
+IUSE="tcl tk"
+
+DEPEND="
+	tcl? ( dev-lang/tcl:0= )
+	tk? ( dev-lang/tk:0= )"
+RDEPEND="${DEPEND}"
+
+# use tk requires tcl - bug #150437
+REQUIRED_USE="tk? ( tcl )"
+PATCHES=(
+	"${FILESDIR}"/${P}-errno.patch
+	"${FILESDIR}"/largerthan2gb.patch
+	"${FILESDIR}"/${P}-fix-tcl-8.6.patch
+)
+
+src_configure() {
+	tc-export CC
+	econf $(use_with tcl) $(use_with tk)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR) rc" CC="$(tc-getCC)" RANLIB="$(tc-getRANLIB)"
+	emake CC="$(tc-getCC)" -C hfsck
+}
+
+src_install() {
+	dodir /usr/bin /usr/lib /usr/share/man/man1
+	emake \
+		prefix="${ED}"/usr \
+		MANDEST="${ED}"/usr/share/man \
+		infodir="${ED}"/usr/share/info \
+		install
+	dobin hfsck/hfsck
+	dodoc BLURB CHANGES README TODO doc/*.txt
+}