gentoo auto-resync : 04:02:2024 - 05:43:52

1 files changed, 42 insertions, 0 deletions

diff --git a/www-apps/nextcloud/nextcloud-26.0.11.ebuild b/www-apps/nextcloud/nextcloud-26.0.11.ebuild
new file mode 100644
index 000000000000..2d28ed73cfa3
--- /dev/null
+++ b/www-apps/nextcloud/nextcloud-26.0.11.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit webapp
+
+DESCRIPTION="Personal cloud that runs on your own server"
+HOMEPAGE="https://nextcloud.com/"
+SRC_URI="https://download.nextcloud.com/server/releases/${P}.tar.bz2"
+LICENSE="AGPL-3"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="+curl +imagemagick mysql postgres +sqlite"
+REQUIRED_USE="|| ( mysql postgres sqlite )"
+
+RDEPEND="<dev-lang/php-8.2[curl?,filter,gd,hash(+),intl,json(+),mysql?,pdo,posix,postgres?,session,simplexml,sqlite?,truetype,xmlreader,xmlwriter,zip]
+	imagemagick? ( dev-php/pecl-imagick )
+	virtual/httpd-php"
+
+S=${WORKDIR}/${PN}
+
+pkg_setup() {
+	webapp_pkg_setup
+}
+
+src_install() {
+	webapp_src_preinst
+
+	insinto "${MY_HTDOCSDIR}"
+	doins -r .
+	dodir "${MY_HTDOCSDIR}"/data
+
+	webapp_serverowned -R "${MY_HTDOCSDIR}"/apps
+	webapp_serverowned -R "${MY_HTDOCSDIR}"/data
+	webapp_serverowned -R "${MY_HTDOCSDIR}"/config
+	webapp_configfile "${MY_HTDOCSDIR}"/.htaccess
+
+	webapp_postinst_txt en "${FILESDIR}"/php-argon2-en.txt
+
+	webapp_src_install
+}