gentoo resync : 02.03.2018

4 files changed, 240 insertions, 8 deletions

diff --git a/sys-process/audit/Manifest b/sys-process/audit/Manifest
index 87c8b360f1a1..8c1cabac9850 100644
--- a/sys-process/audit/Manifest
+++ b/sys-process/audit/Manifest
@@ -8,6 +8,8 @@ AUX auditd-conf.d-2.1.3 734 BLAKE2B 018677362bc82c2052885cdd0e2185050cf5e97722ea
 AUX auditd-init.d-2.4.3 2054 BLAKE2B 20e68ab676c925b8567a7e9a12d2ac055fd90477cbbd6444136b7198828798f7b6428948503c344639fab5fea54962682be7c986950c2cbae8b7c9dfeb321a4b SHA512 1b48c248db5d34f148f9c79f8b2a6acbf61c729230341b861f5e331bbfb0c8356305a09eb2cc5c82c14c4fd9a13c7c13957e1ed493834b8b3b9ee38978e4c31f
 DIST audit-2.6.4.tar.gz 1078677 BLAKE2B 056d9f269926d9b0d74f7187f833f1e94d4e03a5137750fe4ff87b71fa0ce0e0a8569b97ecbd671f951061cfb088dff17b46e37cc14122864c37615356646fc5 SHA512 69b5d3987d2b8b189d1242fde639af3d7d366e901733133e47ee71223caf73aa7da40b7811298f0af861969b0ab482c5ef9830b711bdd15bd5f4d0ebc88a1224
 DIST audit-2.7.1.tar.gz 1099083 BLAKE2B 10f72ac3273ce9e23e1fb8ad8d57dcae772ba1f861f519867399d95e14f4809897637969de45566d62a73a35e5674260155773daf8de00481fcbd1b9c3138f96 SHA512 37964d81deee8608fde5f90d5d096727d3eb009e084be34749adcb0662e607e35c49c80bd83ce38b17161f11363b691721c8a8aa5dea832d320c53ab0ebb7483
-EBUILD audit-2.6.4.ebuild 6168 BLAKE2B 361c1128c2faf2895580041349eb48deb67f8a3ba28061eebb991c1d23fca98d82f00b0d41c32fcc3ce1f4e4ed9b44654d0c6f66177ff835a9b452eb0e60839f SHA512 ca6269971071902dc3688f16287d1c54ee420bab9efd8cfb8e63bdb7eb03d4e80d1bbc75b9e4cb82be3a78743e8617fe656018e509ad77562fe8a14a8f4e5c0d
-EBUILD audit-2.7.1.ebuild 6179 BLAKE2B b4a5a03fb5f3f3807fca8d5d0c26be53480fcc619cbab9344295a7ca09921e2cc7ae2441fd5d40cee7dcb7992ea29cee274f0892bba8c987a30a572bf901c237 SHA512 3b6efbe46f347e3b7abe092557e4c3cbe7cc30fd6a1648cf1d0395dd1f9a707e7eb10c3202481874657d5b9c809506b61b8dfb8dcf494fe62152a2fa6a9007cf
+DIST audit-2.8.2.tar.gz 1121970 BLAKE2B bbec694ed1177a8590d035c2d6d197e49343fc370b101589e58736042c3b12cabb68fe796422f3133feb79068ab7d5931efa5414d22edead10c8871fefcd2549 SHA512 888ebf5e8e9d285b82d87377fc8836886d7a8b089c1be4091420a77a0250c9baf09aebb7a6330ff5043fb35f51eb6baf8d4491e26da7ad0811f0087e395b5012
+EBUILD audit-2.6.4.ebuild 6194 BLAKE2B 5e159665e671092224196d91478246d2f9f56092dac4be65d86d6094bc535c276d90f2635be17214bc9fbae94aa9d4e58d1b538766eda940260c00ce9be66591 SHA512 5769b0f13bd033b5b465ca36d707c4324338fb2ce43948a2d656ebdb76d5004030e5a10057aa8d9f532d13484fdc1819f5633ce52a12c20dd301d0b4b7eaffe5
+EBUILD audit-2.7.1.ebuild 6200 BLAKE2B 82cd0172f07d576f6464fde97462f2106446c42ba38e06c8470628437c80b7c2b7b67d28bcd84c9a48dc0851321986a788b7220534461bb406196414070c2593 SHA512 6216b623842e583033a945f47914ec2fb22945105c2b42bc5fd9588d8a49161ee15a472963a44db781192941f5d217240f2efeff7327dd6d5607d7ad54c1e2f2
+EBUILD audit-2.8.2.ebuild 6205 BLAKE2B 82d223206cf3e14c58ce4bbdec2df18e5ad874eb440b4208a7c7463305ec2ec8039783e6436dff0623478db3dcb0d7909b4f077a819bee494d086f162d455e34 SHA512 ee1194da6ee59e8efb3d625853dfd98b0b4e034282aa72cd5f38860be7023c0e8d795c6898313551fca0b8477912a3d7608d821d74f66851136786620abdd630
 MISC metadata.xml 284 BLAKE2B c99c67d5591687a10bb380f1264dd1cde6370ff3a96864093cb41c7c17617bed826652b7651490b6a4634a7429589bbd137402afd7cf8e79cfd5f636c86baa52 SHA512 84f04c94a976c0e2c7db9a7c8c392b6c714e37650efefe2db9807688c28a8cdb64722064be23b89d0263c82c5de7b7dc412ae13f95b42c97ae928c00bb584fac
diff --git a/sys-process/audit/audit-2.6.4.ebuild b/sys-process/audit/audit-2.6.4.ebuild
index e83cf86b2dd1..999fbf25c03c 100644
--- a/sys-process/audit/audit-2.6.4.ebuild
+++ b/sys-process/audit/audit-2.6.4.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI="6"
 
-PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
 
-inherit autotools multilib multilib-minimal toolchain-funcs python-r1 linux-info systemd
+inherit autotools ltprune multilib multilib-minimal toolchain-funcs preserve-libs python-r1 linux-info systemd
 
 DESCRIPTION="Userspace utilities for storing and processing auditing records"
 HOMEPAGE="https://people.redhat.com/sgrubb/audit/"
diff --git a/sys-process/audit/audit-2.7.1.ebuild b/sys-process/audit/audit-2.7.1.ebuild
index 85a1f9a420fb..ef27492f5ac8 100644
--- a/sys-process/audit/audit-2.7.1.ebuild
+++ b/sys-process/audit/audit-2.7.1.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
 
 PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
 
-inherit autotools multilib multilib-minimal toolchain-funcs python-r1 linux-info systemd
+inherit autotools ltprune multilib multilib-minimal toolchain-funcs preserve-libs python-r1 linux-info systemd
 
 DESCRIPTION="Userspace utilities for storing and processing auditing records"
 HOMEPAGE="https://people.redhat.com/sgrubb/audit/"
@@ -13,7 +13,7 @@ SRC_URI="https://people.redhat.com/sgrubb/audit/${P}.tar.gz"
 
 LICENSE="GPL-2"
 SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
 IUSE="gssapi ldap python static-libs"
 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
 # Testcases are pretty useless as they are built for RedHat users/groups and kernels.
diff --git a/sys-process/audit/audit-2.8.2.ebuild b/sys-process/audit/audit-2.8.2.ebuild
new file mode 100644
index 000000000000..c03f103ef2f8
--- /dev/null
+++ b/sys-process/audit/audit-2.8.2.ebuild
@@ -0,0 +1,230 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit autotools multilib multilib-minimal toolchain-funcs preserve-libs python-r1 linux-info systemd
+
+DESCRIPTION="Userspace utilities for storing and processing auditing records"
+HOMEPAGE="https://people.redhat.com/sgrubb/audit/"
+SRC_URI="https://people.redhat.com/sgrubb/audit/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="gssapi ldap python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+# Testcases are pretty useless as they are built for RedHat users/groups and kernels.
+RESTRICT="test"
+
+RDEPEND="gssapi? ( virtual/krb5 )
+	ldap? ( net-nds/openldap )
+	sys-libs/libcap-ng
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	>=sys-kernel/linux-headers-2.6.34
+	python? ( dev-lang/swig:0 )"
+# Do not use os-headers as this is linux specific
+
+CONFIG_CHECK="~AUDIT"
+
+pkg_setup() {
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	eapply_user
+
+	# Do not build GUI tools
+	sed -i \
+		-e '/AC_CONFIG_SUBDIRS.*system-config-audit/d' \
+		"${S}"/configure.ac || die
+	sed -i \
+		-e 's,system-config-audit,,g' \
+		"${S}"/Makefile.am || die
+	rm -rf "${S}"/system-config-audit
+
+	if ! use ldap; then
+		sed -i \
+			-e '/^AC_OUTPUT/s,audisp/plugins/zos-remote/Makefile,,g' \
+			"${S}"/configure.ac || die
+		sed -i \
+			-e '/^SUBDIRS/s,zos-remote,,g' \
+			"${S}"/audisp/plugins/Makefile.am || die
+	fi
+
+	# Don't build static version of Python module.
+	eapply "${FILESDIR}"/${PN}-2.4.3-python.patch
+
+	# glibc/kernel upstreams suck with both defining ia64_fpreg
+	# This patch is a horribly workaround that is only valid as long as you
+	# don't need the OTHER definitions in fpu.h.
+	eapply "${FILESDIR}"/${PN}-2.1.3-ia64-compile-fix.patch
+
+	# there is no --without-golang conf option
+	sed -e "/^SUBDIRS =/s/ @gobind_dir@//" -i bindings/Makefile.am || die
+
+	# Regenerate autotooling
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local ECONF_SOURCE=${S}
+	econf \
+		--sbindir="${EPREFIX}/sbin" \
+		$(use_enable gssapi gssapi-krb5) \
+		$(use_enable static-libs static) \
+		--enable-systemd \
+		--without-python \
+		--without-python3
+
+	if multilib_is_native_abi; then
+		python_configure() {
+			mkdir -p "${BUILD_DIR}" || die
+			cd "${BUILD_DIR}" || die
+
+			if python_is_python3; then
+				econf --without-python --with-python3
+			else
+				econf --with-python --without-python3
+			fi
+		}
+
+		use python && python_foreach_impl python_configure
+	fi
+}
+
+src_configure() {
+	tc-export_build_env BUILD_{CC,CPP}
+	export CC_FOR_BUILD="${BUILD_CC}"
+	export CPP_FOR_BUILD="${BUILD_CPP}"
+
+	multilib-minimal_src_configure
+}
+
+multilib_src_compile() {
+	if multilib_is_native_abi; then
+		default
+
+		python_compile() {
+			local pysuffix pydef
+			if python_is_python3; then
+				pysuffix=3
+				pydef='USE_PYTHON3=true'
+			else
+				pysuffix=2
+				pydef='HAVE_PYTHON=true'
+			fi
+
+			emake -C "${BUILD_DIR}"/bindings/swig \
+				VPATH="${native_build}/lib" \
+				LIBS="${native_build}/lib/libaudit.la" \
+				_audit_la_LIBADD="${native_build}/lib/libaudit.la" \
+				_audit_la_DEPENDENCIES="${S}/lib/libaudit.h ${native_build}/lib/libaudit.la" \
+				${pydef}
+			emake -C "${BUILD_DIR}"/bindings/python/python${pysuffix} \
+				VPATH="${S}/bindings/python/python${pysuffix}:${native_build}/bindings/python/python${pysuffix}" \
+				auparse_la_LIBADD="${native_build}/auparse/libauparse.la ${native_build}/lib/libaudit.la" \
+				${pydef}
+		}
+
+		local native_build="${BUILD_DIR}"
+		use python && python_foreach_impl python_compile
+	else
+		emake -C lib
+		emake -C auparse
+	fi
+}
+
+multilib_src_install() {
+	if multilib_is_native_abi; then
+		emake DESTDIR="${D}" initdir="$(systemd_get_systemunitdir)" install
+
+		python_install() {
+			local pysuffix pydef
+			if python_is_python3; then
+				pysuffix=3
+				pydef='USE_PYTHON3=true'
+			else
+				pysuffix=2
+				pydef='HAVE_PYTHON=true'
+			fi
+
+			emake -C "${BUILD_DIR}"/bindings/swig \
+				VPATH="${native_build}/lib" \
+				LIBS="${native_build}/lib/libaudit.la" \
+				_audit_la_LIBADD="${native_build}/lib/libaudit.la" \
+				_audit_la_DEPENDENCIES="${S}/lib/libaudit.h ${native_build}/lib/libaudit.la" \
+				${pydef} \
+				DESTDIR="${D}" install
+			emake -C "${BUILD_DIR}"/bindings/python/python${pysuffix} \
+				VPATH="${S}/bindings/python/python${pysuffix}:${native_build}/bindings/python/python${pysuffix}" \
+				auparse_la_LIBADD="${native_build}/auparse/libauparse.la ${native_build}/lib/libaudit.la" \
+				${pydef} \
+				DESTDIR="${D}" install
+		}
+
+		local native_build=${BUILD_DIR}
+		use python && python_foreach_impl python_install
+
+		# things like shadow use this so we need to be in /
+		gen_usr_ldscript -a audit auparse
+	else
+		emake -C lib DESTDIR="${D}" install
+		emake -C auparse DESTDIR="${D}" install
+	fi
+}
+
+multilib_src_install_all() {
+	dodoc AUTHORS ChangeLog README* THANKS TODO
+	docinto contrib
+	dodoc contrib/{avc_snap,skeleton.c}
+	docinto contrib/plugin
+	dodoc contrib/plugin/*
+	docinto rules
+	dodoc rules/*
+
+	newinitd "${FILESDIR}"/auditd-init.d-2.4.3 auditd
+	newconfd "${FILESDIR}"/auditd-conf.d-2.1.3 auditd
+
+	fperms 644 "$(systemd_get_systemunitdir)"/auditd.service # 556436
+
+	[ -f "${ED}"/sbin/audisp-remote ] && \
+	dodir /usr/sbin && \
+	mv "${ED}"/{sbin,usr/sbin}/audisp-remote || die
+
+	# Gentoo rules
+	insinto /etc/audit/
+	newins "${FILESDIR}"/audit.rules-2.1.3 audit.rules
+	doins "${FILESDIR}"/audit.rules.stop*
+
+	# audit logs go here
+	keepdir /var/log/audit/
+
+	find "${D}" -name '*.la' -delete || die
+
+	# Security
+	lockdown_perms "${ED}"
+}
+
+pkg_preinst() {
+	# Preserve from the audit-1 series
+	preserve_old_lib /$(get_libdir)/libaudit.so.0
+}
+
+pkg_postinst() {
+	lockdown_perms "${EROOT}"
+	# Preserve from the audit-1 series
+	preserve_old_lib_notify /$(get_libdir)/libaudit.so.0
+}
+
+lockdown_perms() {
+	# Upstream wants these to have restrictive perms.
+	# Should not || die as not all paths may exist.
+	local basedir="$1"
+	chmod 0750 "${basedir}"/sbin/au{ditctl,report,dispd,ditd,search,trace} 2>/dev/null
+	chmod 0750 "${basedir}"/var/log/audit/ 2>/dev/null
+	chmod 0640 "${basedir}"/etc/{audit/,}{auditd.conf,audit.rules*} 2>/dev/null
+}