gentoo resync : 18.01.2020

2 files changed, 164 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-4.19.97.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-4.19.97.ebuild
new file mode 100644
index 000000000000..4c339a8d3f81
--- /dev/null
+++ b/sys-kernel/gentoo-kernel/gentoo-kernel-4.19.97.ebuild
@@ -0,0 +1,83 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-build
+
+MY_P=linux-4.19.94
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} - 1))
+# https://git.archlinux.org/svntogit/packages.git/log/trunk/config?h=packages/linux-lts
+AMD64_CONFIG_VER=4.19.92-arch1
+AMD64_CONFIG_HASH=bf97de6a2e405659aaad4c251b7f0bb48d5ed3c9
+# https://git.archlinux32.org/packages/log/core/linux-lts/config
+I686_CONFIG_VER=4.19.85-arch1
+I686_CONFIG_HASH=1f0345e2983d2edd55b401cb5a87fdf365a4192c
+
+DESCRIPTION="Linux kernel built with Gentoo patches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+=" https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	amd64? (
+		https://git.archlinux.org/svntogit/packages.git/plain/trunk/config?h=packages/linux-lts&id=${AMD64_CONFIG_HASH}
+			-> linux-${AMD64_CONFIG_VER}.amd64.config
+	)
+	x86? (
+		https://git.archlinux32.org/packages/plain/core/linux-lts/config?id=${I686_CONFIG_HASH}
+			-> linux-${I686_CONFIG_VER}.i686.config
+	)"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+
+pkg_pretend() {
+	mount-boot_pkg_pretend
+
+	ewarn "This is an experimental package.  The built kernel and/or initramfs"
+	ewarn "may not work at all or fail with your bootloader configuration.  Please"
+	ewarn "make sure to keep a backup kernel available before testing it."
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		# (skip most patch release patches, we just fetch newer sources)
+		"${WORKDIR}"/109[4-9]*.patch
+		"${WORKDIR}"/[2-9]*.patch
+	)
+	default
+
+	# prepare the default config
+	case ${ARCH} in
+		amd64)
+			cp "${DISTDIR}"/linux-${AMD64_CONFIG_VER}.amd64.config .config || die
+			;;
+		x86)
+			cp "${DISTDIR}"/linux-${I686_CONFIG_VER}.i686.config .config || die
+			;;
+		*)
+			die "Unsupported arch ${ARCH}"
+			;;
+	esac
+
+	local config_tweaks=(
+		# shove arch under the carpet!
+		-e 's:^CONFIG_DEFAULT_HOSTNAME=:&"gentoo":'
+		# we do support x32
+		-e '/CONFIG_X86_X32/s:.*:CONFIG_X86_X32=y:'
+		# disable signatures
+		-e '/CONFIG_MODULE_SIG/d'
+		-e '/CONFIG_SECURITY_LOCKDOWN/d'
+		# disable compression to allow stripping
+		-e '/CONFIG_MODULE_COMPRESS/d'
+		# disable gcc plugins to unbreak distcc
+		-e '/CONFIG_GCC_PLUGIN_STRUCTLEAK/d'
+	)
+	sed -i "${config_tweaks[@]}" .config || die
+}
diff --git a/sys-kernel/gentoo-kernel/gentoo-kernel-5.4.13.ebuild b/sys-kernel/gentoo-kernel/gentoo-kernel-5.4.13.ebuild
new file mode 100644
index 000000000000..3c88e7c1bad9
--- /dev/null
+++ b/sys-kernel/gentoo-kernel/gentoo-kernel-5.4.13.ebuild
@@ -0,0 +1,81 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-build
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-${PV##*.}
+# https://git.archlinux.org/svntogit/packages.git/log/trunk/config?h=packages/linux
+AMD64_CONFIG_VER=5.4.7.arch1-1
+AMD64_CONFIG_HASH=ff79453bc0451a9083bdaa02c3901372d61a9982
+# https://git.archlinux32.org/packages/log/core/linux/config.i686
+I686_CONFIG_VER=5.4.7-arch1
+I686_CONFIG_HASH=f888688da499e17f3c7a5f15a3c44482a29acc2c
+
+DESCRIPTION="Linux kernel built with Gentoo patches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+=" https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	amd64? (
+		https://git.archlinux.org/svntogit/packages.git/plain/trunk/config?h=packages/linux&id=${AMD64_CONFIG_HASH}
+			-> linux-${AMD64_CONFIG_VER}.amd64.config
+	)
+	x86? (
+		https://git.archlinux32.org/packages/plain/core/linux/config.i686?id=${I686_CONFIG_HASH}
+			-> linux-${I686_CONFIG_VER}.i686.config
+	)"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	!sys-kernel/vanilla-kernel:${SLOT}
+	!sys-kernel/vanilla-kernel-bin:${SLOT}"
+
+pkg_pretend() {
+	mount-boot_pkg_pretend
+
+	ewarn "This is an experimental package.  The built kernel and/or initramfs"
+	ewarn "may not work at all or fail with your bootloader configuration.  Please"
+	ewarn "make sure to keep a backup kernel available before testing it."
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	default
+
+	# prepare the default config
+	case ${ARCH} in
+		amd64)
+			cp "${DISTDIR}"/linux-${AMD64_CONFIG_VER}.amd64.config .config || die
+			;;
+		x86)
+			cp "${DISTDIR}"/linux-${I686_CONFIG_VER}.i686.config .config || die
+			;;
+		*)
+			die "Unsupported arch ${ARCH}"
+			;;
+	esac
+
+	local config_tweaks=(
+		# shove arch under the carpet!
+		-e 's:^CONFIG_DEFAULT_HOSTNAME=:&"gentoo":'
+		# we do support x32
+		-e '/CONFIG_X86_X32/s:.*:CONFIG_X86_X32=y:'
+		# disable signatures
+		-e '/CONFIG_MODULE_SIG/d'
+		-e '/CONFIG_SECURITY_LOCKDOWN/d'
+		# disable compression to allow stripping
+		-e '/CONFIG_MODULE_COMPRESS/d'
+		# disable gcc plugins to unbreak distcc
+		-e '/CONFIG_GCC_PLUGIN_STRUCTLEAK/d'
+	)
+	sed -i "${config_tweaks[@]}" .config || die
+}