gentoo resync : 09.03.2018

2 files changed, 116 insertions, 0 deletions

diff --git a/www-client/opera-developer/Manifest b/www-client/opera-developer/Manifest
index b0dd81a194ef..02cca4e180a9 100644
--- a/www-client/opera-developer/Manifest
+++ b/www-client/opera-developer/Manifest
@@ -1,3 +1,5 @@
 DIST opera-developer_53.0.2880.0_amd64.deb 54207438 BLAKE2B 0e2f9dd67b3e10badad0ae15d940637a54a8d490eb0522a6e257d161e12a73776aed8b78f8d1e87a7632126fdea8864cf3220a0df16396b0bdcb1c9554a341d7 SHA512 25b49c1aabf9e05d47cb19847f224b53ad3053217c033775b7eaa728eba3f3ba0019997cf88f985366f7c5092bbfc2b3b75cf7c1de4a452c2a2cb9a347751413
+DIST opera-developer_53.0.2885.0_amd64.deb 54539420 BLAKE2B adda26647ef8b194ce1c99f0ad3d963ce35c2a7957a3150c01bc420b6eef59806a1ab807f49d64931c72e23e215db5f99d5aadbb72de680c2a7ea9619c1799ae SHA512 ef9398b3c090e7a77654943a2b394960604859d4daf133f1bc1b713523edfb4eafcd8e7f9b3023142a9115043ce3bedb6a9db0fc48d27007c145dedf8455c4d0
 EBUILD opera-developer-53.0.2880.0.ebuild 2316 BLAKE2B 8fbb8274e4ef03f9fca9382ade28d36524be58c1e16fecb33d7c90947f938e115e3f47bba5df7b07f145b15e3759df73bb6f2cc5729b4d327492e25f68429a72 SHA512 0199d19ab24caff2b35b700db1c75a8d0279bfa2612395c83572a43f3cfc49526501377cf9d2a1042843e999f451a3ceff13f381dbbcc9d3e6b2305b88531ff8
+EBUILD opera-developer-53.0.2885.0.ebuild 2316 BLAKE2B 8fbb8274e4ef03f9fca9382ade28d36524be58c1e16fecb33d7c90947f938e115e3f47bba5df7b07f145b15e3759df73bb6f2cc5729b4d327492e25f68429a72 SHA512 0199d19ab24caff2b35b700db1c75a8d0279bfa2612395c83572a43f3cfc49526501377cf9d2a1042843e999f451a3ceff13f381dbbcc9d3e6b2305b88531ff8
 MISC metadata.xml 238 BLAKE2B 72d4053d28bbf82c9a08a88b354321a782501542b5d506fc6d9f4034839f302761124d59445c0414a0fd38b6401cd5fbe06670802abdb1f25c7cb60919ea5d2e SHA512 b0b981ef72f4d295f427f92dc9931553b4fb7a91c8ed63fa1f28bdbe8bc61d6f0943e1217eb7b61b8d85d9685cbe759db49f094a18a1461cb48429affe76d993
diff --git a/www-client/opera-developer/opera-developer-53.0.2885.0.ebuild b/www-client/opera-developer/opera-developer-53.0.2885.0.ebuild
new file mode 100644
index 000000000000..12a41bce61c8
--- /dev/null
+++ b/www-client/opera-developer/opera-developer-53.0.2885.0.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 gnome2-utils multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="http://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	http://download1.operacdn.com/pub/
+	http://download2.operacdn.com/pub/
+	http://download3.operacdn.com/pub/
+	http://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="usr/$(get_libdir)/${PN}"
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	rm usr/bin/${PN} || die
+
+	rm usr/share/doc/${PN}/copyright || die
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}