gentoo resync : 14.04.2018

1 files changed, 62 insertions, 0 deletions

diff --git a/sys-process/htop/htop-2.2.0.ebuild b/sys-process/htop/htop-2.2.0.ebuild
new file mode 100644
index 000000000000..980d490717ab
--- /dev/null
+++ b/sys-process/htop/htop-2.2.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit linux-info python-single-r1
+
+DESCRIPTION="interactive process viewer"
+HOMEPAGE="http://hisham.hm/htop/"
+SRC_URI="http://hisham.hm/htop/releases/${PV}/${P}.tar.gz"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="kernel_FreeBSD kernel_linux openvz unicode vserver"
+
+RDEPEND="sys-libs/ncurses:0=[unicode?]"
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	virtual/pkgconfig"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+DOCS=( ChangeLog README )
+
+CONFIG_CHECK="~TASKSTATS ~TASK_XACCT ~TASK_IO_ACCOUNTING ~CGROUPS"
+
+pkg_setup() {
+	if ! has_version sys-process/lsof; then
+		ewarn "To use lsof features in htop(what processes are accessing"
+		ewarn "what files), you must have sys-process/lsof installed."
+	fi
+
+	python-single-r1_pkg_setup
+	linux-info_pkg_setup
+}
+
+src_prepare() {
+	rm missing || die
+
+	default
+
+	python_fix_shebang scripts/MakeHeader.py
+}
+
+src_configure() {
+	[[ $CBUILD != $CHOST ]] && export ac_cv_file__proc_{meminfo,stat}=yes #328971
+
+	local myeconfargs=(
+		# fails to build against recent hwloc versions
+		--disable-hwloc
+		--enable-taskstats
+		$(use_enable kernel_linux cgroup)
+		$(use_enable kernel_linux linux-affinity)
+		$(use_enable openvz)
+		$(use_enable unicode)
+		$(use_enable vserver)
+	)
+	econf ${myeconfargs[@]}
+}