gentoo resync : 06.08.2019

3 files changed, 146 insertions, 18 deletions

diff --git a/sys-fs/xfsprogs/Manifest b/sys-fs/xfsprogs/Manifest
index cbb56325e9ed..9a4f31858ed8 100644
--- a/sys-fs/xfsprogs/Manifest
+++ b/sys-fs/xfsprogs/Manifest
@@ -2,9 +2,11 @@ AUX xfsprogs-4.15.0-docdir.patch 299 BLAKE2B 1ef9dd458806f33ca989dd977ae3b62fb5b
 AUX xfsprogs-4.15.0-sharedlibs.patch 3022 BLAKE2B cfa23520a55750af375ada8c35fb9f4b3ea2f401ddebd95aef6d46f9195ac6ab3fb38f5f9d08529d3c2658623a49eadc7db0be68159753025310605fdfc35a6b SHA512 5a6e62f2914e372f2bf679b10c32fe65f60677b4bf0e58f60c40a297ed8974d5ec0af3bcba5801ba19cadbb689a6dad62c1e2cd88587f6f3d30f21f1472f3ac0
 AUX xfsprogs-4.9.0-underlinking.patch 731 BLAKE2B 501b3967487d89c56c986f0c03e13fe3d217a6c4c8dd21fce1986793cefaa4777e827945adb3807f2d644665fbf66e7fbd5318d6f5c58d37c49260c24ca46181 SHA512 2fcbaab48ca33cd2e8724cdc55d814a970beb5127c861f4b829ede9f501516733c6dabbfe0bfb1d23df01bb69538af5ca31eb403030e3d2ad9efd8643c509ac7
 DIST xfsprogs-4.19.0.tar.xz 1212852 BLAKE2B 2d04390765c5e0dd7d51366f0310c9e680651d49bdd1ecd220b4eec50540a66c97bf6e54f976414351bc77381ffd463803836b27ca25b53960a278a34bc09775 SHA512 a96d0ce406534e70b0a531dfab296de420ec710cd0682dffaf5211602adf82dd59f84b9eb7793c54eabb782a9e0229acf7b247ab644d531ee9e5b51fe9dc0f58
-DIST xfsprogs-5.0.0.tar.xz 1218476 BLAKE2B ef6eaab43531f696f739972c362e31c3304baaecb3485b45c16441a8bf7f1da7f47cd74a21660ba2c2bb45858a2b13b7af41c94671135f6a32a36eb745c024a0 SHA512 cebe3d2ea80676a99cc7f9cc014894398fbe3bdaf237829e9c7aa0404558c1ab16f2055acb5afd8234b2bc8475117bcef3c7500c553adb12bbaf3262bd077d18
 DIST xfsprogs-5.1.0.tar.xz 1223736 BLAKE2B bfadb13cf3a4f9231eb13f4e7d3c803c2143abb776c0fee758ea7257097ef3fb79253c16133942041c20ff6078a1704fa18d08866c6a2e1a61b63f4de11d00c7 SHA512 ca5959edb299be8574b2ca51e907a418fab796ae92f588075a2aab0c2a3cf8dae49e2b68679c65c361201223e8f8ac29b1e5618eb1e519496c3aca9218620881
+DIST xfsprogs-5.2.0.tar.xz 1225884 BLAKE2B bec075d2adbafc5f6be215b658b8617141ade481558477525251c8547162f462af5464af5ac25d9498aca99b960a59071cc6651c36c6d30e5757e8d177c1b898 SHA512 b65ffb4d293f1ee0a9ec5aa35bf7a9491c2d536ad0da7f8e1d533743caebd98abffd1b93508969bac4135dc15434a9e170a516cedd373466ef762b65029f013f
+DIST xfsprogs-5.2.1.tar.xz 1227012 BLAKE2B af6c25d88d0a50fc82ecb2d9d00545ffdf906d6e85361360130b5a2b0d362e566c097f15be04a61023bd5c7815b77d0bab6258d8f188c5afe68098c51ae26ee0 SHA512 a2ecd8e2ae8a4e7357b4133beaeffeae4d6c9d0ece9855d9780a84c2d4072e3d4e0b8ffa3baa995862ec38dcbc5dd74205f7f4456676826082c4811867508a43
 EBUILD xfsprogs-4.19.0.ebuild 2434 BLAKE2B cc6ca0e0425994414497bb9ac27541408958d9da936a659028b38cdaf3ed6527c741efeff812b023ce513b091b301723fa21fce1a4512939c5d3f6ddb8f42ab4 SHA512 bcef5fcc339809950886dd2a37fa696892216e1ddc5fc85b773ba40fe94fd1430a0b34b71a1ea22ce5d3cb947a8de23c800993067b5f909358ed037a2c18a198
-EBUILD xfsprogs-5.0.0.ebuild 2446 BLAKE2B 56b0df730592b592b2fec03628d77b23c85fa83c327aa79576a4e7a3ade9eeb2b7ce37c94ec28372cfd90ca627e975aaeb9410d3b92976e40b7efa046a6ce613 SHA512 0346edc9cca81230879dd85b7eec3db552c48ae14cc97d2ca00c7a47e743c360b5a7a66533705f302e6062368e4497df7bbc114294cc0693c02acb804f4221a9
 EBUILD xfsprogs-5.1.0.ebuild 2466 BLAKE2B 568609a5a361342a9eba9c591910ef0304f0a362dcddd3c4629671bcc28600b9155e17a59111bdd28e90d4be51f26d9e0ca4c313b0daea82fe4eafd4af77813e SHA512 5a4c27c82ea4e20c0e8a1428cbbff72e58c84e72281dbe2e5a91fb52ab3e6824fe778e375c0c8318df1ebf83975c5bef637b4749e21fc5f5309d8b82743867a0
+EBUILD xfsprogs-5.2.0.ebuild 2847 BLAKE2B 21b2d3dd8fb503e435a97af0bec0b2a6d4c51dc3be92bf1bc12c41e568e154b44d41e5c559c5893da7962ad05d9a08f25ee3f9f51983ece8631c8601d942a7f6 SHA512 c76c5830628b64bbed2af76f3529e6354bcc9c89667836c107c7f8f25bbac48de6ef5b36b55b71273441a0a17289f51ee12017c23ed0c2bf16448e5f16160466
+EBUILD xfsprogs-5.2.1.ebuild 2782 BLAKE2B 13add8a58236a489688016d3d58800be7542c8ae31d334c72999fc7bc280063112ce5c642da5b01cd922d9c54706899e72c8af7b9becd8c910c4314cb30f39f3 SHA512 9c51e3b40019277aeb1751bc5686157601cdb9b477e086584d5d68866b1f2062690ad2e85f4140d4f5a9f13468609df041007c5e077e848da300083c62d051d7
 MISC metadata.xml 257 BLAKE2B f8a00f23163e58c310fa0e4ab94b2e6b5638ec569a5e93ea2efec8c7bdd97c1629e9bc0e9bf04917f5ca4fea4085855b281c30ced2f09548e96b12e6bb1d5a40 SHA512 9c7759d33e1bbc8be0da5b4f59fc720266e40f4116d7db0c17c5ad800a7bb638f33a1308e1554092af781f06df6f6cb55db41fc22207cd3edc2e159840e3a3b1
diff --git a/sys-fs/xfsprogs/xfsprogs-5.0.0.ebuild b/sys-fs/xfsprogs/xfsprogs-5.2.0.ebuild
index 79a212d5e50d..22a5cc55eeaa 100644
--- a/sys-fs/xfsprogs/xfsprogs-5.0.0.ebuild
+++ b/sys-fs/xfsprogs/xfsprogs-5.2.0.ebuild
@@ -1,9 +1,9 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-inherit toolchain-funcs multilib systemd usr-ldscript
+inherit flag-o-matic toolchain-funcs systemd
 
 DESCRIPTION="xfs filesystem utilities"
 HOMEPAGE="https://xfs.wiki.kernel.org/"
@@ -12,7 +12,7 @@ SRC_URI="https://www.kernel.org/pub/linux/utils/fs/xfs/${PN}/${P}.tar.xz"
 LICENSE="LGPL-2.1"
 SLOT="0"
 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
-IUSE="icu libedit nls readline static-libs"
+IUSE="icu libedit nls readline"
 
 LIB_DEPEND=">=sys-apps/util-linux-2.17.2[static-libs(+)]
 	icu? ( dev-libs/icu:=[static-libs(+)] )
@@ -20,8 +20,10 @@ LIB_DEPEND=">=sys-apps/util-linux-2.17.2[static-libs(+)]
 	!readline? ( libedit? ( dev-libs/libedit[static-libs(+)] ) )"
 RDEPEND="${LIB_DEPEND//\[static-libs(+)]}
 	!<sys-fs/xfsdump-3"
-DEPEND="${RDEPEND}
-	nls? ( sys-devel/gettext )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	nls? ( sys-devel/gettext )
+"
 
 PATCHES=(
 	"${FILESDIR}"/${PN}-4.9.0-underlinking.patch
@@ -39,14 +41,13 @@ pkg_setup() {
 src_prepare() {
 	default
 
-	# Clear out -static from all flags since we want to link against dynamic xfs libs.
+	# Fix doc dir
 	sed -i \
 		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
 		include/builddefs.in || die
+
 	# Don't install compressed docs
 	sed 's@\(CHANGES\)\.gz[[:space:]]@\1 @' -i doc/Makefile || die
-	find -name Makefile -exec \
-		sed -i -r -e '/^LLDFLAGS [+]?= -static(-libtool-libs)?$/d' {} +
 }
 
 src_configure() {
@@ -54,8 +55,10 @@ src_configure() {
 	export OPTIMIZER=${CFLAGS}
 	unset PLATFORM # if set in user env, this breaks configure
 
+	# Upstream does NOT support --disable-static anymore,
+	# https://www.spinics.net/lists/linux-xfs/msg30185.html
+	# https://www.spinics.net/lists/linux-xfs/msg30272.html
 	local myconf=(
-		--disable-lto #655638
 		--enable-blkid
 		--with-crond-dir="${EPREFIX}/etc/cron.d"
 		--with-systemd-unit-dir="$(systemd_get_systemunitdir)"
@@ -63,12 +66,34 @@ src_configure() {
 		$(use_enable nls gettext)
 		$(use_enable readline)
 		$(usex readline --disable-editline $(use_enable libedit editline))
-		$(use_enable static-libs static)
 	)
 
+	if is-flagq -fno-lto ; then
+		einfo "LTO disabled via {C,CXX,F,FC}FLAGS"
+		myconf+=( --disable-lto )
+	else
+		if is-flagq -flto ; then
+			einfo "LTO forced via {C,CXX,F,FC}FLAGS"
+			myconf+=( --enable-lto )
+		elif use amd64 || use x86  ; then
+			# match upstream default
+			myconf+=( --enable-lto )
+		else
+			# LTO can cause problems on some architectures, bug 655638
+			myconf+=( --disable-lto )
+		fi
+	fi
+
 	econf "${myconf[@]}"
+}
+
+src_compile() {
+	# Unset {CF,LD}FLAGS which are already set via configure
+	# but will cause problems when available during make.
+	# Fixed in >=xfsprogs-5.3.0.
+	unset CFLAGS LDFLAGS
 
-	MAKEOPTS+=" V=1"
+	emake V=1
 }
 
 src_install() {
@@ -76,10 +101,6 @@ src_install() {
 	# parallel install fails on this target for >=xfsprogs-3.2.0
 	emake -j1 DIST_ROOT="${ED}" install-dev
 
-	# handle is for xfsdump, the rest for xfsprogs
-	gen_usr_ldscript -a handle xcmd xfs xlog frog
 	# removing unnecessary .la files if not needed
-	if ! use static-libs ; then
-		find "${ED}" -name '*.la' -delete || die
-	fi
+	find "${ED}" -type f -name '*.la' -delete || die
 }
diff --git a/sys-fs/xfsprogs/xfsprogs-5.2.1.ebuild b/sys-fs/xfsprogs/xfsprogs-5.2.1.ebuild
new file mode 100644
index 000000000000..a546b735ad7c
--- /dev/null
+++ b/sys-fs/xfsprogs/xfsprogs-5.2.1.ebuild
@@ -0,0 +1,105 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit flag-o-matic toolchain-funcs systemd
+
+DESCRIPTION="xfs filesystem utilities"
+HOMEPAGE="https://xfs.wiki.kernel.org/"
+SRC_URI="https://www.kernel.org/pub/linux/utils/fs/xfs/${PN}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="icu libedit nls readline"
+
+LIB_DEPEND=">=sys-apps/util-linux-2.17.2[static-libs(+)]
+	icu? ( dev-libs/icu:=[static-libs(+)] )
+	readline? ( sys-libs/readline:0=[static-libs(+)] )
+	!readline? ( libedit? ( dev-libs/libedit[static-libs(+)] ) )"
+RDEPEND="${LIB_DEPEND//\[static-libs(+)]}
+	!<sys-fs/xfsdump-3"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-4.9.0-underlinking.patch
+	"${FILESDIR}"/${PN}-4.15.0-sharedlibs.patch
+	"${FILESDIR}"/${PN}-4.15.0-docdir.patch
+)
+
+pkg_setup() {
+	if use readline && use libedit ; then
+		ewarn "You have USE='readline libedit' but these are exclusive."
+		ewarn "Defaulting to readline; please disable this USE flag if you want libedit."
+	fi
+}
+
+src_prepare() {
+	default
+
+	# Fix doc dir
+	sed -i \
+		-e "/^PKG_DOC_DIR/s:@pkg_name@:${PF}:" \
+		include/builddefs.in || die
+
+	# Don't install compressed docs
+	sed 's@\(CHANGES\)\.gz[[:space:]]@\1 @' -i doc/Makefile || die
+}
+
+src_configure() {
+	export DEBUG=-DNDEBUG
+	export OPTIMIZER=${CFLAGS}
+	unset PLATFORM # if set in user env, this breaks configure
+
+	# Upstream does NOT support --disable-static anymore,
+	# https://www.spinics.net/lists/linux-xfs/msg30185.html
+	# https://www.spinics.net/lists/linux-xfs/msg30272.html
+	local myconf=(
+		--enable-blkid
+		--with-crond-dir="${EPREFIX}/etc/cron.d"
+		--with-systemd-unit-dir="$(systemd_get_systemunitdir)"
+		$(use_enable icu libicu)
+		$(use_enable nls gettext)
+		$(use_enable readline)
+		$(usex readline --disable-editline $(use_enable libedit editline))
+	)
+
+	if is-flagq -fno-lto ; then
+		einfo "LTO disabled via {C,CXX,F,FC}FLAGS"
+		myconf+=( --disable-lto )
+	else
+		if is-flagq -flto ; then
+			einfo "LTO forced via {C,CXX,F,FC}FLAGS"
+			myconf+=( --enable-lto )
+		elif use amd64 || use x86  ; then
+			# match upstream default
+			myconf+=( --enable-lto )
+		else
+			# LTO can cause problems on some architectures, bug 655638
+			myconf+=( --disable-lto )
+		fi
+	fi
+
+	econf "${myconf[@]}"
+}
+
+src_compile() {
+	# Unset {CF,LD}FLAGS which are already set via configure
+	# but will cause problems when available during make.
+	# Fixed in >=xfsprogs-5.3.0.
+	unset CFLAGS LDFLAGS
+
+	emake V=1
+}
+
+src_install() {
+	emake DIST_ROOT="${ED}" install 
+	emake DIST_ROOT="${ED}" install-dev
+
+	# removing unnecessary .la files if not needed
+	find "${ED}" -type f -name '*.la' -delete || die
+}